lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use DBIx::Class::ResultClass::HashRefInflator;
   9 use Scalar::Util qw/blessed weaken reftype/;
  10 use DBIx::Class::_Util qw(
  11   dbic_internal_try
  12   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  13 );
  14 use Try::Tiny;
  15
  16 # not importing first() as it will clash with our own method
  17 use List::Util ();
  18
  19 BEGIN {
  20   # De-duplication in _merge_attr() is disabled, but left in for reference
  21   # (the merger is used for other things that ought not to be de-duped)
  22   *__HM_DEDUP = sub () { 0 };
  23 }
  24
  25 use namespace::clean;
  26
  27 use overload
  28         '0+'     => "count",
  29         'bool'   => "_bool",
  30         fallback => 1;
  31
  32 # this is real - CDBICompat overrides it with insanity
  33 # yes, prototype won't matter, but that's for now ;)
  34 sub _bool () { 1 }
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  37
  38 =head1 NAME
  39
  40 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  41
  42 =head1 SYNOPSIS
  43
  44   my $users_rs = $schema->resultset('User');
  45   while( $user = $users_rs->next) {
  46     print $user->username;
  47   }
  48
  49   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  50   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  51
  52 =head1 DESCRIPTION
  53
  54 A ResultSet is an object which stores a set of conditions representing
  55 a query. It is the backbone of DBIx::Class (i.e. the really
  56 important/useful bit).
  57
  58 No SQL is executed on the database when a ResultSet is created, it
  59 just stores all the conditions needed to create the query.
  60
  61 A basic ResultSet representing the data of an entire table is returned
  62 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  63 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  64
  65   my $users_rs = $schema->resultset('User');
  66
  67 A new ResultSet is returned from calling L</search> on an existing
  68 ResultSet. The new one will contain all the conditions of the
  69 original, plus any new conditions added in the C<search> call.
  70
  71 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  72 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  73 represents.
  74
  75 The query that the ResultSet represents is B<only> executed against
  76 the database when these methods are called:
  77 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  78
  79 If a resultset is used in a numeric context it returns the L</count>.
  80 However, if it is used in a boolean context it is B<always> true.  So if
  81 you want to check if a resultset has any results, you must use C<if $rs
  82 != 0>.
  83
  84 =head1 EXAMPLES
  85
  86 =head2 Chaining resultsets
  87
  88 Let's say you've got a query that needs to be run to return some data
  89 to the user. But, you have an authorization system in place that
  90 prevents certain users from seeing certain information. So, you want
  91 to construct the basic query in one method, but add constraints to it in
  92 another.
  93
  94   sub get_data {
  95     my $self = shift;
  96     my $request = $self->get_request; # Get a request object somehow.
  97     my $schema = $self->result_source->schema;
  98
  99     my $cd_rs = $schema->resultset('CD')->search({
 100       title => $request->param('title'),
 101       year => $request->param('year'),
 102     });
 103
 104     $cd_rs = $self->apply_security_policy( $cd_rs );
 105
 106     return $cd_rs->all();
 107   }
 108
 109   sub apply_security_policy {
 110     my $self = shift;
 111     my ($rs) = @_;
 112
 113     return $rs->search({
 114       subversive => 0,
 115     });
 116   }
 117
 118 =head3 Resolving conditions and attributes
 119
 120 When a resultset is chained from another resultset (e.g.:
 121 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 122 and attributes with the same keys need resolving.
 123
 124 If any of L</columns>, L</select>, L</as> are present, they reset the
 125 original selection, and start the selection "clean".
 126
 127 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 128 are merged into the existing ones from the original resultset.
 129
 130 The L</where> and L</having> attributes, and any search conditions, are
 131 merged with an SQL C<AND> to the existing condition from the original
 132 resultset.
 133
 134 All other attributes are overridden by any new ones supplied in the
 135 search attributes.
 136
 137 =head2 Multiple queries
 138
 139 Since a resultset just defines a query, you can do all sorts of
 140 things with it with the same object.
 141
 142   # Don't hit the DB yet.
 143   my $cd_rs = $schema->resultset('CD')->search({
 144     title => 'something',
 145     year => 2009,
 146   });
 147
 148   # Each of these hits the DB individually.
 149   my $count = $cd_rs->count;
 150   my $most_recent = $cd_rs->get_column('date_released')->max();
 151   my @records = $cd_rs->all;
 152
 153 And it's not just limited to SELECT statements.
 154
 155   $cd_rs->delete();
 156
 157 This is even cooler:
 158
 159   $cd_rs->create({ artist => 'Fred' });
 160
 161 Which is the same as:
 162
 163   $schema->resultset('CD')->create({
 164     title => 'something',
 165     year => 2009,
 166     artist => 'Fred'
 167   });
 168
 169 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 170
 171 =head2 Custom ResultSet classes
 172
 173 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 174
 175   package MyApp::Schema::ResultSet::User;
 176
 177   use strict;
 178   use warnings;
 179
 180   use base 'DBIx::Class::ResultSet';
 181
 182   sub active {
 183     my $self = shift;
 184     $self->search({ $self->current_source_alias . '.active' => 1 });
 185   }
 186
 187   sub unverified {
 188     my $self = shift;
 189     $self->search({ $self->current_source_alias . '.verified' => 0 });
 190   }
 191
 192   sub created_n_days_ago {
 193     my ($self, $days_ago) = @_;
 194     $self->search({
 195       $self->current_source_alias . '.create_date' => {
 196         '<=',
 197       $self->result_source->schema->storage->datetime_parser->format_datetime(
 198         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 199       )}
 200     });
 201   }
 202
 203   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 204
 205   1;
 206
 207 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 208 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 209 L<ResulSet|DBIx::Class::ResultSet> classes.
 210
 211 =head3 ResultSet subclassing with Moose and similar constructor-providers
 212
 213 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 214 you may find it useful if your ResultSets contain a lot of business logic
 215 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 216 your code via roles.
 217
 218 In order to write custom ResultSet classes with L<Moo> you need to use the
 219 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 220 unusual signature of the L<constructor provided by DBIC
 221 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 222
 223   use Moo;
 224   extends 'DBIx::Class::ResultSet';
 225   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 226
 227   ...your code...
 228
 229   1;
 230
 231 If you want to build your custom ResultSet classes with L<Moose>, you need
 232 a similar, though a little more elaborate template in order to interface the
 233 inlining of the L<Moose>-provided
 234 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 235 with the DBIC one.
 236
 237   package MyApp::Schema::ResultSet::User;
 238
 239   use Moose;
 240   use MooseX::NonMoose;
 241   extends 'DBIx::Class::ResultSet';
 242
 243   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 244
 245   ...your code...
 246
 247   __PACKAGE__->meta->make_immutable;
 248
 249   1;
 250
 251 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 252 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 253 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 254 instead by doing:
 255
 256   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 257
 258 =head1 METHODS
 259
 260 =head2 new
 261
 262 =over 4
 263
 264 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 265
 266 =item Return Value: L<$resultset|/search>
 267
 268 =back
 269
 270 The resultset constructor. Takes a source object (usually a
 271 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 272 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 273 executed as needed by the other methods.
 274
 275 Generally you never construct a resultset manually. Instead you get one
 276 from e.g. a
 277 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 278 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 279 scalar context):
 280
 281   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 282
 283 =over
 284
 285 =item WARNING
 286
 287 If called on an object, proxies to L</new_result> instead, so
 288
 289   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 290
 291 will return a CD object, not a ResultSet, and is equivalent to:
 292
 293   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 294
 295 Please also keep in mind that many internals call L</new_result> directly,
 296 so overloading this method with the idea of intercepting new result object
 297 creation B<will not work>. See also warning pertaining to L</create>.
 298
 299 =back
 300
 301 =cut
 302
 303 sub new {
 304   my $class = shift;
 305
 306   if (ref $class) {
 307     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 308     return $class->new_result(@_);
 309   }
 310
 311   my ($source, $attrs) = @_;
 312   $source = $source->resolve
 313     if $source->isa('DBIx::Class::ResultSourceHandle');
 314
 315   $attrs = { %{$attrs||{}} };
 316   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 317
 318   if ($attrs->{page}) {
 319     $attrs->{rows} ||= 10;
 320   }
 321
 322   $attrs->{alias} ||= 'me';
 323
 324   my $self = bless {
 325     result_source => $source,
 326     cond => $attrs->{where},
 327     pager => undef,
 328     attrs => $attrs,
 329   }, $class;
 330
 331   # if there is a dark selector, this means we are already in a
 332   # chain and the cleanup/sanification was taken care of by
 333   # _search_rs already
 334   $self->_normalize_selection($attrs)
 335     unless $attrs->{_dark_selector};
 336
 337   $self->result_class(
 338     $attrs->{result_class} || $source->result_class
 339   );
 340
 341   $self;
 342 }
 343
 344 =head2 search
 345
 346 =over 4
 347
 348 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 349
 350 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 351
 352 =back
 353
 354   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 355   my $new_rs = $cd_rs->search({ year => 2005 });
 356
 357   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 358                  # year = 2005 OR year = 2004
 359
 360 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 361 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 362 To avoid that, use L</search_rs>.
 363
 364 If you need to pass in additional attributes but no additional condition,
 365 call it as C<search(undef, \%attrs)>.
 366
 367   # "SELECT name, artistid FROM $artist_table"
 368   my @all_artists = $schema->resultset('Artist')->search(undef, {
 369     columns => [qw/name artistid/],
 370   });
 371
 372 For a list of attributes that can be passed to C<search>, see
 373 L</ATTRIBUTES>. For more examples of using this function, see
 374 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 375 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 376 and its extension L<DBIx::Class::SQLMaker>.
 377
 378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 379
 380 =head3 CAVEAT
 381
 382 Note that L</search> does not process/deflate any of the values passed in the
 383 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 384 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 385 manually that any value passed to this method will stringify to something the
 386 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 387 objects, for more info see:
 388 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 389
 390 =cut
 391
 392 sub search {
 393   my $self = shift;
 394   my $rs = $self->search_rs( @_ );
 395
 396   if (wantarray) {
 397     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 398     return $rs->all;
 399   }
 400   elsif (defined wantarray) {
 401     return $rs;
 402   }
 403   else {
 404     # we can be called by a relationship helper, which in
 405     # turn may be called in void context due to some braindead
 406     # overload or whatever else the user decided to be clever
 407     # at this particular day. Thus limit the exception to
 408     # external code calls only
 409     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 410       if (caller)[0] !~ /^\QDBIx::Class::/;
 411
 412     return ();
 413   }
 414 }
 415
 416 =head2 search_rs
 417
 418 =over 4
 419
 420 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 421
 422 =item Return Value: L<$resultset|/search>
 423
 424 =back
 425
 426 This method does the same exact thing as search() except it will
 427 always return a resultset, even in list context.
 428
 429 =cut
 430
 431 sub search_rs {
 432   my $self = shift;
 433
 434   my $rsrc = $self->result_source;
 435   my ($call_cond, $call_attrs);
 436
 437   # Special-case handling for (undef, undef) or (undef)
 438   # Note that (foo => undef) is valid deprecated syntax
 439   @_ = () if not scalar grep { defined $_ } @_;
 440
 441   # just a cond
 442   if (@_ == 1) {
 443     $call_cond = shift;
 444   }
 445   # fish out attrs in the ($condref, $attr) case
 446   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 447     ($call_cond, $call_attrs) = @_;
 448   }
 449   elsif (@_ % 2) {
 450     $self->throw_exception('Odd number of arguments to search')
 451   }
 452   # legacy search
 453   elsif (@_) {
 454     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 455       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 456
 457     for my $i (0 .. $#_) {
 458       next if $i % 2;
 459       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 460         if (! defined $_[$i] or length ref $_[$i] );
 461     }
 462
 463     $call_cond = { @_ };
 464   }
 465
 466   # see if we can keep the cache (no $rs changes)
 467   my $cache;
 468   my %safe = (alias => 1, cache => 1);
 469   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 470     ! defined $call_cond
 471       or
 472     ref $call_cond eq 'HASH' && ! keys %$call_cond
 473       or
 474     ref $call_cond eq 'ARRAY' && ! @$call_cond
 475   )) {
 476     $cache = $self->get_cache;
 477   }
 478
 479   my $old_attrs = { %{$self->{attrs}} };
 480   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 481
 482   my $new_attrs = { %$old_attrs };
 483
 484   # take care of call attrs (only if anything is changing)
 485   if ($call_attrs and keys %$call_attrs) {
 486
 487     # copy for _normalize_selection
 488     $call_attrs = { %$call_attrs };
 489
 490     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 491
 492     # reset the current selector list if new selectors are supplied
 493     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 494       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 495     }
 496
 497     # Normalize the new selector list (operates on the passed-in attr structure)
 498     # Need to do it on every chain instead of only once on _resolved_attrs, in
 499     # order to allow detection of empty vs partial 'as'
 500     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 501       if $old_attrs->{_dark_selector};
 502     $self->_normalize_selection ($call_attrs);
 503
 504     # start with blind overwriting merge, exclude selector attrs
 505     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 506     delete @{$new_attrs}{@selector_attrs};
 507
 508     for (@selector_attrs) {
 509       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 510         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 511     }
 512
 513     # older deprecated name, use only if {columns} is not there
 514     if (my $c = delete $new_attrs->{cols}) {
 515       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 516       if ($new_attrs->{columns}) {
 517         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 518       }
 519       else {
 520         $new_attrs->{columns} = $c;
 521       }
 522     }
 523
 524
 525     # join/prefetch use their own crazy merging heuristics
 526     foreach my $key (qw/join prefetch/) {
 527       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 528         if exists $call_attrs->{$key};
 529     }
 530
 531     # stack binds together
 532     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 533   }
 534
 535
 536   for ($old_where, $call_cond) {
 537     if (defined $_) {
 538       $new_attrs->{where} = $self->_stack_cond (
 539         $_, $new_attrs->{where}
 540       );
 541     }
 542   }
 543
 544   if (defined $old_having) {
 545     $new_attrs->{having} = $self->_stack_cond (
 546       $old_having, $new_attrs->{having}
 547     )
 548   }
 549
 550   my $rs = (ref $self)->new($rsrc, $new_attrs);
 551
 552   $rs->set_cache($cache) if ($cache);
 553
 554   return $rs;
 555 }
 556
 557 my $dark_sel_dumper;
 558 sub _normalize_selection {
 559   my ($self, $attrs) = @_;
 560
 561   # legacy syntax
 562   if ( exists $attrs->{include_columns} ) {
 563     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 564     $attrs->{'+columns'} = $self->_merge_attr(
 565       $attrs->{'+columns'}, delete $attrs->{include_columns}
 566     );
 567   }
 568
 569   # columns are always placed first, however
 570
 571   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 572   # delay the decision on whether to use a default select list ($rsrc->columns)
 573   # allowing stuff like the remove_columns helper to work
 574   #
 575   # select/as +select/+as pairs need special handling - the amount of select/as
 576   # elements in each pair does *not* have to be equal (think multicolumn
 577   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 578   # supplied at all) - try to infer the alias, either from the -as parameter
 579   # of the selector spec, or use the parameter whole if it looks like a column
 580   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 581   # is ok as well), but make sure no more additions to the 'as' chain take place
 582   for my $pref ('', '+') {
 583
 584     my ($sel, $as) = map {
 585       my $key = "${pref}${_}";
 586
 587       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 588         ? @{$attrs->{$key}}
 589         : $attrs->{$key} || ()
 590       ];
 591       delete $attrs->{$key};
 592       $val;
 593     } qw/select as/;
 594
 595     if (! @$as and ! @$sel ) {
 596       next;
 597     }
 598     elsif (@$as and ! @$sel) {
 599       $self->throw_exception(
 600         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 601       );
 602     }
 603     elsif( ! @$as ) {
 604       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 605       # if any @$as has been supplied we assume the user knows what (s)he is doing
 606       # and blindly keep stacking up pieces
 607       unless ($attrs->{_dark_selector}) {
 608         SELECTOR:
 609         for (@$sel) {
 610           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 611             push @$as, $_->{-as};
 612           }
 613           # assume any plain no-space, no-parenthesis string to be a column spec
 614           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 615           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 616             push @$as, $_;
 617           }
 618           # if all else fails - raise a flag that no more aliasing will be allowed
 619           else {
 620             $attrs->{_dark_selector} = {
 621               plus_stage => $pref,
 622               string => ($dark_sel_dumper ||= do {
 623                   require Data::Dumper::Concise;
 624                   Data::Dumper::Concise::DumperObject()->Indent(0);
 625                 })->Values([$_])->Dump
 626               ,
 627             };
 628             last SELECTOR;
 629           }
 630         }
 631       }
 632     }
 633     elsif (@$as < @$sel) {
 634       $self->throw_exception(
 635         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 636       );
 637     }
 638     elsif ($pref and $attrs->{_dark_selector}) {
 639       $self->throw_exception(
 640         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 641       );
 642     }
 643
 644
 645     # merge result
 646     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 647     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 648   }
 649 }
 650
 651 sub _stack_cond {
 652   my ($self, $left, $right) = @_;
 653
 654   (
 655     (ref $_ eq 'ARRAY' and !@$_)
 656       or
 657     (ref $_ eq 'HASH' and ! keys %$_)
 658   ) and $_ = undef for ($left, $right);
 659
 660   # either one of the two undef
 661   if ( (defined $left) xor (defined $right) ) {
 662     return defined $left ? $left : $right;
 663   }
 664   # both undef
 665   elsif ( ! defined $left ) {
 666     return undef
 667   }
 668   else {
 669     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 670   }
 671 }
 672
 673 =head2 search_literal
 674
 675 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 676 should only be used in that context. C<search_literal> is a convenience
 677 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 678 want to ensure columns are bound correctly, use L</search>.
 679
 680 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 681 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 682 require C<search_literal>.
 683
 684 =over 4
 685
 686 =item Arguments: $sql_fragment, @standalone_bind_values
 687
 688 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 689
 690 =back
 691
 692   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 693   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 694
 695 Pass a literal chunk of SQL to be added to the conditional part of the
 696 resultset query.
 697
 698 Example of how to use C<search> instead of C<search_literal>
 699
 700   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 701   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 702
 703 =cut
 704
 705 sub search_literal {
 706   my ($self, $sql, @bind) = @_;
 707   my $attr;
 708   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 709     $attr = pop @bind;
 710   }
 711   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 712 }
 713
 714 =head2 find
 715
 716 =over 4
 717
 718 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 719
 720 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 721
 722 =back
 723
 724 Finds and returns a single row based on supplied criteria. Takes either a
 725 hashref with the same format as L</create> (including inference of foreign
 726 keys from related objects), or a list of primary key values in the same
 727 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 728 declaration on the L</result_source>.
 729
 730 In either case an attempt is made to combine conditions already existing on
 731 the resultset with the condition passed to this method.
 732
 733 To aid with preparing the correct query for the storage you may supply the
 734 C<key> attribute, which is the name of a
 735 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 736 unique constraint corresponding to the
 737 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 738 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 739 to construct a query that satisfies the named unique constraint fully (
 740 non-NULL values for each column member of the constraint) an exception is
 741 thrown.
 742
 743 If no C<key> is specified, the search is carried over all unique constraints
 744 which are fully defined by the available condition.
 745
 746 If no such constraint is found, C<find> currently defaults to a simple
 747 C<< search->(\%column_values) >> which may or may not do what you expect.
 748 Note that this fallback behavior may be deprecated in further versions. If
 749 you need to search with arbitrary conditions - use L</search>. If the query
 750 resulting from this fallback produces more than one row, a warning to the
 751 effect is issued, though only the first row is constructed and returned as
 752 C<$result_object>.
 753
 754 In addition to C<key>, L</find> recognizes and applies standard
 755 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 756
 757 Note that if you have extra concerns about the correctness of the resulting
 758 query you need to specify the C<key> attribute and supply the entire condition
 759 as an argument to find (since it is not always possible to perform the
 760 combination of the resultset condition with the supplied one, especially if
 761 the resultset condition contains literal sql).
 762
 763 For example, to find a row by its primary key:
 764
 765   my $cd = $schema->resultset('CD')->find(5);
 766
 767 You can also find a row by a specific unique constraint:
 768
 769   my $cd = $schema->resultset('CD')->find(
 770     {
 771       artist => 'Massive Attack',
 772       title  => 'Mezzanine',
 773     },
 774     { key => 'cd_artist_title' }
 775   );
 776
 777 See also L</find_or_create> and L</update_or_create>.
 778
 779 =cut
 780
 781 sub find {
 782   my $self = shift;
 783   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 784
 785   my $rsrc = $self->result_source;
 786
 787   my $constraint_name;
 788   if (exists $attrs->{key}) {
 789     $constraint_name = defined $attrs->{key}
 790       ? $attrs->{key}
 791       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 792     ;
 793   }
 794
 795   # Parse out the condition from input
 796   my $call_cond;
 797
 798   if (ref $_[0] eq 'HASH') {
 799     $call_cond = { %{$_[0]} };
 800   }
 801   else {
 802     # if only values are supplied we need to default to 'primary'
 803     $constraint_name = 'primary' unless defined $constraint_name;
 804
 805     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 806
 807     $self->throw_exception(
 808       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 809     ) unless @c_cols;
 810
 811     $self->throw_exception (
 812       'find() expects either a column/value hashref, or a list of values '
 813     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 814     ) unless @c_cols == @_;
 815
 816     @{$call_cond}{@c_cols} = @_;
 817   }
 818
 819   # process relationship data if any
 820   for my $key (keys %$call_cond) {
 821     if (
 822       length ref($call_cond->{$key})
 823         and
 824       my $relinfo = $rsrc->relationship_info($key)
 825         and
 826       # implicitly skip has_many's (likely MC)
 827       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 828     ) {
 829       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 830         $relinfo->{cond}, $val, $key, $key
 831       );
 832
 833       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 834          if $crosstable or ref($rel_cond) ne 'HASH';
 835
 836       # supplement condition
 837       # relationship conditions take precedence (?)
 838       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 839     }
 840   }
 841
 842   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 843   my $final_cond;
 844   if (defined $constraint_name) {
 845     $final_cond = $self->_qualify_cond_columns (
 846
 847       $self->result_source->_minimal_valueset_satisfying_constraint(
 848         constraint_name => $constraint_name,
 849         values => ($self->_merge_with_rscond($call_cond))[0],
 850         carp_on_nulls => 1,
 851       ),
 852
 853       $alias,
 854     );
 855   }
 856   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 857     # This means that we got here after a merger of relationship conditions
 858     # in ::Relationship::Base::search_related (the row method), and furthermore
 859     # the relationship is of the 'single' type. This means that the condition
 860     # provided by the relationship (already attached to $self) is sufficient,
 861     # as there can be only one row in the database that would satisfy the
 862     # relationship
 863   }
 864   else {
 865     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 866
 867     # no key was specified - fall down to heuristics mode:
 868     # run through all unique queries registered on the resultset, and
 869     # 'OR' all qualifying queries together
 870     #
 871     # always start from 'primary' if it exists at all
 872     for my $c_name ( sort {
 873         $a eq 'primary' ? -1
 874       : $b eq 'primary' ? 1
 875       : $a cmp $b
 876     } $rsrc->unique_constraint_names) {
 877
 878       next if $seen_column_combinations{
 879         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 880       }++;
 881
 882       dbic_internal_try {
 883         push @unique_queries, $self->_qualify_cond_columns(
 884           $self->result_source->_minimal_valueset_satisfying_constraint(
 885             constraint_name => $c_name,
 886             values => ($self->_merge_with_rscond($call_cond))[0],
 887             columns_info => ($ci ||= $self->result_source->columns_info),
 888           ),
 889           $alias
 890         );
 891       }
 892       catch {
 893         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 894       };
 895     }
 896
 897     $final_cond =
 898         @unique_queries   ? \@unique_queries
 899       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 900       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 901     ;
 902   }
 903
 904   # Run the query, passing the result_class since it should propagate for find
 905   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 906   if ($rs->_resolved_attrs->{collapse}) {
 907     my $row = $rs->next;
 908     carp "Query returned more than one row" if $rs->next;
 909     return $row;
 910   }
 911   else {
 912     return $rs->single;
 913   }
 914 }
 915
 916 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 917 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 918 #
 919 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 920 # condition. It is provided for overrides until a saner way forward is devised
 921 #
 922 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 923 # the road. Please adjust your tests accordingly to catch this situation early
 924 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 925 #
 926 # The method will not be removed without an adequately complete replacement
 927 # for strict-mode enforcement
 928 sub _non_unique_find_fallback {
 929   my ($self, $cond, $attrs) = @_;
 930
 931   return $self->_qualify_cond_columns(
 932     $cond,
 933     exists $attrs->{alias}
 934       ? $attrs->{alias}
 935       : $self->{attrs}{alias}
 936   );
 937 }
 938
 939
 940 sub _qualify_cond_columns {
 941   my ($self, $cond, $alias) = @_;
 942
 943   my %aliased = %$cond;
 944   for (keys %aliased) {
 945     $aliased{"$alias.$_"} = delete $aliased{$_}
 946       if $_ !~ /\./;
 947   }
 948
 949   return \%aliased;
 950 }
 951
 952 sub _build_unique_cond {
 953   carp_unique sprintf
 954     '_build_unique_cond is a private method, and moreover is about to go '
 955   . 'away. Please contact the development team at %s if you believe you '
 956   . 'have a genuine use for this method, in order to discuss alternatives.',
 957     DBIx::Class::_ENV_::HELP_URL,
 958   ;
 959
 960   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 961
 962   $self->result_source->_minimal_valueset_satisfying_constraint(
 963     constraint_name => $constraint_name,
 964     values => $cond,
 965     carp_on_nulls => !$croak_on_null
 966   );
 967 }
 968
 969 =head2 search_related
 970
 971 =over 4
 972
 973 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 974
 975 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 976
 977 =back
 978
 979   $new_rs = $cd_rs->search_related('artist', {
 980     name => 'Emo-R-Us',
 981   });
 982
 983 Searches the specified relationship, optionally specifying a condition and
 984 attributes for matching records. See L</ATTRIBUTES> for more information.
 985
 986 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 987 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 988
 989 See also L</search_related_rs>.
 990
 991 =cut
 992
 993 sub search_related {
 994   return shift->related_resultset(shift)->search(@_);
 995 }
 996
 997 =head2 search_related_rs
 998
 999 This method works exactly the same as search_related, except that
1000 it guarantees a resultset, even in list context.
1001
1002 =cut
1003
1004 sub search_related_rs {
1005   return shift->related_resultset(shift)->search_rs(@_);
1006 }
1007
1008 =head2 cursor
1009
1010 =over 4
1011
1012 =item Arguments: none
1013
1014 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1015
1016 =back
1017
1018 Returns a storage-driven cursor to the given resultset. See
1019 L<DBIx::Class::Cursor> for more information.
1020
1021 =cut
1022
1023 sub cursor {
1024   my $self = shift;
1025
1026   return $self->{cursor} ||= do {
1027     my $attrs = $self->_resolved_attrs;
1028     $self->result_source->storage->select(
1029       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1030     );
1031   };
1032 }
1033
1034 =head2 single
1035
1036 =over 4
1037
1038 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1039
1040 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1041
1042 =back
1043
1044   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1045
1046 Inflates the first result without creating a cursor if the resultset has
1047 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1048 of L</search>.
1049
1050 While this method can take an optional search condition (just like L</search>)
1051 being a fast-code-path it does not recognize search attributes. If you need to
1052 add extra joins or similar, call L</search> and then chain-call L</single> on the
1053 L<DBIx::Class::ResultSet> returned.
1054
1055 =over
1056
1057 =item B<Note>
1058
1059 As of 0.08100, this method enforces the assumption that the preceding
1060 query returns only one row. If more than one row is returned, you will receive
1061 a warning:
1062
1063   Query returned more than one row
1064
1065 In this case, you should be using L</next> or L</find> instead, or if you really
1066 know what you are doing, use the L</rows> attribute to explicitly limit the size
1067 of the resultset.
1068
1069 This method will also throw an exception if it is called on a resultset prefetching
1070 has_many, as such a prefetch implies fetching multiple rows from the database in
1071 order to assemble the resulting object.
1072
1073 =back
1074
1075 =cut
1076
1077 sub single {
1078   my ($self, $where) = @_;
1079   if(@_ > 2) {
1080       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1081   }
1082
1083   my $attrs = { %{$self->_resolved_attrs} };
1084
1085   $self->throw_exception(
1086     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1087   ) if $attrs->{collapse};
1088
1089   if ($where) {
1090     if (defined $attrs->{where}) {
1091       $attrs->{where} = {
1092         '-and' =>
1093             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1094                $where, delete $attrs->{where} ]
1095       };
1096     } else {
1097       $attrs->{where} = $where;
1098     }
1099   }
1100
1101   my $data = [ $self->result_source->storage->select_single(
1102     $attrs->{from}, $attrs->{select},
1103     $attrs->{where}, $attrs
1104   )];
1105
1106   return undef unless @$data;
1107   $self->{_stashed_rows} = [ $data ];
1108   $self->_construct_results->[0];
1109 }
1110
1111 =head2 get_column
1112
1113 =over 4
1114
1115 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1116
1117 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1118
1119 =back
1120
1121   my $max_length = $rs->get_column('length')->max;
1122
1123 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1124
1125 =cut
1126
1127 sub get_column {
1128   my ($self, $column) = @_;
1129   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1130   return $new;
1131 }
1132
1133 =head2 search_like
1134
1135 =over 4
1136
1137 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1138
1139 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1140
1141 =back
1142
1143   # WHERE title LIKE '%blue%'
1144   $cd_rs = $rs->search_like({ title => '%blue%'});
1145
1146 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1147 that this is simply a convenience method retained for ex Class::DBI users.
1148 You most likely want to use L</search> with specific operators.
1149
1150 For more information, see L<DBIx::Class::Manual::Cookbook>.
1151
1152 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1153 instead. An example conversion is:
1154
1155   ->search_like({ foo => 'bar' });
1156
1157   # Becomes
1158
1159   ->search({ foo => { like => 'bar' } });
1160
1161 =cut
1162
1163 sub search_like {
1164   my $class = shift;
1165   carp_unique (
1166     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1167    .' Instead use ->search({ x => { -like => "y%" } })'
1168    .' (note the outer pair of {}s - they are important!)'
1169   );
1170   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1171   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1172   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1173   return $class->search($query, { %$attrs });
1174 }
1175
1176 =head2 slice
1177
1178 =over 4
1179
1180 =item Arguments: $first, $last
1181
1182 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1183
1184 =back
1185
1186 Returns a resultset or object list representing a subset of elements from the
1187 resultset slice is called on. Indexes are from 0, i.e., to get the first
1188 three records, call:
1189
1190   my ($one, $two, $three) = $rs->slice(0, 2);
1191
1192 =cut
1193
1194 sub slice {
1195   my ($self, $min, $max) = @_;
1196   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1197   $attrs->{offset} = $self->{attrs}{offset} || 0;
1198   $attrs->{offset} += $min;
1199   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1200   return $self->search(undef, $attrs);
1201 }
1202
1203 =head2 next
1204
1205 =over 4
1206
1207 =item Arguments: none
1208
1209 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1210
1211 =back
1212
1213 Returns the next element in the resultset (C<undef> is there is none).
1214
1215 Can be used to efficiently iterate over records in the resultset:
1216
1217   my $rs = $schema->resultset('CD')->search;
1218   while (my $cd = $rs->next) {
1219     print $cd->title;
1220   }
1221
1222 Note that you need to store the resultset object, and call C<next> on it.
1223 Calling C<< resultset('Table')->next >> repeatedly will always return the
1224 first record from the resultset.
1225
1226 =cut
1227
1228 sub next {
1229   my ($self) = @_;
1230
1231   if (my $cache = $self->get_cache) {
1232     $self->{all_cache_position} ||= 0;
1233     return $cache->[$self->{all_cache_position}++];
1234   }
1235
1236   if ($self->{attrs}{cache}) {
1237     delete $self->{pager};
1238     $self->{all_cache_position} = 1;
1239     return ($self->all)[0];
1240   }
1241
1242   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1243
1244   $self->{_stashed_results} = $self->_construct_results
1245     or return undef;
1246
1247   return shift @{$self->{_stashed_results}};
1248 }
1249
1250 # Constructs as many results as it can in one pass while respecting
1251 # cursor laziness. Several modes of operation:
1252 #
1253 # * Always builds everything present in @{$self->{_stashed_rows}}
1254 # * If called with $fetch_all true - pulls everything off the cursor and
1255 #   builds all result structures (or objects) in one pass
1256 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1257 #   and if the resultset is ordered properly by the left side:
1258 #   * Fetches stuff off the cursor until the "master object" changes,
1259 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1260 #   OR
1261 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1262 #     was requested (there is no other way to collapse except for an
1263 #     eager cursor)
1264 # * If no collapse is requested - just get the next row, construct and
1265 #   return
1266 sub _construct_results {
1267   my ($self, $fetch_all) = @_;
1268
1269   my $rsrc = $self->result_source;
1270   my $attrs = $self->_resolved_attrs;
1271
1272   if (
1273     ! $fetch_all
1274       and
1275     ! $attrs->{order_by}
1276       and
1277     $attrs->{collapse}
1278       and
1279     my @pcols = $rsrc->primary_columns
1280   ) {
1281     # default order for collapsing unless the user asked for something
1282     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1283     $attrs->{_ordered_for_collapse} = 1;
1284     $attrs->{_order_is_artificial} = 1;
1285   }
1286
1287   # this will be used as both initial raw-row collector AND as a RV of
1288   # _construct_results. Not regrowing the array twice matters a lot...
1289   # a surprising amount actually
1290   my $rows = delete $self->{_stashed_rows};
1291
1292   my $cursor; # we may not need one at all
1293
1294   my $did_fetch_all = $fetch_all;
1295
1296   if ($fetch_all) {
1297     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1298     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1299   }
1300   elsif( $attrs->{collapse} ) {
1301
1302     # a cursor will need to be closed over in case of collapse
1303     $cursor = $self->cursor;
1304
1305     $attrs->{_ordered_for_collapse} = (
1306       (
1307         $attrs->{order_by}
1308           and
1309         $rsrc->schema
1310               ->storage
1311                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1312       ) ? 1 : 0
1313     ) unless defined $attrs->{_ordered_for_collapse};
1314
1315     if (! $attrs->{_ordered_for_collapse}) {
1316       $did_fetch_all = 1;
1317
1318       # instead of looping over ->next, use ->all in stealth mode
1319       # *without* calling a ->reset afterwards
1320       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1321       if (! $cursor->{_done}) {
1322         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1323         $cursor->{_done} = 1;
1324       }
1325     }
1326   }
1327
1328   if (! $did_fetch_all and ! @{$rows||[]} ) {
1329     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1330     $cursor ||= $self->cursor;
1331     if (scalar (my @r = $cursor->next) ) {
1332       $rows = [ \@r ];
1333     }
1334   }
1335
1336   return undef unless @{$rows||[]};
1337
1338   # sanity check - people are too clever for their own good
1339   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1340
1341     my $multiplied_selectors;
1342     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1343       if (
1344         $aliastypes->{multiplying}{$sel_alias}
1345           or
1346         $aliastypes->{premultiplied}{$sel_alias}
1347       ) {
1348         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1349       }
1350     }
1351
1352     for my $i (0 .. $#{$attrs->{as}} ) {
1353       my $sel = $attrs->{select}[$i];
1354
1355       if (ref $sel eq 'SCALAR') {
1356         $sel = $$sel;
1357       }
1358       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1359         $sel = $$sel->[0];
1360       }
1361
1362       $self->throw_exception(
1363         'Result collapse not possible - selection from a has_many source redirected to the main object'
1364       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1365     }
1366   }
1367
1368   # hotspot - skip the setter
1369   my $res_class = $self->_result_class;
1370
1371   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1372     $res_class->can ('inflate_result')
1373       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1374   };
1375
1376   my $infmap = $attrs->{as};
1377
1378   $self->{_result_inflator}{is_core_row} = ( (
1379     $inflator_cref
1380       ==
1381     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1382   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1383
1384   $self->{_result_inflator}{is_hri} = ( (
1385     ! $self->{_result_inflator}{is_core_row}
1386       and
1387     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1388   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1389
1390
1391   if ($attrs->{_simple_passthrough_construction}) {
1392     # construct a much simpler array->hash folder for the one-table HRI cases right here
1393     if ($self->{_result_inflator}{is_hri}) {
1394       for my $r (@$rows) {
1395         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1396       }
1397     }
1398     # FIXME SUBOPTIMAL this is a very very very hot spot
1399     # while rather optimal we can *still* do much better, by
1400     # building a smarter Row::inflate_result(), and
1401     # switch to feeding it data via a much leaner interface
1402     #
1403     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1404     # this particular resultset size
1405     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1406       for my $r (@$rows) {
1407         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1408       }
1409     }
1410     else {
1411       eval sprintf (
1412         ( $self->{_result_inflator}{is_core_row}
1413           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1414           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1415           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1416         ),
1417         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1418       );
1419     }
1420   }
1421   else {
1422     my $parser_type =
1423         $self->{_result_inflator}{is_hri}       ? 'hri'
1424       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1425       :                                           'classic_nonpruning'
1426     ;
1427
1428     # $args and $attrs to _mk_row_parser are separated to delineate what is
1429     # core collapser stuff and what is dbic $rs specific
1430     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1431       eval => 1,
1432       inflate_map => $infmap,
1433       collapse => $attrs->{collapse},
1434       premultiplied => $attrs->{_main_source_premultiplied},
1435       hri_style => $self->{_result_inflator}{is_hri},
1436       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1437     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1438
1439     # column_info metadata historically hasn't been too reliable.
1440     # We need to start fixing this somehow (the collapse resolver
1441     # can't work without it). Add an explicit check for the *main*
1442     # result, hopefully this will gradually weed out such errors
1443     #
1444     # FIXME - this is a temporary kludge that reduces performance
1445     # It is however necessary for the time being
1446     my ($unrolled_non_null_cols_to_check, $err);
1447
1448     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1449
1450       $err =
1451         'Collapse aborted due to invalid ResultSource metadata - the following '
1452       . 'selections are declared non-nullable but NULLs were retrieved: '
1453       ;
1454
1455       my @violating_idx;
1456       COL: for my $i (@$check_non_null_cols) {
1457         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1458       }
1459
1460       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1461         if @violating_idx;
1462
1463       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1464
1465       utf8::upgrade($unrolled_non_null_cols_to_check)
1466         if DBIx::Class::_ENV_::STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE;
1467     }
1468
1469     my $next_cref =
1470       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1471     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1472 sub {
1473   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1474   my @r = $cursor->next or return;
1475   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1476     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1477   }
1478   \@r
1479 }
1480 EOS
1481     : sub {
1482         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1483         my @r = $cursor->next or return;
1484         \@r
1485       }
1486     ;
1487
1488     $self->{_row_parser}{$parser_type}{cref}->(
1489       $rows,
1490       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1491     );
1492
1493     # simple in-place substitution, does not regrow $rows
1494     if ($self->{_result_inflator}{is_core_row}) {
1495       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1496     }
1497     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1498     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1499       # the inflator may be a multiplier/reductor - put it in list ctx
1500       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1501     }
1502   }
1503
1504   # The @$rows check seems odd at first - why wouldn't we want to warn
1505   # regardless? The issue is things like find() etc, where the user
1506   # *knows* only one result will come back. In these cases the ->all
1507   # is not a pessimization, but rather something we actually want
1508   carp_unique(
1509     'Unable to properly collapse has_many results in iterator mode due '
1510   . 'to order criteria - performed an eager cursor slurp underneath. '
1511   . 'Consider using ->all() instead'
1512   ) if ( ! $fetch_all and @$rows > 1 );
1513
1514   return $rows;
1515 }
1516
1517 =head2 result_source
1518
1519 =over 4
1520
1521 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1522
1523 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1524
1525 =back
1526
1527 An accessor for the primary ResultSource object from which this ResultSet
1528 is derived.
1529
1530 =head2 result_class
1531
1532 =over 4
1533
1534 =item Arguments: $result_class?
1535
1536 =item Return Value: $result_class
1537
1538 =back
1539
1540 An accessor for the class to use when creating result objects. Defaults to
1541 C<< result_source->result_class >> - which in most cases is the name of the
1542 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1543
1544 Note that changing the result_class will also remove any components
1545 that were originally loaded in the source class via
1546 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1547 Any overloaded methods in the original source class will not run.
1548
1549 =cut
1550
1551 sub result_class {
1552   my ($self, $result_class) = @_;
1553   if ($result_class) {
1554
1555     # don't fire this for an object
1556     $self->ensure_class_loaded($result_class)
1557       unless ref($result_class);
1558
1559     if ($self->get_cache) {
1560       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1561     }
1562     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1563     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1564       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1565     }
1566
1567     $self->_result_class($result_class);
1568
1569     delete $self->{_result_inflator};
1570   }
1571   $self->_result_class;
1572 }
1573
1574 =head2 count
1575
1576 =over 4
1577
1578 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1579
1580 =item Return Value: $count
1581
1582 =back
1583
1584 Performs an SQL C<COUNT> with the same query as the resultset was built
1585 with to find the number of elements. Passing arguments is equivalent to
1586 C<< $rs->search ($cond, \%attrs)->count >>
1587
1588 =cut
1589
1590 sub count {
1591   my $self = shift;
1592   return $self->search(@_)->count if @_ and defined $_[0];
1593   return scalar @{ $self->get_cache } if $self->get_cache;
1594
1595   my $attrs = { %{ $self->_resolved_attrs } };
1596
1597   # this is a little optimization - it is faster to do the limit
1598   # adjustments in software, instead of a subquery
1599   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1600
1601   my $crs;
1602   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1603     $crs = $self->_count_subq_rs ($attrs);
1604   }
1605   else {
1606     $crs = $self->_count_rs ($attrs);
1607   }
1608   my $count = $crs->next;
1609
1610   $count -= $offset if $offset;
1611   $count = $rows if $rows and $rows < $count;
1612   $count = 0 if ($count < 0);
1613
1614   return $count;
1615 }
1616
1617 =head2 count_rs
1618
1619 =over 4
1620
1621 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1622
1623 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1624
1625 =back
1626
1627 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1628 This can be very handy for subqueries:
1629
1630   ->search( { amount => $some_rs->count_rs->as_query } )
1631
1632 As with regular resultsets the SQL query will be executed only after
1633 the resultset is accessed via L</next> or L</all>. That would return
1634 the same single value obtainable via L</count>.
1635
1636 =cut
1637
1638 sub count_rs {
1639   my $self = shift;
1640   return $self->search(@_)->count_rs if @_;
1641
1642   # this may look like a lack of abstraction (count() does about the same)
1643   # but in fact an _rs *must* use a subquery for the limits, as the
1644   # software based limiting can not be ported if this $rs is to be used
1645   # in a subquery itself (i.e. ->as_query)
1646   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1647     return $self->_count_subq_rs($self->{_attrs});
1648   }
1649   else {
1650     return $self->_count_rs($self->{_attrs});
1651   }
1652 }
1653
1654 #
1655 # returns a ResultSetColumn object tied to the count query
1656 #
1657 sub _count_rs {
1658   my ($self, $attrs) = @_;
1659
1660   my $rsrc = $self->result_source;
1661
1662   my $tmp_attrs = { %$attrs };
1663   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1664   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1665
1666   # overwrite the selector (supplied by the storage)
1667   $rsrc->resultset_class->new($rsrc, {
1668     %$tmp_attrs,
1669     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1670     as => 'count',
1671   })->get_column ('count');
1672 }
1673
1674 #
1675 # same as above but uses a subquery
1676 #
1677 sub _count_subq_rs {
1678   my ($self, $attrs) = @_;
1679
1680   my $rsrc = $self->result_source;
1681
1682   my $sub_attrs = { %$attrs };
1683   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1684   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1685
1686   # if we multi-prefetch we group_by something unique, as this is what we would
1687   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1688   if ( $attrs->{collapse}  ) {
1689     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1690       $rsrc->_identifying_column_set || $self->throw_exception(
1691         'Unable to construct a unique group_by criteria properly collapsing the '
1692       . 'has_many prefetch before count()'
1693       );
1694     } ]
1695   }
1696
1697   # Calculate subquery selector
1698   if (my $g = $sub_attrs->{group_by}) {
1699
1700     my $sql_maker = $rsrc->storage->sql_maker;
1701
1702     # necessary as the group_by may refer to aliased functions
1703     my $sel_index;
1704     for my $sel (@{$attrs->{select}}) {
1705       $sel_index->{$sel->{-as}} = $sel
1706         if (ref $sel eq 'HASH' and $sel->{-as});
1707     }
1708
1709     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1710     # also look for named aggregates referred in the having clause
1711     # having often contains scalarrefs - thus parse it out entirely
1712     my @parts = @$g;
1713     if ($attrs->{having}) {
1714       local $sql_maker->{having_bind};
1715       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1716       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1717       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1718         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1719         # if we don't unset it we screw up retarded but unfortunately working
1720         # 'MAX(foo.bar)' => { '>', 3 }
1721         $sql_maker->{name_sep} = '';
1722       }
1723
1724       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1725
1726       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1727       my %seen_having;
1728
1729       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1730       # and if all fails for an utterly naive quoted scalar-with-function
1731       while ($having_sql =~ /
1732         $rquote $sep $lquote (.+?) $rquote
1733           |
1734         [\s,] \w+ \. (\w+) [\s,]
1735           |
1736         [\s,] $lquote (.+?) $rquote [\s,]
1737       /gx) {
1738         my $part = $1 || $2 || $3;  # one of them matched if we got here
1739         unless ($seen_having{$part}++) {
1740           push @parts, $part;
1741         }
1742       }
1743     }
1744
1745     for (@parts) {
1746       my $colpiece = $sel_index->{$_} || $_;
1747
1748       # unqualify join-based group_by's. Arcane but possible query
1749       # also horrible horrible hack to alias a column (not a func.)
1750       # (probably need to introduce SQLA syntax)
1751       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1752         my $as = $colpiece;
1753         $as =~ s/\./__/;
1754         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1755       }
1756       push @{$sub_attrs->{select}}, $colpiece;
1757     }
1758   }
1759   else {
1760     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1761     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1762   }
1763
1764   return $rsrc->resultset_class
1765                ->new ($rsrc, $sub_attrs)
1766                 ->as_subselect_rs
1767                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1768                   ->get_column ('count');
1769 }
1770
1771
1772 =head2 count_literal
1773
1774 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1775 should only be used in that context. See L</search_literal> for further info.
1776
1777 =over 4
1778
1779 =item Arguments: $sql_fragment, @standalone_bind_values
1780
1781 =item Return Value: $count
1782
1783 =back
1784
1785 Counts the results in a literal query. Equivalent to calling L</search_literal>
1786 with the passed arguments, then L</count>.
1787
1788 =cut
1789
1790 sub count_literal { shift->search_literal(@_)->count; }
1791
1792 =head2 all
1793
1794 =over 4
1795
1796 =item Arguments: none
1797
1798 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1799
1800 =back
1801
1802 Returns all elements in the resultset.
1803
1804 =cut
1805
1806 sub all {
1807   my $self = shift;
1808   if(@_) {
1809     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1810   }
1811
1812   delete @{$self}{qw/_stashed_rows _stashed_results/};
1813
1814   if (my $c = $self->get_cache) {
1815     return @$c;
1816   }
1817
1818   $self->cursor->reset;
1819
1820   my $objs = $self->_construct_results('fetch_all') || [];
1821
1822   $self->set_cache($objs) if $self->{attrs}{cache};
1823
1824   return @$objs;
1825 }
1826
1827 =head2 reset
1828
1829 =over 4
1830
1831 =item Arguments: none
1832
1833 =item Return Value: $self
1834
1835 =back
1836
1837 Resets the resultset's cursor, so you can iterate through the elements again.
1838 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1839 another query.
1840
1841 =cut
1842
1843 sub reset {
1844   my ($self) = @_;
1845
1846   delete @{$self}{qw/_stashed_rows _stashed_results/};
1847   $self->{all_cache_position} = 0;
1848   $self->cursor->reset;
1849   return $self;
1850 }
1851
1852 =head2 first
1853
1854 =over 4
1855
1856 =item Arguments: none
1857
1858 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1859
1860 =back
1861
1862 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1863 an object for the first result (or C<undef> if the resultset is empty).
1864
1865 =cut
1866
1867 sub first {
1868   return $_[0]->reset->next;
1869 }
1870
1871
1872 # _rs_update_delete
1873 #
1874 # Determines whether and what type of subquery is required for the $rs operation.
1875 # If grouping is necessary either supplies its own, or verifies the current one
1876 # After all is done delegates to the proper storage method.
1877
1878 sub _rs_update_delete {
1879   my ($self, $op, $values) = @_;
1880
1881   my $rsrc = $self->result_source;
1882   my $storage = $rsrc->schema->storage;
1883
1884   my $attrs = { %{$self->_resolved_attrs} };
1885
1886   my $join_classifications;
1887   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1888
1889   # do we need a subquery for any reason?
1890   my $needs_subq = (
1891     defined $existing_group_by
1892       or
1893     # if {from} is unparseable wrap a subq
1894     ref($attrs->{from}) ne 'ARRAY'
1895       or
1896     # limits call for a subq
1897     $self->_has_resolved_attr(qw/rows offset/)
1898   );
1899
1900   # simplify the joinmap, so we can further decide if a subq is necessary
1901   if (!$needs_subq and @{$attrs->{from}} > 1) {
1902
1903     ($attrs->{from}, $join_classifications) =
1904       $storage->_prune_unused_joins ($attrs);
1905
1906     # any non-pruneable non-local restricting joins imply subq
1907     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1908   }
1909
1910   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1911   $needs_subq ||= (
1912     (ref $attrs->{from}[0]) ne 'HASH'
1913       or
1914     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1915   );
1916
1917   my ($cond, $guard);
1918   # do we need anything like a subquery?
1919   if (! $needs_subq) {
1920     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1921     # a condition containing 'me' or other table prefixes will not work
1922     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1923     $cond = do {
1924       my $sqla = $rsrc->storage->sql_maker;
1925       local $sqla->{_dequalify_idents} = 1;
1926       \[ $sqla->_recurse_where($self->{cond}) ];
1927     };
1928   }
1929   else {
1930     # we got this far - means it is time to wrap a subquery
1931     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1932       sprintf(
1933         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1934         $op,
1935         $rsrc->source_name,
1936       )
1937     );
1938
1939     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1940     delete $attrs->{$_} for qw/select as collapse/;
1941     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1942
1943     # this will be consumed by the pruner waaaaay down the stack
1944     $attrs->{_force_prune_multiplying_joins} = 1;
1945
1946     my $subrs = (ref $self)->new($rsrc, $attrs);
1947
1948     if (@$idcols == 1) {
1949       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1950     }
1951     elsif ($storage->_use_multicolumn_in) {
1952       # no syntax for calling this properly yet
1953       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1954       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1955         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1956         $subrs->as_query
1957       ),
1958     }
1959     else {
1960       # if all else fails - get all primary keys and operate over a ORed set
1961       # wrap in a transaction for consistency
1962       # this is where the group_by/multiplication starts to matter
1963       if (
1964         $existing_group_by
1965           or
1966         # we do not need to check pre-multipliers, since if the premulti is there, its
1967         # parent (who is multi) will be there too
1968         keys %{ $join_classifications->{multiplying} || {} }
1969       ) {
1970         # make sure if there is a supplied group_by it matches the columns compiled above
1971         # perfectly. Anything else can not be sanely executed on most databases so croak
1972         # right then and there
1973         if ($existing_group_by) {
1974           my @current_group_by = map
1975             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1976             @$existing_group_by
1977           ;
1978
1979           if (
1980             join ("\x00", sort @current_group_by)
1981               ne
1982             join ("\x00", sort @{$attrs->{columns}} )
1983           ) {
1984             $self->throw_exception (
1985               "You have just attempted a $op operation on a resultset which does group_by"
1986               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1987               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1988               . ' kind of queries. Please retry the operation with a modified group_by or'
1989               . ' without using one at all.'
1990             );
1991           }
1992         }
1993
1994         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1995       }
1996
1997       $guard = $storage->txn_scope_guard;
1998
1999       for my $row ($subrs->cursor->all) {
2000         push @$cond, { map
2001           { $idcols->[$_] => $row->[$_] }
2002           (0 .. $#$idcols)
2003         };
2004       }
2005     }
2006   }
2007
2008   my $res = $cond ? $storage->$op (
2009     $rsrc,
2010     $op eq 'update' ? $values : (),
2011     $cond,
2012   ) : '0E0';
2013
2014   $guard->commit if $guard;
2015
2016   return $res;
2017 }
2018
2019 =head2 update
2020
2021 =over 4
2022
2023 =item Arguments: \%values
2024
2025 =item Return Value: $underlying_storage_rv
2026
2027 =back
2028
2029 Sets the specified columns in the resultset to the supplied values in a
2030 single query. Note that this will not run any accessor/set_column/update
2031 triggers, nor will it update any result object instances derived from this
2032 resultset (this includes the contents of the L<resultset cache|/set_cache>
2033 if any). See L</update_all> if you need to execute any on-update
2034 triggers or cascades defined either by you or a
2035 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2036
2037 The return value is a pass through of what the underlying
2038 storage backend returned, and may vary. See L<DBI/execute> for the most
2039 common case.
2040
2041 =head3 CAVEAT
2042
2043 Note that L</update> does not process/deflate any of the values passed in.
2044 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2045 ensure manually that any value passed to this method will stringify to
2046 something the RDBMS knows how to deal with. A notable example is the
2047 handling of L<DateTime> objects, for more info see:
2048 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2049
2050 =cut
2051
2052 sub update {
2053   my ($self, $values) = @_;
2054   $self->throw_exception('Values for update must be a hash')
2055     unless ref $values eq 'HASH';
2056
2057   return $self->_rs_update_delete ('update', $values);
2058 }
2059
2060 =head2 update_all
2061
2062 =over 4
2063
2064 =item Arguments: \%values
2065
2066 =item Return Value: 1
2067
2068 =back
2069
2070 Fetches all objects and updates them one at a time via
2071 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2072 triggers, while L</update> will not.
2073
2074 =cut
2075
2076 sub update_all {
2077   my ($self, $values) = @_;
2078   $self->throw_exception('Values for update_all must be a hash')
2079     unless ref $values eq 'HASH';
2080
2081   my $guard = $self->result_source->schema->txn_scope_guard;
2082   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2083   $guard->commit;
2084   return 1;
2085 }
2086
2087 =head2 delete
2088
2089 =over 4
2090
2091 =item Arguments: none
2092
2093 =item Return Value: $underlying_storage_rv
2094
2095 =back
2096
2097 Deletes the rows matching this resultset in a single query. Note that this
2098 will not run any delete triggers, nor will it alter the
2099 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2100 derived from this resultset (this includes the contents of the
2101 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2102 execute any on-delete triggers or cascades defined either by you or a
2103 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2104
2105 The return value is a pass through of what the underlying storage backend
2106 returned, and may vary. See L<DBI/execute> for the most common case.
2107
2108 =cut
2109
2110 sub delete {
2111   my $self = shift;
2112   $self->throw_exception('delete does not accept any arguments')
2113     if @_;
2114
2115   return $self->_rs_update_delete ('delete');
2116 }
2117
2118 =head2 delete_all
2119
2120 =over 4
2121
2122 =item Arguments: none
2123
2124 =item Return Value: 1
2125
2126 =back
2127
2128 Fetches all objects and deletes them one at a time via
2129 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2130 triggers, while L</delete> will not.
2131
2132 =cut
2133
2134 sub delete_all {
2135   my $self = shift;
2136   $self->throw_exception('delete_all does not accept any arguments')
2137     if @_;
2138
2139   my $guard = $self->result_source->schema->txn_scope_guard;
2140   $_->delete for $self->all;
2141   $guard->commit;
2142   return 1;
2143 }
2144
2145 =head2 populate
2146
2147 =over 4
2148
2149 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2150
2151 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2152
2153 =back
2154
2155 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2156 arrayrefs.
2157
2158 =over
2159
2160 =item NOTE
2161
2162 The context of this method call has an important effect on what is
2163 submitted to storage. In void context data is fed directly to fastpath
2164 insertion routines provided by the underlying storage (most often
2165 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2166 L<insert|DBIx::Class::Row/insert> calls on the
2167 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2168 augmentation of these methods provided by components. For example if you
2169 are using something like L<DBIx::Class::UUIDColumns> to create primary
2170 keys for you, you will find that your PKs are empty.  In this case you
2171 will have to explicitly force scalar or list context in order to create
2172 those values.
2173
2174 =back
2175
2176 In non-void (scalar or list) context, this method is simply a wrapper
2177 for L</create>. Depending on list or scalar context either a list of
2178 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2179 containing these objects is returned.
2180
2181 When supplying data in "arrayref of arrayrefs" invocation style, the
2182 first element should be a list of column names and each subsequent
2183 element should be a data value in the earlier specified column order.
2184 For example:
2185
2186   $schema->resultset("Artist")->populate([
2187     [ qw( artistid name ) ],
2188     [ 100, 'A Formally Unknown Singer' ],
2189     [ 101, 'A singer that jumped the shark two albums ago' ],
2190     [ 102, 'An actually cool singer' ],
2191   ]);
2192
2193 For the arrayref of hashrefs style each hashref should be a structure
2194 suitable for passing to L</create>. Multi-create is also permitted with
2195 this syntax.
2196
2197   $schema->resultset("Artist")->populate([
2198      { artistid => 4, name => 'Manufactured Crap', cds => [
2199         { title => 'My First CD', year => 2006 },
2200         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2201       ],
2202      },
2203      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2204         { title => 'My parents sold me to a record company', year => 2005 },
2205         { title => 'Why Am I So Ugly?', year => 2006 },
2206         { title => 'I Got Surgery and am now Popular', year => 2007 }
2207       ],
2208      },
2209   ]);
2210
2211 If you attempt a void-context multi-create as in the example above (each
2212 Artist also has the related list of CDs), and B<do not> supply the
2213 necessary autoinc foreign key information, this method will proxy to the
2214 less efficient L</create>, and then throw the Result objects away. In this
2215 case there are obviously no benefits to using this method over L</create>.
2216
2217 =cut
2218
2219 sub populate {
2220   my $self = shift;
2221
2222   # this is naive and just a quick check
2223   # the types will need to be checked more thoroughly when the
2224   # multi-source populate gets added
2225   my $data = (
2226     ref $_[0] eq 'ARRAY'
2227       and
2228     ( @{$_[0]} or return )
2229       and
2230     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2231       and
2232     $_[0]
2233   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2234
2235   # FIXME - no cref handling
2236   # At this point assume either hashes or arrays
2237
2238   if(defined wantarray) {
2239     my (@results, $guard);
2240
2241     if (ref $data->[0] eq 'ARRAY') {
2242       # column names only, nothing to do
2243       return if @$data == 1;
2244
2245       $guard = $self->result_source->schema->storage->txn_scope_guard
2246         if @$data > 2;
2247
2248       @results = map
2249         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2250         @{$data}[1 .. $#$data]
2251       ;
2252     }
2253     else {
2254
2255       $guard = $self->result_source->schema->storage->txn_scope_guard
2256         if @$data > 1;
2257
2258       @results = map { $self->new_result($_)->insert } @$data;
2259     }
2260
2261     $guard->commit if $guard;
2262     return wantarray ? @results : \@results;
2263   }
2264
2265   # we have to deal with *possibly incomplete* related data
2266   # this means we have to walk the data structure twice
2267   # whether we want this or not
2268   # jnap, I hate you ;)
2269   my $rsrc = $self->result_source;
2270   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2271
2272   my ($colinfo, $colnames, $slices_with_rels);
2273   my $data_start = 0;
2274
2275   DATA_SLICE:
2276   for my $i (0 .. $#$data) {
2277
2278     my $current_slice_seen_rel_infos;
2279
2280 ### Determine/Supplement collists
2281 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2282     if( ref $data->[$i] eq 'ARRAY' ) {
2283
2284       # positional(!) explicit column list
2285       if ($i == 0) {
2286         # column names only, nothing to do
2287         return if @$data == 1;
2288
2289         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2290           for 0 .. $#{$data->[0]};
2291
2292         $data_start = 1;
2293
2294         next DATA_SLICE;
2295       }
2296       else {
2297         for (values %$colinfo) {
2298           if ($_->{is_rel} ||= (
2299             $rel_info->{$_->{name}}
2300               and
2301             (
2302               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2303                 or
2304               ref $data->[$i][$_->{pos}] eq 'HASH'
2305                 or
2306               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2307             )
2308               and
2309             1
2310           )) {
2311
2312             # moar sanity check... sigh
2313             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2314               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2315                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2316                 return my $throwaway = $self->populate(@_);
2317               }
2318             }
2319
2320             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2321           }
2322         }
2323       }
2324
2325      if ($current_slice_seen_rel_infos) {
2326         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2327
2328         # this is needed further down to decide whether or not to fallback to create()
2329         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2330           for 0 .. $#$colnames;
2331       }
2332     }
2333     elsif( ref $data->[$i] eq 'HASH' ) {
2334
2335       for ( sort keys %{$data->[$i]} ) {
2336
2337         $colinfo->{$_} ||= do {
2338
2339           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2340             if $data_start; # it will be 0 on AoH, 1 on AoA
2341
2342           push @$colnames, $_;
2343
2344           # RV
2345           { pos => $#$colnames, name => $_ }
2346         };
2347
2348         if ($colinfo->{$_}{is_rel} ||= (
2349           $rel_info->{$_}
2350             and
2351           (
2352             ref $data->[$i]{$_} eq 'ARRAY'
2353               or
2354             ref $data->[$i]{$_} eq 'HASH'
2355               or
2356             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2357           )
2358             and
2359           1
2360         )) {
2361
2362           # moar sanity check... sigh
2363           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2364             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2365               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2366               return my $throwaway = $self->populate(@_);
2367             }
2368           }
2369
2370           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2371         }
2372       }
2373
2374       if ($current_slice_seen_rel_infos) {
2375         push @$slices_with_rels, $data->[$i];
2376
2377         # this is needed further down to decide whether or not to fallback to create()
2378         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2379           for keys %{$data->[$i]};
2380       }
2381     }
2382     else {
2383       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2384     }
2385
2386     if ( grep
2387       { $_->{attrs}{is_depends_on} }
2388       @{ $current_slice_seen_rel_infos || [] }
2389     ) {
2390       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2391       return my $throwaway = $self->populate(@_);
2392     }
2393   }
2394
2395   if( $slices_with_rels ) {
2396
2397     # need to exclude the rel "columns"
2398     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2399
2400     # extra sanity check - ensure the main source is in fact identifiable
2401     # the localizing of nullability is insane, but oh well... the use-case is legit
2402     my $ci = $rsrc->columns_info($colnames);
2403
2404     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2405       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2406
2407     unless( $rsrc->_identifying_column_set($ci) ) {
2408       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2409       return my $throwaway = $self->populate(@_);
2410     }
2411   }
2412
2413 ### inherit the data locked in the conditions of the resultset
2414   my ($rs_data) = $self->_merge_with_rscond({});
2415   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2416
2417   # if anything left - decompose rs_data
2418   my $rs_data_vals;
2419   if (keys %$rs_data) {
2420      push @$rs_data_vals, $rs_data->{$_}
2421       for sort keys %$rs_data;
2422   }
2423
2424 ### start work
2425   my $guard;
2426   $guard = $rsrc->schema->storage->txn_scope_guard
2427     if $slices_with_rels;
2428
2429 ### main source data
2430   # FIXME - need to switch entirely to a coderef-based thing,
2431   # so that large sets aren't copied several times... I think
2432   $rsrc->storage->_insert_bulk(
2433     $rsrc,
2434     [ @$colnames, sort keys %$rs_data ],
2435     [ map {
2436       ref $data->[$_] eq 'ARRAY'
2437       ? (
2438           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2439         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2440         :                     $data->[$_]
2441       )
2442       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2443     } $data_start .. $#$data ],
2444   );
2445
2446 ### do the children relationships
2447   if ( $slices_with_rels ) {
2448     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2449       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2450
2451     for my $sl (@$slices_with_rels) {
2452
2453       my ($main_proto, $main_proto_rs);
2454       for my $rel (@rels) {
2455         next unless defined $sl->{$rel};
2456
2457         $main_proto ||= {
2458           %$rs_data,
2459           (map { $_ => $sl->{$_} } @$colnames),
2460         };
2461
2462         unless (defined $colinfo->{$rel}{rs}) {
2463
2464           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2465
2466           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2467             rel_name => $rel,
2468             self_alias => "\xFE", # irrelevant
2469             foreign_alias => "\xFF", # irrelevant
2470           )->{identity_map} || {} } };
2471
2472         }
2473
2474         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2475           {
2476             $_ => { '=' =>
2477               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2478                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2479                  ->as_query
2480             }
2481           }
2482           keys %{$colinfo->{$rel}{fk_map}}
2483         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2484
2485         1;
2486       }
2487     }
2488   }
2489
2490   $guard->commit if $guard;
2491 }
2492
2493 =head2 pager
2494
2495 =over 4
2496
2497 =item Arguments: none
2498
2499 =item Return Value: L<$pager|Data::Page>
2500
2501 =back
2502
2503 Returns a L<Data::Page> object for the current resultset. Only makes
2504 sense for queries with a C<page> attribute.
2505
2506 To get the full count of entries for a paged resultset, call
2507 C<total_entries> on the L<Data::Page> object.
2508
2509 =cut
2510
2511 sub pager {
2512   my ($self) = @_;
2513
2514   return $self->{pager} if $self->{pager};
2515
2516   my $attrs = $self->{attrs};
2517   if (!defined $attrs->{page}) {
2518     $self->throw_exception("Can't create pager for non-paged rs");
2519   }
2520   elsif ($attrs->{page} <= 0) {
2521     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2522   }
2523   $attrs->{rows} ||= 10;
2524
2525   # throw away the paging flags and re-run the count (possibly
2526   # with a subselect) to get the real total count
2527   my $count_attrs = { %$attrs };
2528   delete @{$count_attrs}{qw/rows offset page pager/};
2529
2530   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2531
2532   require DBIx::Class::ResultSet::Pager;
2533   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2534     sub { $total_rs->count },  #lazy-get the total
2535     $attrs->{rows},
2536     $self->{attrs}{page},
2537   );
2538 }
2539
2540 =head2 page
2541
2542 =over 4
2543
2544 =item Arguments: $page_number
2545
2546 =item Return Value: L<$resultset|/search>
2547
2548 =back
2549
2550 Returns a resultset for the $page_number page of the resultset on which page
2551 is called, where each page contains a number of rows equal to the 'rows'
2552 attribute set on the resultset (10 by default).
2553
2554 =cut
2555
2556 sub page {
2557   my ($self, $page) = @_;
2558   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2559 }
2560
2561 =head2 new_result
2562
2563 =over 4
2564
2565 =item Arguments: \%col_data
2566
2567 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2568
2569 =back
2570
2571 Creates a new result object in the resultset's result class and returns
2572 it. The row is not inserted into the database at this point, call
2573 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2574 will tell you whether the result object has been inserted or not.
2575
2576 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2577
2578 =cut
2579
2580 sub new_result {
2581   my ($self, $values) = @_;
2582
2583   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2584     if @_ > 2;
2585
2586   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2587     unless (ref $values eq 'HASH');
2588
2589   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2590
2591   my $new = $self->result_class->new({
2592     %$merged_cond,
2593     ( @$cols_from_relations
2594       ? (-cols_from_relations => $cols_from_relations)
2595       : ()
2596     ),
2597     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2598   });
2599
2600   if (
2601     reftype($new) eq 'HASH'
2602       and
2603     ! keys %$new
2604       and
2605     blessed($new)
2606   ) {
2607     carp_unique (sprintf (
2608       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2609       $self->result_class,
2610     ));
2611   }
2612
2613   $new;
2614 }
2615
2616 # _merge_with_rscond
2617 #
2618 # Takes a simple hash of K/V data and returns its copy merged with the
2619 # condition already present on the resultset. Additionally returns an
2620 # arrayref of value/condition names, which were inferred from related
2621 # objects (this is needed for in-memory related objects)
2622 sub _merge_with_rscond {
2623   my ($self, $data) = @_;
2624
2625   my ($implied_data, @cols_from_relations);
2626
2627   my $alias = $self->{attrs}{alias};
2628
2629   if (! defined $self->{cond}) {
2630     # just massage $data below
2631   }
2632   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2633     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2634     @cols_from_relations = keys %{ $implied_data || {} };
2635   }
2636   else {
2637     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2638     $implied_data = { map {
2639       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2640     } keys %$eqs };
2641   }
2642
2643   return (
2644     { map
2645       { %{ $self->_remove_alias($_, $alias) } }
2646       # precedence must be given to passed values over values inherited from
2647       # the cond, so the order here is important.
2648       ( $implied_data||(), $data)
2649     },
2650     \@cols_from_relations
2651   );
2652 }
2653
2654 # _has_resolved_attr
2655 #
2656 # determines if the resultset defines at least one
2657 # of the attributes supplied
2658 #
2659 # used to determine if a subquery is necessary
2660 #
2661 # supports some virtual attributes:
2662 #   -join
2663 #     This will scan for any joins being present on the resultset.
2664 #     It is not a mere key-search but a deep inspection of {from}
2665 #
2666
2667 sub _has_resolved_attr {
2668   my ($self, @attr_names) = @_;
2669
2670   my $attrs = $self->_resolved_attrs;
2671
2672   my %extra_checks;
2673
2674   for my $n (@attr_names) {
2675     if (grep { $n eq $_ } (qw/-join/) ) {
2676       $extra_checks{$n}++;
2677       next;
2678     }
2679
2680     my $attr =  $attrs->{$n};
2681
2682     next if not defined $attr;
2683
2684     if (ref $attr eq 'HASH') {
2685       return 1 if keys %$attr;
2686     }
2687     elsif (ref $attr eq 'ARRAY') {
2688       return 1 if @$attr;
2689     }
2690     else {
2691       return 1 if $attr;
2692     }
2693   }
2694
2695   # a resolved join is expressed as a multi-level from
2696   return 1 if (
2697     $extra_checks{-join}
2698       and
2699     ref $attrs->{from} eq 'ARRAY'
2700       and
2701     @{$attrs->{from}} > 1
2702   );
2703
2704   return 0;
2705 }
2706
2707 # _remove_alias
2708 #
2709 # Remove the specified alias from the specified query hash. A copy is made so
2710 # the original query is not modified.
2711
2712 sub _remove_alias {
2713   my ($self, $query, $alias) = @_;
2714
2715   my %orig = %{ $query || {} };
2716   my %unaliased;
2717
2718   foreach my $key (keys %orig) {
2719     if ($key !~ /\./) {
2720       $unaliased{$key} = $orig{$key};
2721       next;
2722     }
2723     $unaliased{$1} = $orig{$key}
2724       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2725   }
2726
2727   return \%unaliased;
2728 }
2729
2730 =head2 as_query
2731
2732 =over 4
2733
2734 =item Arguments: none
2735
2736 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2737
2738 =back
2739
2740 Returns the SQL query and bind vars associated with the invocant.
2741
2742 This is generally used as the RHS for a subquery.
2743
2744 =cut
2745
2746 sub as_query {
2747   my $self = shift;
2748
2749   my $attrs = { %{ $self->_resolved_attrs } };
2750
2751   my $aq = $self->result_source->storage->_select_args_to_query (
2752     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2753   );
2754
2755   $aq;
2756 }
2757
2758 =head2 find_or_new
2759
2760 =over 4
2761
2762 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2763
2764 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2765
2766 =back
2767
2768   my $artist = $schema->resultset('Artist')->find_or_new(
2769     { artist => 'fred' }, { key => 'artists' });
2770
2771   $cd->cd_to_producer->find_or_new({ producer => $producer },
2772                                    { key => 'primary' });
2773
2774 Find an existing record from this resultset using L</find>. if none exists,
2775 instantiate a new result object and return it. The object will not be saved
2776 into your storage until you call L<DBIx::Class::Row/insert> on it.
2777
2778 You most likely want this method when looking for existing rows using a unique
2779 constraint that is not the primary key, or looking for related rows.
2780
2781 If you want objects to be saved immediately, use L</find_or_create> instead.
2782
2783 B<Note>: Make sure to read the documentation of L</find> and understand the
2784 significance of the C<key> attribute, as its lack may skew your search, and
2785 subsequently result in spurious new objects.
2786
2787 B<Note>: Take care when using C<find_or_new> with a table having
2788 columns with default values that you intend to be automatically
2789 supplied by the database (e.g. an auto_increment primary key column).
2790 In normal usage, the value of such columns should NOT be included at
2791 all in the call to C<find_or_new>, even when set to C<undef>.
2792
2793 =cut
2794
2795 sub find_or_new {
2796   my $self     = shift;
2797   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2798   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2799   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2800     return $row;
2801   }
2802   return $self->new_result($hash);
2803 }
2804
2805 =head2 create
2806
2807 =over 4
2808
2809 =item Arguments: \%col_data
2810
2811 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2812
2813 =back
2814
2815 Attempt to create a single new row or a row with multiple related rows
2816 in the table represented by the resultset (and related tables). This
2817 will not check for duplicate rows before inserting, use
2818 L</find_or_create> to do that.
2819
2820 To create one row for this resultset, pass a hashref of key/value
2821 pairs representing the columns of the table and the values you wish to
2822 store. If the appropriate relationships are set up, foreign key fields
2823 can also be passed an object representing the foreign row, and the
2824 value will be set to its primary key.
2825
2826 To create related objects, pass a hashref of related-object column values
2827 B<keyed on the relationship name>. If the relationship is of type C<multi>
2828 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2829 The process will correctly identify columns holding foreign keys, and will
2830 transparently populate them from the keys of the corresponding relation.
2831 This can be applied recursively, and will work correctly for a structure
2832 with an arbitrary depth and width, as long as the relationships actually
2833 exists and the correct column data has been supplied.
2834
2835 Instead of hashrefs of plain related data (key/value pairs), you may
2836 also pass new or inserted objects. New objects (not inserted yet, see
2837 L</new_result>), will be inserted into their appropriate tables.
2838
2839 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2840
2841 Example of creating a new row.
2842
2843   $person_rs->create({
2844     name=>"Some Person",
2845     email=>"somebody@someplace.com"
2846   });
2847
2848 Example of creating a new row and also creating rows in a related C<has_many>
2849 or C<has_one> resultset.  Note Arrayref.
2850
2851   $artist_rs->create(
2852      { artistid => 4, name => 'Manufactured Crap', cds => [
2853         { title => 'My First CD', year => 2006 },
2854         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2855       ],
2856      },
2857   );
2858
2859 Example of creating a new row and also creating a row in a related
2860 C<belongs_to> resultset. Note Hashref.
2861
2862   $cd_rs->create({
2863     title=>"Music for Silly Walks",
2864     year=>2000,
2865     artist => {
2866       name=>"Silly Musician",
2867     }
2868   });
2869
2870 =over
2871
2872 =item WARNING
2873
2874 When subclassing ResultSet never attempt to override this method. Since
2875 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2876 lot of the internals simply never call it, so your override will be
2877 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2878 or L<DBIx::Class::Row/insert> depending on how early in the
2879 L</create> process you need to intervene. See also warning pertaining to
2880 L</new>.
2881
2882 =back
2883
2884 =cut
2885
2886 sub create {
2887   #my ($self, $col_data) = @_;
2888   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2889   return shift->new_result(shift)->insert;
2890 }
2891
2892 =head2 find_or_create
2893
2894 =over 4
2895
2896 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2897
2898 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2899
2900 =back
2901
2902   $cd->cd_to_producer->find_or_create({ producer => $producer },
2903                                       { key => 'primary' });
2904
2905 Tries to find a record based on its primary key or unique constraints; if none
2906 is found, creates one and returns that instead.
2907
2908   my $cd = $schema->resultset('CD')->find_or_create({
2909     cdid   => 5,
2910     artist => 'Massive Attack',
2911     title  => 'Mezzanine',
2912     year   => 2005,
2913   });
2914
2915 Also takes an optional C<key> attribute, to search by a specific key or unique
2916 constraint. For example:
2917
2918   my $cd = $schema->resultset('CD')->find_or_create(
2919     {
2920       artist => 'Massive Attack',
2921       title  => 'Mezzanine',
2922     },
2923     { key => 'cd_artist_title' }
2924   );
2925
2926 B<Note>: Make sure to read the documentation of L</find> and understand the
2927 significance of the C<key> attribute, as its lack may skew your search, and
2928 subsequently result in spurious row creation.
2929
2930 B<Note>: Because find_or_create() reads from the database and then
2931 possibly inserts based on the result, this method is subject to a race
2932 condition. Another process could create a record in the table after
2933 the find has completed and before the create has started. To avoid
2934 this problem, use find_or_create() inside a transaction.
2935
2936 B<Note>: Take care when using C<find_or_create> with a table having
2937 columns with default values that you intend to be automatically
2938 supplied by the database (e.g. an auto_increment primary key column).
2939 In normal usage, the value of such columns should NOT be included at
2940 all in the call to C<find_or_create>, even when set to C<undef>.
2941
2942 See also L</find> and L</update_or_create>. For information on how to declare
2943 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2944
2945 If you need to know if an existing row was found or a new one created use
2946 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2947 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2948 database!
2949
2950   my $cd = $schema->resultset('CD')->find_or_new({
2951     cdid   => 5,
2952     artist => 'Massive Attack',
2953     title  => 'Mezzanine',
2954     year   => 2005,
2955   });
2956
2957   if( !$cd->in_storage ) {
2958       # do some stuff
2959       $cd->insert;
2960   }
2961
2962 =cut
2963
2964 sub find_or_create {
2965   my $self     = shift;
2966   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2967   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2968   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2969     return $row;
2970   }
2971   return $self->new_result($hash)->insert;
2972 }
2973
2974 =head2 update_or_create
2975
2976 =over 4
2977
2978 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2979
2980 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2981
2982 =back
2983
2984   $resultset->update_or_create({ col => $val, ... });
2985
2986 Like L</find_or_create>, but if a row is found it is immediately updated via
2987 C<< $found_row->update (\%col_data) >>.
2988
2989
2990 Takes an optional C<key> attribute to search on a specific unique constraint.
2991 For example:
2992
2993   # In your application
2994   my $cd = $schema->resultset('CD')->update_or_create(
2995     {
2996       artist => 'Massive Attack',
2997       title  => 'Mezzanine',
2998       year   => 1998,
2999     },
3000     { key => 'cd_artist_title' }
3001   );
3002
3003   $cd->cd_to_producer->update_or_create({
3004     producer => $producer,
3005     name => 'harry',
3006   }, {
3007     key => 'primary',
3008   });
3009
3010 B<Note>: Make sure to read the documentation of L</find> and understand the
3011 significance of the C<key> attribute, as its lack may skew your search, and
3012 subsequently result in spurious row creation.
3013
3014 B<Note>: Take care when using C<update_or_create> with a table having
3015 columns with default values that you intend to be automatically
3016 supplied by the database (e.g. an auto_increment primary key column).
3017 In normal usage, the value of such columns should NOT be included at
3018 all in the call to C<update_or_create>, even when set to C<undef>.
3019
3020 See also L</find> and L</find_or_create>. For information on how to declare
3021 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3022
3023 If you need to know if an existing row was updated or a new one created use
3024 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3025 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3026 database!
3027
3028 =cut
3029
3030 sub update_or_create {
3031   my $self = shift;
3032   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3033   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3034
3035   my $row = $self->find($cond, $attrs);
3036   if (defined $row) {
3037     $row->update($cond);
3038     return $row;
3039   }
3040
3041   return $self->new_result($cond)->insert;
3042 }
3043
3044 =head2 update_or_new
3045
3046 =over 4
3047
3048 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3049
3050 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3051
3052 =back
3053
3054   $resultset->update_or_new({ col => $val, ... });
3055
3056 Like L</find_or_new> but if a row is found it is immediately updated via
3057 C<< $found_row->update (\%col_data) >>.
3058
3059 For example:
3060
3061   # In your application
3062   my $cd = $schema->resultset('CD')->update_or_new(
3063     {
3064       artist => 'Massive Attack',
3065       title  => 'Mezzanine',
3066       year   => 1998,
3067     },
3068     { key => 'cd_artist_title' }
3069   );
3070
3071   if ($cd->in_storage) {
3072       # the cd was updated
3073   }
3074   else {
3075       # the cd is not yet in the database, let's insert it
3076       $cd->insert;
3077   }
3078
3079 B<Note>: Make sure to read the documentation of L</find> and understand the
3080 significance of the C<key> attribute, as its lack may skew your search, and
3081 subsequently result in spurious new objects.
3082
3083 B<Note>: Take care when using C<update_or_new> with a table having
3084 columns with default values that you intend to be automatically
3085 supplied by the database (e.g. an auto_increment primary key column).
3086 In normal usage, the value of such columns should NOT be included at
3087 all in the call to C<update_or_new>, even when set to C<undef>.
3088
3089 See also L</find>, L</find_or_create> and L</find_or_new>.
3090
3091 =cut
3092
3093 sub update_or_new {
3094     my $self  = shift;
3095     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3096     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3097
3098     my $row = $self->find( $cond, $attrs );
3099     if ( defined $row ) {
3100         $row->update($cond);
3101         return $row;
3102     }
3103
3104     return $self->new_result($cond);
3105 }
3106
3107 =head2 get_cache
3108
3109 =over 4
3110
3111 =item Arguments: none
3112
3113 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3114
3115 =back
3116
3117 Gets the contents of the cache for the resultset, if the cache is set.
3118
3119 The cache is populated either by using the L</prefetch> attribute to
3120 L</search> or by calling L</set_cache>.
3121
3122 =cut
3123
3124 sub get_cache {
3125   shift->{all_cache};
3126 }
3127
3128 =head2 set_cache
3129
3130 =over 4
3131
3132 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3133
3134 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3135
3136 =back
3137
3138 Sets the contents of the cache for the resultset. Expects an arrayref
3139 of objects of the same class as those produced by the resultset. Note that
3140 if the cache is set, the resultset will return the cached objects rather
3141 than re-querying the database even if the cache attr is not set.
3142
3143 The contents of the cache can also be populated by using the
3144 L</prefetch> attribute to L</search>.
3145
3146 =cut
3147
3148 sub set_cache {
3149   my ( $self, $data ) = @_;
3150   $self->throw_exception("set_cache requires an arrayref")
3151       if defined($data) && (ref $data ne 'ARRAY');
3152   $self->{all_cache} = $data;
3153 }
3154
3155 =head2 clear_cache
3156
3157 =over 4
3158
3159 =item Arguments: none
3160
3161 =item Return Value: undef
3162
3163 =back
3164
3165 Clears the cache for the resultset.
3166
3167 =cut
3168
3169 sub clear_cache {
3170   shift->set_cache(undef);
3171 }
3172
3173 =head2 is_paged
3174
3175 =over 4
3176
3177 =item Arguments: none
3178
3179 =item Return Value: true, if the resultset has been paginated
3180
3181 =back
3182
3183 =cut
3184
3185 sub is_paged {
3186   my ($self) = @_;
3187   return !!$self->{attrs}{page};
3188 }
3189
3190 =head2 is_ordered
3191
3192 =over 4
3193
3194 =item Arguments: none
3195
3196 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3197
3198 =back
3199
3200 =cut
3201
3202 sub is_ordered {
3203   my ($self) = @_;
3204   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3205 }
3206
3207 =head2 related_resultset
3208
3209 =over 4
3210
3211 =item Arguments: $rel_name
3212
3213 =item Return Value: L<$resultset|/search>
3214
3215 =back
3216
3217 Returns a related resultset for the supplied relationship name.
3218
3219   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3220
3221 =cut
3222
3223 sub related_resultset {
3224   $_[0]->throw_exception(
3225     'Extra arguments to $rs->related_resultset() were always quietly '
3226   . 'discarded without consideration, you need to switch to '
3227   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3228   ) if @_ > 2;
3229
3230   return $_[0]->{related_resultsets}{$_[1]}
3231     if defined $_[0]->{related_resultsets}{$_[1]};
3232
3233   my ($self, $rel) = @_;
3234
3235   return $self->{related_resultsets}{$rel} = do {
3236     my $rsrc = $self->result_source;
3237     my $rel_info = $rsrc->relationship_info($rel);
3238
3239     $self->throw_exception(
3240       "search_related: result source '" . $rsrc->source_name .
3241         "' has no such relationship $rel")
3242       unless $rel_info;
3243
3244     my $attrs = $self->_chain_relationship($rel);
3245
3246     my $storage = $rsrc->schema->storage;
3247
3248     # Previously this atribute was deleted (instead of being set as it is now)
3249     # Doing so seems to be harmless in all available test permutations
3250     # See also 01d59a6a6 and mst's comment below
3251     #
3252     $attrs->{alias} = $storage->relname_to_table_alias(
3253       $rel,
3254       $attrs->{seen_join}{$rel}
3255     );
3256
3257     # since this is search_related, and we already slid the select window inwards
3258     # (the select/as attrs were deleted in the beginning), we need to flip all
3259     # left joins to inner, so we get the expected results
3260     # read the comment on top of the actual function to see what this does
3261     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3262
3263     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3264     delete $attrs->{result_class};
3265
3266     my $new = do {
3267
3268       # The reason we do this now instead of passing the alias to the
3269       # search_rs below is that if you wrap/overload resultset on the
3270       # source you need to know what alias it's -going- to have for things
3271       # to work sanely (e.g. RestrictWithObject wants to be able to add
3272       # extra query restrictions, and these may need to be $alias.)
3273       #                                       -- mst ~ 2007 (01d59a6a6)
3274       #
3275       # FIXME - this seems to be no longer neccessary (perhaps due to the
3276       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3277       # dependent (as of Jun 2015 ) does not yield any difference with or
3278       # without this line. Nevertheless keep it as is for now, to minimize
3279       # churn, there is enough potential for breakage in 0.0829xx as it is
3280       #                                       -- ribasushi Jun 2015
3281       #
3282       my $rel_source = $rsrc->related_source($rel);
3283       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3284
3285       $rel_source->resultset->search_rs( undef, $attrs );
3286     };
3287
3288     if (my $cache = $self->get_cache) {
3289       my @related_cache = map
3290         { $_->related_resultset($rel)->get_cache || () }
3291         @$cache
3292       ;
3293
3294       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3295     }
3296
3297     $new;
3298   };
3299 }
3300
3301 =head2 current_source_alias
3302
3303 =over 4
3304
3305 =item Arguments: none
3306
3307 =item Return Value: $source_alias
3308
3309 =back
3310
3311 Returns the current table alias for the result source this resultset is built
3312 on, that will be used in the SQL query. Usually it is C<me>.
3313
3314 Currently the source alias that refers to the result set returned by a
3315 L</search>/L</find> family method depends on how you got to the resultset: it's
3316 C<me> by default, but eg. L</search_related> aliases it to the related result
3317 source name (and keeps C<me> referring to the original result set). The long
3318 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3319 (and make this method unnecessary).
3320
3321 Thus it's currently necessary to use this method in predefined queries (see
3322 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3323 source alias of the current result set:
3324
3325   # in a result set class
3326   sub modified_by {
3327     my ($self, $user) = @_;
3328
3329     my $me = $self->current_source_alias;
3330
3331     return $self->search({
3332       "$me.modified" => $user->id,
3333     });
3334   }
3335
3336 The alias of L<newly created resultsets|/search> can be altered by the
3337 L<alias attribute|/alias>.
3338
3339 =cut
3340
3341 sub current_source_alias {
3342   return (shift->{attrs} || {})->{alias} || 'me';
3343 }
3344
3345 =head2 as_subselect_rs
3346
3347 =over 4
3348
3349 =item Arguments: none
3350
3351 =item Return Value: L<$resultset|/search>
3352
3353 =back
3354
3355 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3356 "virtual view" by including it as a subquery within the from clause.  From this
3357 point on, any joined tables are inaccessible to ->search on the resultset (as if
3358 it were simply where-filtered without joins).  For example:
3359
3360  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3361
3362  # 'x' now pollutes the query namespace
3363
3364  # So the following works as expected
3365  my $ok_rs = $rs->search({'x.other' => 1});
3366
3367  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3368  # def) we look for one row with contradictory terms and join in another table
3369  # (aliased 'x_2') which we never use
3370  my $broken_rs = $rs->search({'x.name' => 'def'});
3371
3372  my $rs2 = $rs->as_subselect_rs;
3373
3374  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3375  my $not_joined_rs = $rs2->search({'x.other' => 1});
3376
3377  # works as expected: finds a 'table' row related to two x rows (abc and def)
3378  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3379
3380 Another example of when one might use this would be to select a subset of
3381 columns in a group by clause:
3382
3383  my $rs = $schema->resultset('Bar')->search(undef, {
3384    group_by => [qw{ id foo_id baz_id }],
3385  })->as_subselect_rs->search(undef, {
3386    columns => [qw{ id foo_id }]
3387  });
3388
3389 In the above example normally columns would have to be equal to the group by,
3390 but because we isolated the group by into a subselect the above works.
3391
3392 =cut
3393
3394 sub as_subselect_rs {
3395   my $self = shift;
3396
3397   my $attrs = $self->_resolved_attrs;
3398
3399   my $fresh_rs = (ref $self)->new (
3400     $self->result_source
3401   );
3402
3403   # these pieces will be locked in the subquery
3404   delete $fresh_rs->{cond};
3405   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3406
3407   return $fresh_rs->search( {}, {
3408     from => [{
3409       $attrs->{alias} => $self->as_query,
3410       -alias  => $attrs->{alias},
3411       -rsrc   => $self->result_source,
3412     }],
3413     alias => $attrs->{alias},
3414   });
3415 }
3416
3417 # This code is called by search_related, and makes sure there
3418 # is clear separation between the joins before, during, and
3419 # after the relationship. This information is needed later
3420 # in order to properly resolve prefetch aliases (any alias
3421 # with a relation_chain_depth less than the depth of the
3422 # current prefetch is not considered)
3423 #
3424 # The increments happen twice per join. An even number means a
3425 # relationship specified via a search_related, whereas an odd
3426 # number indicates a join/prefetch added via attributes
3427 #
3428 # Also this code will wrap the current resultset (the one we
3429 # chain to) in a subselect IFF it contains limiting attributes
3430 sub _chain_relationship {
3431   my ($self, $rel) = @_;
3432   my $source = $self->result_source;
3433   my $attrs = { %{$self->{attrs}||{}} };
3434
3435   # we need to take the prefetch the attrs into account before we
3436   # ->_resolve_join as otherwise they get lost - captainL
3437   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3438
3439   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3440
3441   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3442
3443   my $from;
3444   my @force_subq_attrs = qw/offset rows group_by having/;
3445
3446   if (
3447     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3448       ||
3449     $self->_has_resolved_attr (@force_subq_attrs)
3450   ) {
3451     # Nuke the prefetch (if any) before the new $rs attrs
3452     # are resolved (prefetch is useless - we are wrapping
3453     # a subquery anyway).
3454     my $rs_copy = $self->search;
3455     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3456       $rs_copy->{attrs}{join},
3457       delete $rs_copy->{attrs}{prefetch},
3458     );
3459
3460     $from = [{
3461       -rsrc   => $source,
3462       -alias  => $attrs->{alias},
3463       $attrs->{alias} => $rs_copy->as_query,
3464     }];
3465     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3466     $seen->{-relation_chain_depth} = 0;
3467   }
3468   elsif ($attrs->{from}) {  #shallow copy suffices
3469     $from = [ @{$attrs->{from}} ];
3470   }
3471   else {
3472     $from = [{
3473       -rsrc  => $source,
3474       -alias => $attrs->{alias},
3475       $attrs->{alias} => $source->from,
3476     }];
3477   }
3478
3479   my $jpath = ($seen->{-relation_chain_depth})
3480     ? $from->[-1][0]{-join_path}
3481     : [];
3482
3483   my @requested_joins = $source->_resolve_join(
3484     $join,
3485     $attrs->{alias},
3486     $seen,
3487     $jpath,
3488   );
3489
3490   push @$from, @requested_joins;
3491
3492   $seen->{-relation_chain_depth}++;
3493
3494   # if $self already had a join/prefetch specified on it, the requested
3495   # $rel might very well be already included. What we do in this case
3496   # is effectively a no-op (except that we bump up the chain_depth on
3497   # the join in question so we could tell it *is* the search_related)
3498   my $already_joined;
3499
3500   # we consider the last one thus reverse
3501   for my $j (reverse @requested_joins) {
3502     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3503     if ($rel eq $last_j) {
3504       $j->[0]{-relation_chain_depth}++;
3505       $already_joined++;
3506       last;
3507     }
3508   }
3509
3510   unless ($already_joined) {
3511     push @$from, $source->_resolve_join(
3512       $rel,
3513       $attrs->{alias},
3514       $seen,
3515       $jpath,
3516     );
3517   }
3518
3519   $seen->{-relation_chain_depth}++;
3520
3521   return {%$attrs, from => $from, seen_join => $seen};
3522 }
3523
3524 sub _resolved_attrs {
3525   my $self = shift;
3526   return $self->{_attrs} if $self->{_attrs};
3527
3528   my $attrs  = { %{ $self->{attrs} || {} } };
3529   my $source = $attrs->{result_source} = $self->result_source;
3530   my $alias  = $attrs->{alias};
3531
3532   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3533     if $attrs->{collapse} and $attrs->{distinct};
3534
3535
3536   # Sanity check the paging attributes
3537   # SQLMaker does it too, but in case of a software_limit we'll never get there
3538   if (defined $attrs->{offset}) {
3539     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3540       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3541   }
3542   if (defined $attrs->{rows}) {
3543     $self->throw_exception("The rows attribute must be a positive integer if present")
3544       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3545   }
3546
3547
3548   # default selection list
3549   $attrs->{columns} = [ $source->columns ]
3550     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3551
3552   # merge selectors together
3553   for (qw/columns select as/) {
3554     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3555       if $attrs->{$_} or $attrs->{"+$_"};
3556   }
3557
3558   # disassemble columns
3559   my (@sel, @as);
3560   if (my $cols = delete $attrs->{columns}) {
3561     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3562       if (ref $c eq 'HASH') {
3563         for my $as (sort keys %$c) {
3564           push @sel, $c->{$as};
3565           push @as, $as;
3566         }
3567       }
3568       else {
3569         push @sel, $c;
3570         push @as, $c;
3571       }
3572     }
3573   }
3574
3575   # when trying to weed off duplicates later do not go past this point -
3576   # everything added from here on is unbalanced "anyone's guess" stuff
3577   my $dedup_stop_idx = $#as;
3578
3579   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3580     if $attrs->{as};
3581   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3582     if $attrs->{select};
3583
3584   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3585   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3586
3587   # disqualify all $alias.col as-bits (inflate-map mandated)
3588   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3589
3590   # de-duplicate the result (remove *identical* select/as pairs)
3591   # and also die on duplicate {as} pointing to different {select}s
3592   # not using a c-style for as the condition is prone to shrinkage
3593   my $seen;
3594   my $i = 0;
3595   while ($i <= $dedup_stop_idx) {
3596     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3597       splice @sel, $i, 1;
3598       splice @as, $i, 1;
3599       $dedup_stop_idx--;
3600     }
3601     elsif ($seen->{$as[$i]}++) {
3602       $self->throw_exception(
3603         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3604       );
3605     }
3606     else {
3607       $i++;
3608     }
3609   }
3610
3611   $attrs->{select} = \@sel;
3612   $attrs->{as} = \@as;
3613
3614   $attrs->{from} ||= [{
3615     -rsrc   => $source,
3616     -alias  => $self->{attrs}{alias},
3617     $self->{attrs}{alias} => $source->from,
3618   }];
3619
3620   if ( $attrs->{join} || $attrs->{prefetch} ) {
3621
3622     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3623       if ref $attrs->{from} ne 'ARRAY';
3624
3625     my $join = (delete $attrs->{join}) || {};
3626
3627     if ( defined $attrs->{prefetch} ) {
3628       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3629     }
3630
3631     $attrs->{from} =    # have to copy here to avoid corrupting the original
3632       [
3633         @{ $attrs->{from} },
3634         $source->_resolve_join(
3635           $join,
3636           $alias,
3637           { %{ $attrs->{seen_join} || {} } },
3638           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3639             ? $attrs->{from}[-1][0]{-join_path}
3640             : []
3641           ,
3642         )
3643       ];
3644   }
3645
3646
3647   for my $attr (qw(order_by group_by)) {
3648
3649     if ( defined $attrs->{$attr} ) {
3650       $attrs->{$attr} = (
3651         ref( $attrs->{$attr} ) eq 'ARRAY'
3652         ? [ @{ $attrs->{$attr} } ]
3653         : [ $attrs->{$attr} || () ]
3654       );
3655
3656       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3657     }
3658   }
3659
3660
3661   # set collapse default based on presence of prefetch
3662   my $prefetch;
3663   if (
3664     defined $attrs->{prefetch}
3665       and
3666     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3667   ) {
3668     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3669       if defined $attrs->{collapse} and ! $attrs->{collapse};
3670
3671     $attrs->{collapse} = 1;
3672   }
3673
3674
3675   # run through the resulting joinstructure (starting from our current slot)
3676   # and unset collapse if proven unnecessary
3677   #
3678   # also while we are at it find out if the current root source has
3679   # been premultiplied by previous related_source chaining
3680   #
3681   # this allows to predict whether a root object with all other relation
3682   # data set to NULL is in fact unique
3683   if ($attrs->{collapse}) {
3684
3685     if (ref $attrs->{from} eq 'ARRAY') {
3686
3687       if (@{$attrs->{from}} == 1) {
3688         # no joins - no collapse
3689         $attrs->{collapse} = 0;
3690       }
3691       else {
3692         # find where our table-spec starts
3693         my @fromlist = @{$attrs->{from}};
3694         while (@fromlist) {
3695           my $t = shift @fromlist;
3696
3697           my $is_multi;
3698           # me vs join from-spec distinction - a ref means non-root
3699           if (ref $t eq 'ARRAY') {
3700             $t = $t->[0];
3701             $is_multi ||= ! $t->{-is_single};
3702           }
3703           last if ($t->{-alias} && $t->{-alias} eq $alias);
3704           $attrs->{_main_source_premultiplied} ||= $is_multi;
3705         }
3706
3707         # no non-singles remaining, nor any premultiplication - nothing to collapse
3708         if (
3709           ! $attrs->{_main_source_premultiplied}
3710             and
3711           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3712         ) {
3713           $attrs->{collapse} = 0;
3714         }
3715       }
3716     }
3717
3718     else {
3719       # if we can not analyze the from - err on the side of safety
3720       $attrs->{_main_source_premultiplied} = 1;
3721     }
3722   }
3723
3724
3725   # generate the distinct induced group_by before injecting the prefetched select/as parts
3726   if (delete $attrs->{distinct}) {
3727     if ($attrs->{group_by}) {
3728       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3729     }
3730     else {
3731       $attrs->{_grouped_by_distinct} = 1;
3732       # distinct affects only the main selection part, not what prefetch may add below
3733       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3734
3735       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3736       # The thinking is: if we are collapsing the subquerying prefetch engine will
3737       # rip stuff apart for us anyway, and we do not want to have a potentially
3738       # function-converted external order_by
3739       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3740       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3741     }
3742   }
3743
3744
3745   # generate selections based on the prefetch helper
3746   if ($prefetch) {
3747
3748     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3749       if $attrs->{_dark_selector};
3750
3751     # this is a separate structure (we don't look in {from} directly)
3752     # as the resolver needs to shift things off the lists to work
3753     # properly (identical-prefetches on different branches)
3754     my $joined_node_aliases_map = {};
3755     if (ref $attrs->{from} eq 'ARRAY') {
3756
3757       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3758
3759       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3760         next unless $j->[0]{-alias};
3761         next unless $j->[0]{-join_path};
3762         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3763
3764         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3765
3766         my $p = $joined_node_aliases_map;
3767         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3768         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3769       }
3770     }
3771
3772     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3773       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3774   }
3775
3776
3777   $attrs->{_simple_passthrough_construction} = !(
3778     $attrs->{collapse}
3779       or
3780     grep { $_ =~ /\./ } @{$attrs->{as}}
3781   );
3782
3783
3784   # if both page and offset are specified, produce a combined offset
3785   # even though it doesn't make much sense, this is what pre 081xx has
3786   # been doing
3787   if (my $page = delete $attrs->{page}) {
3788     $attrs->{offset} =
3789       ($attrs->{rows} * ($page - 1))
3790             +
3791       ($attrs->{offset} || 0)
3792     ;
3793   }
3794
3795   return $self->{_attrs} = $attrs;
3796 }
3797
3798 sub _rollout_attr {
3799   my ($self, $attr) = @_;
3800
3801   if (ref $attr eq 'HASH') {
3802     return $self->_rollout_hash($attr);
3803   } elsif (ref $attr eq 'ARRAY') {
3804     return $self->_rollout_array($attr);
3805   } else {
3806     return [$attr];
3807   }
3808 }
3809
3810 sub _rollout_array {
3811   my ($self, $attr) = @_;
3812
3813   my @rolled_array;
3814   foreach my $element (@{$attr}) {
3815     if (ref $element eq 'HASH') {
3816       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3817     } elsif (ref $element eq 'ARRAY') {
3818       #  XXX - should probably recurse here
3819       push( @rolled_array, @{$self->_rollout_array($element)} );
3820     } else {
3821       push( @rolled_array, $element );
3822     }
3823   }
3824   return \@rolled_array;
3825 }
3826
3827 sub _rollout_hash {
3828   my ($self, $attr) = @_;
3829
3830   my @rolled_array;
3831   foreach my $key (keys %{$attr}) {
3832     push( @rolled_array, { $key => $attr->{$key} } );
3833   }
3834   return \@rolled_array;
3835 }
3836
3837 sub _calculate_score {
3838   my ($self, $a, $b) = @_;
3839
3840   if (defined $a xor defined $b) {
3841     return 0;
3842   }
3843   elsif (not defined $a) {
3844     return 1;
3845   }
3846
3847   if (ref $b eq 'HASH') {
3848     my ($b_key) = keys %{$b};
3849     $b_key = '' if ! defined $b_key;
3850     if (ref $a eq 'HASH') {
3851       my ($a_key) = keys %{$a};
3852       $a_key = '' if ! defined $a_key;
3853       if ($a_key eq $b_key) {
3854         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3855       } else {
3856         return 0;
3857       }
3858     } else {
3859       return ($a eq $b_key) ? 1 : 0;
3860     }
3861   } else {
3862     if (ref $a eq 'HASH') {
3863       my ($a_key) = keys %{$a};
3864       return ($b eq $a_key) ? 1 : 0;
3865     } else {
3866       return ($b eq $a) ? 1 : 0;
3867     }
3868   }
3869 }
3870
3871 sub _merge_joinpref_attr {
3872   my ($self, $orig, $import) = @_;
3873
3874   return $import unless defined($orig);
3875   return $orig unless defined($import);
3876
3877   $orig = $self->_rollout_attr($orig);
3878   $import = $self->_rollout_attr($import);
3879
3880   my $seen_keys;
3881   foreach my $import_element ( @{$import} ) {
3882     # find best candidate from $orig to merge $b_element into
3883     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3884     foreach my $orig_element ( @{$orig} ) {
3885       my $score = $self->_calculate_score( $orig_element, $import_element );
3886       if ($score > $best_candidate->{score}) {
3887         $best_candidate->{position} = $position;
3888         $best_candidate->{score} = $score;
3889       }
3890       $position++;
3891     }
3892     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3893     $import_key = '' if not defined $import_key;
3894
3895     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3896       push( @{$orig}, $import_element );
3897     } else {
3898       my $orig_best = $orig->[$best_candidate->{position}];
3899       # merge orig_best and b_element together and replace original with merged
3900       if (ref $orig_best ne 'HASH') {
3901         $orig->[$best_candidate->{position}] = $import_element;
3902       } elsif (ref $import_element eq 'HASH') {
3903         my ($key) = keys %{$orig_best};
3904         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3905       }
3906     }
3907     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3908   }
3909
3910   return @$orig ? $orig : ();
3911 }
3912
3913 {
3914   my $hm;
3915
3916   sub _merge_attr {
3917     $hm ||= do {
3918       require Hash::Merge;
3919       my $hm = Hash::Merge->new;
3920
3921       $hm->specify_behavior({
3922         SCALAR => {
3923           SCALAR => sub {
3924             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3925
3926             if ($defl xor $defr) {
3927               return [ $defl ? $_[0] : $_[1] ];
3928             }
3929             elsif (! $defl) {
3930               return [];
3931             }
3932             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3933               return [ $_[0] ];
3934             }
3935             else {
3936               return [$_[0], $_[1]];
3937             }
3938           },
3939           ARRAY => sub {
3940             return $_[1] if !defined $_[0];
3941             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3942             return [$_[0], @{$_[1]}]
3943           },
3944           HASH  => sub {
3945             return [] if !defined $_[0] and !keys %{$_[1]};
3946             return [ $_[1] ] if !defined $_[0];
3947             return [ $_[0] ] if !keys %{$_[1]};
3948             return [$_[0], $_[1]]
3949           },
3950         },
3951         ARRAY => {
3952           SCALAR => sub {
3953             return $_[0] if !defined $_[1];
3954             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3955             return [@{$_[0]}, $_[1]]
3956           },
3957           ARRAY => sub {
3958             my @ret = @{$_[0]} or return $_[1];
3959             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3960             my %idx = map { $_ => 1 } @ret;
3961             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3962             \@ret;
3963           },
3964           HASH => sub {
3965             return [ $_[1] ] if ! @{$_[0]};
3966             return $_[0] if !keys %{$_[1]};
3967             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3968             return [ @{$_[0]}, $_[1] ];
3969           },
3970         },
3971         HASH => {
3972           SCALAR => sub {
3973             return [] if !keys %{$_[0]} and !defined $_[1];
3974             return [ $_[0] ] if !defined $_[1];
3975             return [ $_[1] ] if !keys %{$_[0]};
3976             return [$_[0], $_[1]]
3977           },
3978           ARRAY => sub {
3979             return [] if !keys %{$_[0]} and !@{$_[1]};
3980             return [ $_[0] ] if !@{$_[1]};
3981             return $_[1] if !keys %{$_[0]};
3982             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3983             return [ $_[0], @{$_[1]} ];
3984           },
3985           HASH => sub {
3986             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3987             return [ $_[0] ] if !keys %{$_[1]};
3988             return [ $_[1] ] if !keys %{$_[0]};
3989             return [ $_[0] ] if $_[0] eq $_[1];
3990             return [ $_[0], $_[1] ];
3991           },
3992         }
3993       } => 'DBIC_RS_ATTR_MERGER');
3994       $hm;
3995     };
3996
3997     return $hm->merge ($_[1], $_[2]);
3998   }
3999 }
4000
4001 sub STORABLE_freeze {
4002   my ($self, $cloning) = @_;
4003   my $to_serialize = { %$self };
4004
4005   # A cursor in progress can't be serialized (and would make little sense anyway)
4006   # the parser can be regenerated (and can't be serialized)
4007   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
4008
4009   # nor is it sensical to store a not-yet-fired-count pager
4010   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
4011     delete $to_serialize->{pager};
4012   }
4013
4014   Storable::nfreeze($to_serialize);
4015 }
4016
4017 # need this hook for symmetry
4018 sub STORABLE_thaw {
4019   my ($self, $cloning, $serialized) = @_;
4020
4021   %$self = %{ Storable::thaw($serialized) };
4022
4023   $self;
4024 }
4025
4026
4027 =head2 throw_exception
4028
4029 See L<DBIx::Class::Schema/throw_exception> for details.
4030
4031 =cut
4032
4033 sub throw_exception {
4034   my $self=shift;
4035
4036   if (ref $self and my $rsrc = $self->result_source) {
4037     $rsrc->throw_exception(@_)
4038   }
4039   else {
4040     DBIx::Class::Exception->throw(@_);
4041   }
4042 }
4043
4044 1;
4045
4046 __END__
4047
4048 # XXX: FIXME: Attributes docs need clearing up
4049
4050 =head1 ATTRIBUTES
4051
4052 Attributes are used to refine a ResultSet in various ways when
4053 searching for data. They can be passed to any method which takes an
4054 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4055 L</count>.
4056
4057 Default attributes can be set on the result class using
4058 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4059 the CAVEATS on that feature before using it!)
4060
4061 These are in no particular order:
4062
4063 =head2 order_by
4064
4065 =over 4
4066
4067 =item Value: ( $order_by | \@order_by | \%order_by )
4068
4069 =back
4070
4071 Which column(s) to order the results by.
4072
4073 [The full list of suitable values is documented in
4074 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4075 common options.]
4076
4077 If a single column name, or an arrayref of names is supplied, the
4078 argument is passed through directly to SQL. The hashref syntax allows
4079 for connection-agnostic specification of ordering direction:
4080
4081  For descending order:
4082
4083   order_by => { -desc => [qw/col1 col2 col3/] }
4084
4085  For explicit ascending order:
4086
4087   order_by => { -asc => 'col' }
4088
4089 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4090 supported, although you are strongly encouraged to use the hashref
4091 syntax as outlined above.
4092
4093 =head2 columns
4094
4095 =over 4
4096
4097 =item Value: \@columns | \%columns | $column
4098
4099 =back
4100
4101 Shortcut to request a particular set of columns to be retrieved. Each
4102 column spec may be a string (a table column name), or a hash (in which
4103 case the key is the C<as> value, and the value is used as the C<select>
4104 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4105 it and sets C<select> from that, then auto-populates C<as> from
4106 C<select> as normal. (You may also use the C<cols> attribute, as in
4107 earlier versions of DBIC, but this is deprecated)
4108
4109 Essentially C<columns> does the same as L</select> and L</as>.
4110
4111     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4112
4113 is the same as
4114
4115     select => [qw(some_column another_column)],
4116     as     => [qw(some_column dbic_slot)]
4117
4118 If you want to individually retrieve related columns (in essence perform
4119 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4120 chain such that it matches existing relationships:
4121
4122     my $rs = $schema->resultset('Artist')->search({}, {
4123         # required to tell DBIC to collapse has_many relationships
4124         collapse => 1,
4125         join     => { cds => 'tracks' },
4126         '+columns'  => {
4127           'cds.cdid'         => 'cds.cdid',
4128           'cds.tracks.title' => 'tracks.title',
4129         },
4130     });
4131
4132 Like elsewhere, literal SQL or literal values can be included by using a
4133 scalar reference or a literal bind value, and these values will be available
4134 in the result with C<get_column> (see also
4135 L<SQL::Abstract/Literal SQL and value type operators>):
4136
4137     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4138     # bind values: $true_value, $false_value
4139     columns => [
4140         {
4141             foo => \1,
4142             bar => \q{'a string'},
4143             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4144         }
4145     ]
4146
4147 =head2 +columns
4148
4149 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4150 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4151 with a unary plus operator before it, which is the same as simply C<columns>.
4152
4153 =over 4
4154
4155 =item Value: \@extra_columns
4156
4157 =back
4158
4159 Indicates additional columns to be selected from storage. Works the same as
4160 L</columns> but adds columns to the current selection. (You may also use the
4161 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4162 deprecated)
4163
4164   $schema->resultset('CD')->search(undef, {
4165     '+columns' => ['artist.name'],
4166     join => ['artist']
4167   });
4168
4169 would return all CDs and include a 'name' column to the information
4170 passed to object inflation. Note that the 'artist' is the name of the
4171 column (or relationship) accessor, and 'name' is the name of the column
4172 accessor in the related table.
4173
4174 =head2 select
4175
4176 =over 4
4177
4178 =item Value: \@select_columns
4179
4180 =back
4181
4182 Indicates which columns should be selected from the storage. You can use
4183 column names, or in the case of RDBMS back ends, function or stored procedure
4184 names:
4185
4186   $rs = $schema->resultset('Employee')->search(undef, {
4187     select => [
4188       'name',
4189       { count => 'employeeid' },
4190       { max => { length => 'name' }, -as => 'longest_name' }
4191     ]
4192   });
4193
4194   # Equivalent SQL
4195   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4196
4197 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4198 use L</select>, to instruct DBIx::Class how to store the result of the column.
4199
4200 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4201 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4202 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4203 function attribute> supplied as shown in the example above.
4204
4205 =head2 +select
4206
4207 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4208 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4209 with a unary plus operator before it, which is the same as simply C<select>.
4210
4211 =over 4
4212
4213 =item Value: \@extra_select_columns
4214
4215 =back
4216
4217 Indicates additional columns to be selected from storage.  Works the same as
4218 L</select> but adds columns to the current selection, instead of specifying
4219 a new explicit list.
4220
4221 =head2 as
4222
4223 =over 4
4224
4225 =item Value: \@inflation_names
4226
4227 =back
4228
4229 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4230 slot name in which the column value will be stored within the
4231 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4232 identifier by the C<get_column> method (or via the object accessor B<if one
4233 with the same name already exists>) as shown below.
4234
4235 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4236 aliasing C<AS>. See L</select> for details.
4237
4238   $rs = $schema->resultset('Employee')->search(undef, {
4239     select => [
4240       'name',
4241       { count => 'employeeid' },
4242       { max => { length => 'name' }, -as => 'longest_name' }
4243     ],
4244     as => [qw/
4245       name
4246       employee_count
4247       max_name_length
4248     /],
4249   });
4250
4251 If the object against which the search is performed already has an accessor
4252 matching a column name specified in C<as>, the value can be retrieved using
4253 the accessor as normal:
4254
4255   my $name = $employee->name();
4256
4257 If on the other hand an accessor does not exist in the object, you need to
4258 use C<get_column> instead:
4259
4260   my $employee_count = $employee->get_column('employee_count');
4261
4262 You can create your own accessors if required - see
4263 L<DBIx::Class::Manual::Cookbook> for details.
4264
4265 =head2 +as
4266
4267 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4268 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4269 with a unary plus operator before it, which is the same as simply C<as>.
4270
4271 =over 4
4272
4273 =item Value: \@extra_inflation_names
4274
4275 =back
4276
4277 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4278
4279 =head2 join
4280
4281 =over 4
4282
4283 =item Value: ($rel_name | \@rel_names | \%rel_names)
4284
4285 =back
4286
4287 Contains a list of relationships that should be joined for this query.  For
4288 example:
4289
4290   # Get CDs by Nine Inch Nails
4291   my $rs = $schema->resultset('CD')->search(
4292     { 'artist.name' => 'Nine Inch Nails' },
4293     { join => 'artist' }
4294   );
4295
4296 Can also contain a hash reference to refer to the other relation's relations.
4297 For example:
4298
4299   package MyApp::Schema::Track;
4300   use base qw/DBIx::Class/;
4301   __PACKAGE__->table('track');
4302   __PACKAGE__->add_columns(qw/trackid cd position title/);
4303   __PACKAGE__->set_primary_key('trackid');
4304   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4305   1;
4306
4307   # In your application
4308   my $rs = $schema->resultset('Artist')->search(
4309     { 'track.title' => 'Teardrop' },
4310     {
4311       join     => { cd => 'track' },
4312       order_by => 'artist.name',
4313     }
4314   );
4315
4316 You need to use the relationship (not the table) name in  conditions,
4317 because they are aliased as such. The current table is aliased as "me", so
4318 you need to use me.column_name in order to avoid ambiguity. For example:
4319
4320   # Get CDs from 1984 with a 'Foo' track
4321   my $rs = $schema->resultset('CD')->search(
4322     {
4323       'me.year' => 1984,
4324       'tracks.name' => 'Foo'
4325     },
4326     { join => 'tracks' }
4327   );
4328
4329 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4330 similarly for a third time). For e.g.
4331
4332   my $rs = $schema->resultset('Artist')->search({
4333     'cds.title'   => 'Down to Earth',
4334     'cds_2.title' => 'Popular',
4335   }, {
4336     join => [ qw/cds cds/ ],
4337   });
4338
4339 will return a set of all artists that have both a cd with title 'Down
4340 to Earth' and a cd with title 'Popular'.
4341
4342 If you want to fetch related objects from other tables as well, see L</prefetch>
4343 below.
4344
4345  NOTE: An internal join-chain pruner will discard certain joins while
4346  constructing the actual SQL query, as long as the joins in question do not
4347  affect the retrieved result. This for example includes 1:1 left joins
4348  that are not part of the restriction specification (WHERE/HAVING) nor are
4349  a part of the query selection.
4350
4351 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4352
4353 =head2 collapse
4354
4355 =over 4
4356
4357 =item Value: (0 | 1)
4358
4359 =back
4360
4361 When set to a true value, indicates that any rows fetched from joined has_many
4362 relationships are to be aggregated into the corresponding "parent" object. For
4363 example, the resultset:
4364
4365   my $rs = $schema->resultset('CD')->search({}, {
4366     '+columns' => [ qw/ tracks.title tracks.position / ],
4367     join => 'tracks',
4368     collapse => 1,
4369   });
4370
4371 While executing the following query:
4372
4373   SELECT me.*, tracks.title, tracks.position
4374     FROM cd me
4375     LEFT JOIN track tracks
4376       ON tracks.cdid = me.cdid
4377
4378 Will return only as many objects as there are rows in the CD source, even
4379 though the result of the query may span many rows. Each of these CD objects
4380 will in turn have multiple "Track" objects hidden behind the has_many
4381 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4382 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4383 product"), with each CD object containing exactly one of all fetched Track data.
4384
4385 When a collapse is requested on a non-ordered resultset, an order by some
4386 unique part of the main source (the left-most table) is inserted automatically.
4387 This is done so that the resultset is allowed to be "lazy" - calling
4388 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4389 object with all of its related data.
4390
4391 If an L</order_by> is already declared, and orders the resultset in a way that
4392 makes collapsing as described above impossible (e.g. C<< ORDER BY
4393 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4394 switch to "eager" mode and slurp the entire resultset before constructing the
4395 first object returned by L</next>.
4396
4397 Setting this attribute on a resultset that does not join any has_many
4398 relations is a no-op.
4399
4400 For a more in-depth discussion, see L</PREFETCHING>.
4401
4402 =head2 prefetch
4403
4404 =over 4
4405
4406 =item Value: ($rel_name | \@rel_names | \%rel_names)
4407
4408 =back
4409
4410 This attribute is a shorthand for specifying a L</join> spec, adding all
4411 columns from the joined related sources as L</+columns> and setting
4412 L</collapse> to a true value. It can be thought of as a rough B<superset>
4413 of the L</join> attribute.
4414
4415 For example, the following two queries are equivalent:
4416
4417   my $rs = $schema->resultset('Artist')->search({}, {
4418     prefetch => { cds => ['genre', 'tracks' ] },
4419   });
4420
4421 and
4422
4423   my $rs = $schema->resultset('Artist')->search({}, {
4424     join => { cds => ['genre', 'tracks' ] },
4425     collapse => 1,
4426     '+columns' => [
4427       (map
4428         { +{ "cds.$_" => "cds.$_" } }
4429         $schema->source('Artist')->related_source('cds')->columns
4430       ),
4431       (map
4432         { +{ "cds.genre.$_" => "genre.$_" } }
4433         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4434       ),
4435       (map
4436         { +{ "cds.tracks.$_" => "tracks.$_" } }
4437         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4438       ),
4439     ],
4440   });
4441
4442 Both producing the following SQL:
4443
4444   SELECT  me.artistid, me.name, me.rank, me.charfield,
4445           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4446           genre.genreid, genre.name,
4447           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4448     FROM artist me
4449     LEFT JOIN cd cds
4450       ON cds.artist = me.artistid
4451     LEFT JOIN genre genre
4452       ON genre.genreid = cds.genreid
4453     LEFT JOIN track tracks
4454       ON tracks.cd = cds.cdid
4455   ORDER BY me.artistid
4456
4457 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4458 the arguments are properly merged and generally do the right thing. For
4459 example, you may want to do the following:
4460
4461   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4462     { 'genre.genreid' => undef },
4463     {
4464       join => { cds => 'genre' },
4465       prefetch => 'cds',
4466     }
4467   );
4468
4469 Which generates the following SQL:
4470
4471   SELECT  me.artistid, me.name, me.rank, me.charfield,
4472           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4473     FROM artist me
4474     LEFT JOIN cd cds
4475       ON cds.artist = me.artistid
4476     LEFT JOIN genre genre
4477       ON genre.genreid = cds.genreid
4478   WHERE genre.genreid IS NULL
4479   ORDER BY me.artistid
4480
4481 For a more in-depth discussion, see L</PREFETCHING>.
4482
4483 =head2 alias
4484
4485 =over 4
4486
4487 =item Value: $source_alias
4488
4489 =back
4490
4491 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4492 nested search queries (sub-SELECTs) might need specific aliases set to
4493 reference inner queries.  For example:
4494
4495    my $q = $rs
4496       ->related_resultset('CDs')
4497       ->related_resultset('Tracks')
4498       ->search({
4499          'track.id' => { -ident => 'none_search.id' },
4500       })
4501       ->as_query;
4502
4503    my $ids = $self->search({
4504       -not_exists => $q,
4505    }, {
4506       alias    => 'none_search',
4507       group_by => 'none_search.id',
4508    })->get_column('id')->as_query;
4509
4510    $self->search({ id => { -in => $ids } })
4511
4512 This attribute is directly tied to L</current_source_alias>.
4513
4514 =head2 page
4515
4516 =over 4
4517
4518 =item Value: $page
4519
4520 =back
4521
4522 Makes the resultset paged and specifies the page to retrieve. Effectively
4523 identical to creating a non-pages resultset and then calling ->page($page)
4524 on it.
4525
4526 If L</rows> attribute is not specified it defaults to 10 rows per page.
4527
4528 When you have a paged resultset, L</count> will only return the number
4529 of rows in the page. To get the total, use the L</pager> and call
4530 C<total_entries> on it.
4531
4532 =head2 rows
4533
4534 =over 4
4535
4536 =item Value: $rows
4537
4538 =back
4539
4540 Specifies the maximum number of rows for direct retrieval or the number of
4541 rows per page if the page attribute or method is used.
4542
4543 =head2 offset
4544
4545 =over 4
4546
4547 =item Value: $offset
4548
4549 =back
4550
4551 Specifies the (zero-based) row number for the  first row to be returned, or the
4552 of the first row of the first page if paging is used.
4553
4554 =head2 software_limit
4555
4556 =over 4
4557
4558 =item Value: (0 | 1)
4559
4560 =back
4561
4562 When combined with L</rows> and/or L</offset> the generated SQL will not
4563 include any limit dialect stanzas. Instead the entire result will be selected
4564 as if no limits were specified, and DBIC will perform the limit locally, by
4565 artificially advancing and finishing the resulting L</cursor>.
4566
4567 This is the recommended way of performing resultset limiting when no sane RDBMS
4568 implementation is available (e.g.
4569 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4570 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4571
4572 =head2 group_by
4573
4574 =over 4
4575
4576 =item Value: \@columns
4577
4578 =back
4579
4580 A arrayref of columns to group by. Can include columns of joined tables.
4581
4582   group_by => [qw/ column1 column2 ... /]
4583
4584 =head2 having
4585
4586 =over 4
4587
4588 =item Value: $condition
4589
4590 =back
4591
4592 The HAVING operator specifies a B<secondary> condition applied to the set
4593 after the grouping calculations have been done. In other words it is a
4594 constraint just like L</where> (and accepting the same
4595 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4596 as it exists after GROUP BY has taken place. Specifying L</having> without
4597 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4598
4599 E.g.
4600
4601   having => { 'count_employee' => { '>=', 100 } }
4602
4603 or with an in-place function in which case literal SQL is required:
4604
4605   having => \[ 'count(employee) >= ?', 100 ]
4606
4607 =head2 distinct
4608
4609 =over 4
4610
4611 =item Value: (0 | 1)
4612
4613 =back
4614
4615 Set to 1 to automatically generate a L</group_by> clause based on the selection
4616 (including intelligent handling of L</order_by> contents). Note that the group
4617 criteria calculation takes place over the B<final> selection. This includes
4618 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4619 L</search> calls, and standalone columns selected via
4620 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4621 extra selections specified via L</prefetch> - such selections are explicitly
4622 excluded from group criteria calculations.
4623
4624 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4625 setting is ignored and an appropriate warning is issued.
4626
4627 =head2 where
4628
4629 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4630 conditions, same as the B<first> argument to the L<search operator|/search>
4631
4632   # only return rows WHERE deleted IS NULL for all searches
4633   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4634
4635 Note that the above example is
4636 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4637
4638 =head2 cache
4639
4640 Set to 1 to cache search results. This prevents extra SQL queries if you
4641 revisit rows in your ResultSet:
4642
4643   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4644
4645   while( my $artist = $resultset->next ) {
4646     ... do stuff ...
4647   }
4648
4649   $resultset->first; # without cache, this would issue a query
4650
4651 By default, searches are not cached.
4652
4653 For more examples of using these attributes, see
4654 L<DBIx::Class::Manual::Cookbook>.
4655
4656 =head2 for
4657
4658 =over 4
4659
4660 =item Value: ( 'update' | 'shared' | \$scalar )
4661
4662 =back
4663
4664 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4665 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4666 query.
4667
4668 =head1 PREFETCHING
4669
4670 DBIx::Class supports arbitrary related data prefetching from multiple related
4671 sources. Any combination of relationship types and column sets are supported.
4672 If L<collapsing|/collapse> is requested, there is an additional requirement of
4673 selecting enough data to make every individual object uniquely identifiable.
4674
4675 Here are some more involved examples, based on the following relationship map:
4676
4677   # Assuming:
4678   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4679   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4680   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4681
4682   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4683
4684   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4685
4686
4687
4688   my $rs = $schema->resultset('Tag')->search(
4689     undef,
4690     {
4691       prefetch => {
4692         cd => 'artist'
4693       }
4694     }
4695   );
4696
4697 The initial search results in SQL like the following:
4698
4699   SELECT tag.*, cd.*, artist.* FROM tag
4700   JOIN cd ON tag.cd = cd.cdid
4701   JOIN artist ON cd.artist = artist.artistid
4702
4703 L<DBIx::Class> has no need to go back to the database when we access the
4704 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4705 case.
4706
4707 Simple prefetches will be joined automatically, so there is no need
4708 for a C<join> attribute in the above search.
4709
4710 The L</prefetch> attribute can be used with any of the relationship types
4711 and multiple prefetches can be specified together. Below is a more complex
4712 example that prefetches a CD's artist, its liner notes (if present),
4713 the cover image, the tracks on that CD, and the guests on those
4714 tracks.
4715
4716   my $rs = $schema->resultset('CD')->search(
4717     undef,
4718     {
4719       prefetch => [
4720         { artist => 'record_label'},  # belongs_to => belongs_to
4721         'liner_note',                 # might_have
4722         'cover_image',                # has_one
4723         { tracks => 'guests' },       # has_many => has_many
4724       ]
4725     }
4726   );
4727
4728 This will produce SQL like the following:
4729
4730   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4731          tracks.*, guests.*
4732     FROM cd me
4733     JOIN artist artist
4734       ON artist.artistid = me.artistid
4735     JOIN record_label record_label
4736       ON record_label.labelid = artist.labelid
4737     LEFT JOIN track tracks
4738       ON tracks.cdid = me.cdid
4739     LEFT JOIN guest guests
4740       ON guests.trackid = track.trackid
4741     LEFT JOIN liner_notes liner_note
4742       ON liner_note.cdid = me.cdid
4743     JOIN cd_artwork cover_image
4744       ON cover_image.cdid = me.cdid
4745   ORDER BY tracks.cd
4746
4747 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4748 C<tracks>, and C<guests> of the CD will all be available through the
4749 relationship accessors without the need for additional queries to the
4750 database.
4751
4752 =head3 CAVEATS
4753
4754 Prefetch does a lot of deep magic. As such, it may not behave exactly
4755 as you might expect.
4756
4757 =over 4
4758
4759 =item *
4760
4761 Prefetch uses the L</cache> to populate the prefetched relationships. This
4762 may or may not be what you want.
4763
4764 =item *
4765
4766 If you specify a condition on a prefetched relationship, ONLY those
4767 rows that match the prefetched condition will be fetched into that relationship.
4768 This means that adding prefetch to a search() B<may alter> what is returned by
4769 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4770
4771   my $artist_rs = $schema->resultset('Artist')->search({
4772       'cds.year' => 2008,
4773   }, {
4774       join => 'cds',
4775   });
4776
4777   my $count = $artist_rs->first->cds->count;
4778
4779   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4780
4781   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4782
4783   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4784
4785 That cmp_ok() may or may not pass depending on the datasets involved. In other
4786 words the C<WHERE> condition would apply to the entire dataset, just like
4787 it would in regular SQL. If you want to add a condition only to the "right side"
4788 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4789 condition|DBIx::Class::Relationship::Base/condition>
4790
4791 =back
4792
4793 =head1 DBIC BIND VALUES
4794
4795 Because DBIC may need more information to bind values than just the column name
4796 and value itself, it uses a special format for both passing and receiving bind
4797 values.  Each bind value should be composed of an arrayref of
4798 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4799
4800 =over 4
4801
4802 =item dbd_attrs
4803
4804 If present (in any form), this is what is being passed directly to bind_param.
4805 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4806 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4807
4808 If this is specified, all other bind options described below are ignored.
4809
4810 =item sqlt_datatype
4811
4812 If present, this is used to infer the actual bind attribute by passing to
4813 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4814 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4815
4816 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4817 currently drivers are expected to "Do the Right Thing" when given a common
4818 datatype name.  (Not ideal, but that's what we got at this point.)
4819
4820 =item sqlt_size
4821
4822 Currently used to correctly allocate buffers for bind_param_inout().
4823 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4824 or to a sensible value based on the "data_type".
4825
4826 =item dbic_colname
4827
4828 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4829 explicitly specified they are never overridden).  Also used by some weird DBDs,
4830 where the column name should be available at bind_param time (e.g. Oracle).
4831
4832 =back
4833
4834 For backwards compatibility and convenience, the following shortcuts are
4835 supported:
4836
4837   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4838   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4839   [ undef,   $val ] === [ {}, $val ]
4840   $val              === [ {}, $val ]
4841
4842 =head1 FURTHER QUESTIONS?
4843
4844 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4845
4846 =head1 COPYRIGHT AND LICENSE
4847
4848 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4849 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4850 redistribute it and/or modify it under the same terms as the
4851 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4852
4853 =cut