lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 Note: When using C<count> with C<group_by>, L<DBIx::Class> emulates C<GROUP BY>
1152 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
1153 not support C<DISTINCT> with multiple columns. If you are using such a
1154 database, you should only use columns from the main table in your C<group_by>
1155 clause.
1156
1157 =cut
1158
1159 sub count {
1160   my $self = shift;
1161   return $self->search(@_)->count if @_ and defined $_[0];
1162   return scalar @{ $self->get_cache } if $self->get_cache;
1163   my $count = $self->_count;
1164   return 0 unless $count;
1165
1166   # need to take offset from resolved attrs
1167
1168   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1169   $count = $self->{attrs}{rows} if
1170     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1171   $count = 0 if ($count < 0);
1172   return $count;
1173 }
1174
1175 sub _count { # Separated out so pager can get the full count
1176   my $self = shift;
1177   my $select = { count => '*' };
1178
1179   my $attrs = { %{$self->_resolved_attrs} };
1180   if (my $group_by = delete $attrs->{group_by}) {
1181     delete $attrs->{having};
1182     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
1183     # todo: try CONCAT for multi-column pk
1184     my @pk = $self->result_source->primary_columns;
1185     if (@pk == 1) {
1186       my $alias = $attrs->{alias};
1187       foreach my $column (@distinct) {
1188         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
1189           @distinct = ($column);
1190           last;
1191         }
1192       }
1193     }
1194
1195     $select = { count => { distinct => \@distinct } };
1196   }
1197
1198   $attrs->{select} = $select;
1199   $attrs->{as} = [qw/count/];
1200
1201   # offset, order by and page are not needed to count. record_filter is cdbi
1202   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
1203
1204   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1205   my ($count) = $tmp_rs->cursor->next;
1206   return $count;
1207 }
1208
1209 sub _bool {
1210   return 1;
1211 }
1212
1213 =head2 count_literal
1214
1215 =over 4
1216
1217 =item Arguments: $sql_fragment, @bind_values
1218
1219 =item Return Value: $count
1220
1221 =back
1222
1223 Counts the results in a literal query. Equivalent to calling L</search_literal>
1224 with the passed arguments, then L</count>.
1225
1226 =cut
1227
1228 sub count_literal { shift->search_literal(@_)->count; }
1229
1230 =head2 all
1231
1232 =over 4
1233
1234 =item Arguments: none
1235
1236 =item Return Value: @objects
1237
1238 =back
1239
1240 Returns all elements in the resultset. Called implicitly if the resultset
1241 is returned in list context.
1242
1243 =cut
1244
1245 sub all {
1246   my $self = shift;
1247   if(@_) {
1248       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1249   }
1250
1251   return @{ $self->get_cache } if $self->get_cache;
1252
1253   my @obj;
1254
1255   # TODO: don't call resolve here
1256   if (keys %{$self->_resolved_attrs->{collapse}}) {
1257 #  if ($self->{attrs}{prefetch}) {
1258       # Using $self->cursor->all is really just an optimisation.
1259       # If we're collapsing has_many prefetches it probably makes
1260       # very little difference, and this is cleaner than hacking
1261       # _construct_object to survive the approach
1262     my @row = $self->cursor->next;
1263     while (@row) {
1264       push(@obj, $self->_construct_object(@row));
1265       @row = (exists $self->{stashed_row}
1266                ? @{delete $self->{stashed_row}}
1267                : $self->cursor->next);
1268     }
1269   } else {
1270     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1271   }
1272
1273   $self->set_cache(\@obj) if $self->{attrs}{cache};
1274   return @obj;
1275 }
1276
1277 =head2 reset
1278
1279 =over 4
1280
1281 =item Arguments: none
1282
1283 =item Return Value: $self
1284
1285 =back
1286
1287 Resets the resultset's cursor, so you can iterate through the elements again.
1288
1289 =cut
1290
1291 sub reset {
1292   my ($self) = @_;
1293   delete $self->{_attrs} if exists $self->{_attrs};
1294   $self->{all_cache_position} = 0;
1295   $self->cursor->reset;
1296   return $self;
1297 }
1298
1299 =head2 first
1300
1301 =over 4
1302
1303 =item Arguments: none
1304
1305 =item Return Value: $object?
1306
1307 =back
1308
1309 Resets the resultset and returns an object for the first result (if the
1310 resultset returns anything).
1311
1312 =cut
1313
1314 sub first {
1315   return $_[0]->reset->next;
1316 }
1317
1318 # _cond_for_update_delete
1319 #
1320 # update/delete require the condition to be modified to handle
1321 # the differing SQL syntax available.  This transforms the $self->{cond}
1322 # appropriately, returning the new condition.
1323
1324 sub _cond_for_update_delete {
1325   my ($self, $full_cond) = @_;
1326   my $cond = {};
1327
1328   $full_cond ||= $self->{cond};
1329   # No-op. No condition, we're updating/deleting everything
1330   return $cond unless ref $full_cond;
1331
1332   foreach my $pk ($self->result_source->primary_columns) {
1333       $cond->{$pk} = { -in => $self->get_column($pk)->as_query };
1334   }
1335
1336   return $cond;
1337 }
1338
1339
1340 =head2 update
1341
1342 =over 4
1343
1344 =item Arguments: \%values
1345
1346 =item Return Value: $storage_rv
1347
1348 =back
1349
1350 Sets the specified columns in the resultset to the supplied values in a
1351 single query. Return value will be true if the update succeeded or false
1352 if no records were updated; exact type of success value is storage-dependent.
1353
1354 =cut
1355
1356 sub update {
1357   my ($self, $values) = @_;
1358   $self->throw_exception("Values for update must be a hash")
1359     unless ref $values eq 'HASH';
1360
1361   my $cond = $self->_cond_for_update_delete;
1362
1363   return $self->result_source->storage->update(
1364     $self->result_source, $values, $cond
1365   );
1366 }
1367
1368 =head2 update_all
1369
1370 =over 4
1371
1372 =item Arguments: \%values
1373
1374 =item Return Value: 1
1375
1376 =back
1377
1378 Fetches all objects and updates them one at a time. Note that C<update_all>
1379 will run DBIC cascade triggers, while L</update> will not.
1380
1381 =cut
1382
1383 sub update_all {
1384   my ($self, $values) = @_;
1385   $self->throw_exception("Values for update must be a hash")
1386     unless ref $values eq 'HASH';
1387   foreach my $obj ($self->all) {
1388     $obj->set_columns($values)->update;
1389   }
1390   return 1;
1391 }
1392
1393 =head2 delete
1394
1395 =over 4
1396
1397 =item Arguments: none
1398
1399 =item Return Value: 1
1400
1401 =back
1402
1403 Deletes the contents of the resultset from its result source. Note that this
1404 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1405 to run. See also L<DBIx::Class::Row/delete>.
1406
1407 delete may not generate correct SQL for a query with joins or a resultset
1408 chained from a related resultset.  In this case it will generate a warning:-
1409
1410 In these cases you may find that delete_all is more appropriate, or you
1411 need to respecify your query in a way that can be expressed without a join.
1412
1413 =cut
1414
1415 sub delete {
1416   my ($self) = @_;
1417   $self->throw_exception("Delete should not be passed any arguments")
1418     if $_[1];
1419
1420   my $cond = $self->_cond_for_update_delete;
1421
1422   $self->result_source->storage->delete($self->result_source, $cond);
1423   return 1;
1424 }
1425
1426 =head2 delete_all
1427
1428 =over 4
1429
1430 =item Arguments: none
1431
1432 =item Return Value: 1
1433
1434 =back
1435
1436 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1437 will run DBIC cascade triggers, while L</delete> will not.
1438
1439 =cut
1440
1441 sub delete_all {
1442   my ($self) = @_;
1443   $_->delete for $self->all;
1444   return 1;
1445 }
1446
1447 =head2 populate
1448
1449 =over 4
1450
1451 =item Arguments: \@data;
1452
1453 =back
1454
1455 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1456 For the arrayref of hashrefs style each hashref should be a structure suitable
1457 forsubmitting to a $resultset->create(...) method.
1458
1459 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1460 to insert the data, as this is a faster method.
1461
1462 Otherwise, each set of data is inserted into the database using
1463 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1464 objects is returned.
1465
1466 Example:  Assuming an Artist Class that has many CDs Classes relating:
1467
1468   my $Artist_rs = $schema->resultset("Artist");
1469
1470   ## Void Context Example
1471   $Artist_rs->populate([
1472      { artistid => 4, name => 'Manufactured Crap', cds => [
1473         { title => 'My First CD', year => 2006 },
1474         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1475       ],
1476      },
1477      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1478         { title => 'My parents sold me to a record company' ,year => 2005 },
1479         { title => 'Why Am I So Ugly?', year => 2006 },
1480         { title => 'I Got Surgery and am now Popular', year => 2007 }
1481       ],
1482      },
1483   ]);
1484
1485   ## Array Context Example
1486   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1487     { name => "Artist One"},
1488     { name => "Artist Two"},
1489     { name => "Artist Three", cds=> [
1490     { title => "First CD", year => 2007},
1491     { title => "Second CD", year => 2008},
1492   ]}
1493   ]);
1494
1495   print $ArtistOne->name; ## response is 'Artist One'
1496   print $ArtistThree->cds->count ## reponse is '2'
1497
1498 For the arrayref of arrayrefs style,  the first element should be a list of the
1499 fieldsnames to which the remaining elements are rows being inserted.  For
1500 example:
1501
1502   $Arstist_rs->populate([
1503     [qw/artistid name/],
1504     [100, 'A Formally Unknown Singer'],
1505     [101, 'A singer that jumped the shark two albums ago'],
1506     [102, 'An actually cool singer.'],
1507   ]);
1508
1509 Please note an important effect on your data when choosing between void and
1510 wantarray context. Since void context goes straight to C<insert_bulk> in
1511 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1512 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1513 create primary keys for you, you will find that your PKs are empty.  In this
1514 case you will have to use the wantarray context in order to create those
1515 values.
1516
1517 =cut
1518
1519 sub populate {
1520   my $self = shift @_;
1521   my $data = ref $_[0][0] eq 'HASH'
1522     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1523     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1524
1525   if(defined wantarray) {
1526     my @created;
1527     foreach my $item (@$data) {
1528       push(@created, $self->create($item));
1529     }
1530     return @created;
1531   } else {
1532     my ($first, @rest) = @$data;
1533
1534     my @names = grep {!ref $first->{$_}} keys %$first;
1535     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1536     my @pks = $self->result_source->primary_columns;
1537
1538     ## do the belongs_to relationships
1539     foreach my $index (0..$#$data) {
1540       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1541         my @ret = $self->populate($data);
1542         return;
1543       }
1544
1545       foreach my $rel (@rels) {
1546         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1547         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1548         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1549         my $related = $result->result_source->resolve_condition(
1550           $result->result_source->relationship_info($reverse)->{cond},
1551           $self,
1552           $result,
1553         );
1554
1555         delete $data->[$index]->{$rel};
1556         $data->[$index] = {%{$data->[$index]}, %$related};
1557
1558         push @names, keys %$related if $index == 0;
1559       }
1560     }
1561
1562     ## do bulk insert on current row
1563     my @values = map { [ @$_{@names} ] } @$data;
1564
1565     $self->result_source->storage->insert_bulk(
1566       $self->result_source,
1567       \@names,
1568       \@values,
1569     );
1570
1571     ## do the has_many relationships
1572     foreach my $item (@$data) {
1573
1574       foreach my $rel (@rels) {
1575         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1576
1577         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1578      || $self->throw_exception('Cannot find the relating object.');
1579
1580         my $child = $parent->$rel;
1581
1582         my $related = $child->result_source->resolve_condition(
1583           $parent->result_source->relationship_info($rel)->{cond},
1584           $child,
1585           $parent,
1586         );
1587
1588         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1589         my @populate = map { {%$_, %$related} } @rows_to_add;
1590
1591         $child->populate( \@populate );
1592       }
1593     }
1594   }
1595 }
1596
1597 =head2 _normalize_populate_args ($args)
1598
1599 Private method used by L</populate> to normalize its incoming arguments.  Factored
1600 out in case you want to subclass and accept new argument structures to the
1601 L</populate> method.
1602
1603 =cut
1604
1605 sub _normalize_populate_args {
1606   my ($self, $data) = @_;
1607   my @names = @{shift(@$data)};
1608   my @results_to_create;
1609   foreach my $datum (@$data) {
1610     my %result_to_create;
1611     foreach my $index (0..$#names) {
1612       $result_to_create{$names[$index]} = $$datum[$index];
1613     }
1614     push @results_to_create, \%result_to_create;
1615   }
1616   return \@results_to_create;
1617 }
1618
1619 =head2 pager
1620
1621 =over 4
1622
1623 =item Arguments: none
1624
1625 =item Return Value: $pager
1626
1627 =back
1628
1629 Return Value a L<Data::Page> object for the current resultset. Only makes
1630 sense for queries with a C<page> attribute.
1631
1632 To get the full count of entries for a paged resultset, call
1633 C<total_entries> on the L<Data::Page> object.
1634
1635 =cut
1636
1637 sub pager {
1638   my ($self) = @_;
1639   my $attrs = $self->{attrs};
1640   $self->throw_exception("Can't create pager for non-paged rs")
1641     unless $self->{attrs}{page};
1642   $attrs->{rows} ||= 10;
1643   return $self->{pager} ||= Data::Page->new(
1644     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1645 }
1646
1647 =head2 page
1648
1649 =over 4
1650
1651 =item Arguments: $page_number
1652
1653 =item Return Value: $rs
1654
1655 =back
1656
1657 Returns a resultset for the $page_number page of the resultset on which page
1658 is called, where each page contains a number of rows equal to the 'rows'
1659 attribute set on the resultset (10 by default).
1660
1661 =cut
1662
1663 sub page {
1664   my ($self, $page) = @_;
1665   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1666 }
1667
1668 =head2 new_result
1669
1670 =over 4
1671
1672 =item Arguments: \%vals
1673
1674 =item Return Value: $rowobject
1675
1676 =back
1677
1678 Creates a new row object in the resultset's result class and returns
1679 it. The row is not inserted into the database at this point, call
1680 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1681 will tell you whether the row object has been inserted or not.
1682
1683 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1684
1685 =cut
1686
1687 sub new_result {
1688   my ($self, $values) = @_;
1689   $self->throw_exception( "new_result needs a hash" )
1690     unless (ref $values eq 'HASH');
1691
1692   my %new;
1693   my $alias = $self->{attrs}{alias};
1694
1695   if (
1696     defined $self->{cond}
1697     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1698   ) {
1699     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1700     $new{-from_resultset} = [ keys %new ] if keys %new;
1701   } else {
1702     $self->throw_exception(
1703       "Can't abstract implicit construct, condition not a hash"
1704     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1705
1706     my $collapsed_cond = (
1707       $self->{cond}
1708         ? $self->_collapse_cond($self->{cond})
1709         : {}
1710     );
1711
1712     # precendence must be given to passed values over values inherited from
1713     # the cond, so the order here is important.
1714     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1715     while( my($col,$value) = each %implied ){
1716       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1717         $new{$col} = $value->{'='};
1718         next;
1719       }
1720       $new{$col} = $value if $self->_is_deterministic_value($value);
1721     }
1722   }
1723
1724   %new = (
1725     %new,
1726     %{ $self->_remove_alias($values, $alias) },
1727     -source_handle => $self->_source_handle,
1728     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1729   );
1730
1731   return $self->result_class->new(\%new);
1732 }
1733
1734 # _is_deterministic_value
1735 #
1736 # Make an effor to strip non-deterministic values from the condition,
1737 # to make sure new_result chokes less
1738
1739 sub _is_deterministic_value {
1740   my $self = shift;
1741   my $value = shift;
1742   my $ref_type = ref $value;
1743   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1744   return 1 if Scalar::Util::blessed($value);
1745   return 0;
1746 }
1747
1748 # _collapse_cond
1749 #
1750 # Recursively collapse the condition.
1751
1752 sub _collapse_cond {
1753   my ($self, $cond, $collapsed) = @_;
1754
1755   $collapsed ||= {};
1756
1757   if (ref $cond eq 'ARRAY') {
1758     foreach my $subcond (@$cond) {
1759       next unless ref $subcond;  # -or
1760       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1761     }
1762   }
1763   elsif (ref $cond eq 'HASH') {
1764     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1765       foreach my $subcond (@{$cond->{-and}}) {
1766         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1767       }
1768     }
1769     else {
1770       foreach my $col (keys %$cond) {
1771         my $value = $cond->{$col};
1772         $collapsed->{$col} = $value;
1773       }
1774     }
1775   }
1776
1777   return $collapsed;
1778 }
1779
1780 # _remove_alias
1781 #
1782 # Remove the specified alias from the specified query hash. A copy is made so
1783 # the original query is not modified.
1784
1785 sub _remove_alias {
1786   my ($self, $query, $alias) = @_;
1787
1788   my %orig = %{ $query || {} };
1789   my %unaliased;
1790
1791   foreach my $key (keys %orig) {
1792     if ($key !~ /\./) {
1793       $unaliased{$key} = $orig{$key};
1794       next;
1795     }
1796     $unaliased{$1} = $orig{$key}
1797       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1798   }
1799
1800   return \%unaliased;
1801 }
1802
1803 =head2 as_query (EXPERIMENTAL)
1804
1805 =over 4
1806
1807 =item Arguments: none
1808
1809 =item Return Value: \[ $sql, @bind ]
1810
1811 =back
1812
1813 Returns the SQL query and bind vars associated with the invocant.
1814
1815 This is generally used as the RHS for a subquery.
1816
1817 B<NOTE>: This feature is still experimental.
1818
1819 =cut
1820
1821 sub as_query { return shift->cursor->as_query(@_) }
1822
1823 =head2 find_or_new
1824
1825 =over 4
1826
1827 =item Arguments: \%vals, \%attrs?
1828
1829 =item Return Value: $rowobject
1830
1831 =back
1832
1833   my $artist = $schema->resultset('Artist')->find_or_new(
1834     { artist => 'fred' }, { key => 'artists' });
1835
1836   $cd->cd_to_producer->find_or_new({ producer => $producer },
1837                                    { key => 'primary });
1838
1839 Find an existing record from this resultset, based on its primary
1840 key, or a unique constraint. If none exists, instantiate a new result
1841 object and return it. The object will not be saved into your storage
1842 until you call L<DBIx::Class::Row/insert> on it.
1843
1844 You most likely want this method when looking for existing rows using
1845 a unique constraint that is not the primary key, or looking for
1846 related rows.
1847
1848 If you want objects to be saved immediately, use L</find_or_create> instead.
1849
1850 B<Note>: C<find_or_new> is probably not what you want when creating a
1851 new row in a table that uses primary keys supplied by the
1852 database. Passing in a primary key column with a value of I<undef>
1853 will cause L</find> to attempt to search for a row with a value of
1854 I<NULL>.
1855
1856 =cut
1857
1858 sub find_or_new {
1859   my $self     = shift;
1860   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1861   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1862   my $exists   = $self->find($hash, $attrs);
1863   return defined $exists ? $exists : $self->new_result($hash);
1864 }
1865
1866 =head2 create
1867
1868 =over 4
1869
1870 =item Arguments: \%vals
1871
1872 =item Return Value: a L<DBIx::Class::Row> $object
1873
1874 =back
1875
1876 Attempt to create a single new row or a row with multiple related rows
1877 in the table represented by the resultset (and related tables). This
1878 will not check for duplicate rows before inserting, use
1879 L</find_or_create> to do that.
1880
1881 To create one row for this resultset, pass a hashref of key/value
1882 pairs representing the columns of the table and the values you wish to
1883 store. If the appropriate relationships are set up, foreign key fields
1884 can also be passed an object representing the foreign row, and the
1885 value will be set to its primary key.
1886
1887 To create related objects, pass a hashref for the value if the related
1888 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1889 and use the name of the relationship as the key. (NOT the name of the field,
1890 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1891 of hashrefs containing the data for each of the rows to create in the foreign
1892 tables, again using the relationship name as the key.
1893
1894 Instead of hashrefs of plain related data (key/value pairs), you may
1895 also pass new or inserted objects. New objects (not inserted yet, see
1896 L</new>), will be inserted into their appropriate tables.
1897
1898 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1899
1900 Example of creating a new row.
1901
1902   $person_rs->create({
1903     name=>"Some Person",
1904     email=>"somebody@someplace.com"
1905   });
1906
1907 Example of creating a new row and also creating rows in a related C<has_many>
1908 or C<has_one> resultset.  Note Arrayref.
1909
1910   $artist_rs->create(
1911      { artistid => 4, name => 'Manufactured Crap', cds => [
1912         { title => 'My First CD', year => 2006 },
1913         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1914       ],
1915      },
1916   );
1917
1918 Example of creating a new row and also creating a row in a related
1919 C<belongs_to>resultset. Note Hashref.
1920
1921   $cd_rs->create({
1922     title=>"Music for Silly Walks",
1923     year=>2000,
1924     artist => {
1925       name=>"Silly Musician",
1926     }
1927   });
1928
1929 =cut
1930
1931 sub create {
1932   my ($self, $attrs) = @_;
1933   $self->throw_exception( "create needs a hashref" )
1934     unless ref $attrs eq 'HASH';
1935   return $self->new_result($attrs)->insert;
1936 }
1937
1938 =head2 find_or_create
1939
1940 =over 4
1941
1942 =item Arguments: \%vals, \%attrs?
1943
1944 =item Return Value: $rowobject
1945
1946 =back
1947
1948   $cd->cd_to_producer->find_or_create({ producer => $producer },
1949                                       { key => 'primary });
1950
1951 Tries to find a record based on its primary key or unique constraints; if none
1952 is found, creates one and returns that instead.
1953
1954   my $cd = $schema->resultset('CD')->find_or_create({
1955     cdid   => 5,
1956     artist => 'Massive Attack',
1957     title  => 'Mezzanine',
1958     year   => 2005,
1959   });
1960
1961 Also takes an optional C<key> attribute, to search by a specific key or unique
1962 constraint. For example:
1963
1964   my $cd = $schema->resultset('CD')->find_or_create(
1965     {
1966       artist => 'Massive Attack',
1967       title  => 'Mezzanine',
1968     },
1969     { key => 'cd_artist_title' }
1970   );
1971
1972 B<Note>: Because find_or_create() reads from the database and then
1973 possibly inserts based on the result, this method is subject to a race
1974 condition. Another process could create a record in the table after
1975 the find has completed and before the create has started. To avoid
1976 this problem, use find_or_create() inside a transaction.
1977
1978 B<Note>: C<find_or_create> is probably not what you want when creating
1979 a new row in a table that uses primary keys supplied by the
1980 database. Passing in a primary key column with a value of I<undef>
1981 will cause L</find> to attempt to search for a row with a value of
1982 I<NULL>.
1983
1984 See also L</find> and L</update_or_create>. For information on how to declare
1985 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1986
1987 =cut
1988
1989 sub find_or_create {
1990   my $self     = shift;
1991   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1992   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1993   my $exists   = $self->find($hash, $attrs);
1994   return defined $exists ? $exists : $self->create($hash);
1995 }
1996
1997 =head2 update_or_create
1998
1999 =over 4
2000
2001 =item Arguments: \%col_values, { key => $unique_constraint }?
2002
2003 =item Return Value: $rowobject
2004
2005 =back
2006
2007   $resultset->update_or_create({ col => $val, ... });
2008
2009 First, searches for an existing row matching one of the unique constraints
2010 (including the primary key) on the source of this resultset. If a row is
2011 found, updates it with the other given column values. Otherwise, creates a new
2012 row.
2013
2014 Takes an optional C<key> attribute to search on a specific unique constraint.
2015 For example:
2016
2017   # In your application
2018   my $cd = $schema->resultset('CD')->update_or_create(
2019     {
2020       artist => 'Massive Attack',
2021       title  => 'Mezzanine',
2022       year   => 1998,
2023     },
2024     { key => 'cd_artist_title' }
2025   );
2026
2027   $cd->cd_to_producer->update_or_create({
2028     producer => $producer,
2029     name => 'harry',
2030   }, {
2031     key => 'primary,
2032   });
2033
2034
2035 If no C<key> is specified, it searches on all unique constraints defined on the
2036 source, including the primary key.
2037
2038 If the C<key> is specified as C<primary>, it searches only on the primary key.
2039
2040 See also L</find> and L</find_or_create>. For information on how to declare
2041 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2042
2043 B<Note>: C<update_or_create> is probably not what you want when
2044 looking for a row in a table that uses primary keys supplied by the
2045 database, unless you actually have a key value. Passing in a primary
2046 key column with a value of I<undef> will cause L</find> to attempt to
2047 search for a row with a value of I<NULL>.
2048
2049 =cut
2050
2051 sub update_or_create {
2052   my $self = shift;
2053   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2054   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2055
2056   my $row = $self->find($cond, $attrs);
2057   if (defined $row) {
2058     $row->update($cond);
2059     return $row;
2060   }
2061
2062   return $self->create($cond);
2063 }
2064
2065 =head2 update_or_new
2066
2067 =over 4
2068
2069 =item Arguments: \%col_values, { key => $unique_constraint }?
2070
2071 =item Return Value: $rowobject
2072
2073 =back
2074
2075   $resultset->update_or_new({ col => $val, ... });
2076
2077 First, searches for an existing row matching one of the unique constraints
2078 (including the primary key) on the source of this resultset. If a row is
2079 found, updates it with the other given column values. Otherwise, instantiate
2080 a new result object and return it. The object will not be saved into your storage
2081 until you call L<DBIx::Class::Row/insert> on it.
2082
2083 Takes an optional C<key> attribute to search on a specific unique constraint.
2084 For example:
2085
2086   # In your application
2087   my $cd = $schema->resultset('CD')->update_or_new(
2088     {
2089       artist => 'Massive Attack',
2090       title  => 'Mezzanine',
2091       year   => 1998,
2092     },
2093     { key => 'cd_artist_title' }
2094   );
2095
2096   if ($cd->in_storage) {
2097       # the cd was updated
2098   }
2099   else {
2100       # the cd is not yet in the database, let's insert it
2101       $cd->insert;
2102   }
2103
2104 See also L</find>, L</find_or_create> and L<find_or_new>.
2105
2106 =cut
2107
2108 sub update_or_new {
2109     my $self  = shift;
2110     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2111     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2112
2113     my $row = $self->find( $cond, $attrs );
2114     if ( defined $row ) {
2115         $row->update($cond);
2116         return $row;
2117     }
2118
2119     return $self->new_result($cond);
2120 }
2121
2122 =head2 get_cache
2123
2124 =over 4
2125
2126 =item Arguments: none
2127
2128 =item Return Value: \@cache_objects?
2129
2130 =back
2131
2132 Gets the contents of the cache for the resultset, if the cache is set.
2133
2134 The cache is populated either by using the L</prefetch> attribute to
2135 L</search> or by calling L</set_cache>.
2136
2137 =cut
2138
2139 sub get_cache {
2140   shift->{all_cache};
2141 }
2142
2143 =head2 set_cache
2144
2145 =over 4
2146
2147 =item Arguments: \@cache_objects
2148
2149 =item Return Value: \@cache_objects
2150
2151 =back
2152
2153 Sets the contents of the cache for the resultset. Expects an arrayref
2154 of objects of the same class as those produced by the resultset. Note that
2155 if the cache is set the resultset will return the cached objects rather
2156 than re-querying the database even if the cache attr is not set.
2157
2158 The contents of the cache can also be populated by using the
2159 L</prefetch> attribute to L</search>.
2160
2161 =cut
2162
2163 sub set_cache {
2164   my ( $self, $data ) = @_;
2165   $self->throw_exception("set_cache requires an arrayref")
2166       if defined($data) && (ref $data ne 'ARRAY');
2167   $self->{all_cache} = $data;
2168 }
2169
2170 =head2 clear_cache
2171
2172 =over 4
2173
2174 =item Arguments: none
2175
2176 =item Return Value: []
2177
2178 =back
2179
2180 Clears the cache for the resultset.
2181
2182 =cut
2183
2184 sub clear_cache {
2185   shift->set_cache(undef);
2186 }
2187
2188 =head2 related_resultset
2189
2190 =over 4
2191
2192 =item Arguments: $relationship_name
2193
2194 =item Return Value: $resultset
2195
2196 =back
2197
2198 Returns a related resultset for the supplied relationship name.
2199
2200   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2201
2202 =cut
2203
2204 sub related_resultset {
2205   my ($self, $rel) = @_;
2206
2207   $self->{related_resultsets} ||= {};
2208   return $self->{related_resultsets}{$rel} ||= do {
2209     my $rel_obj = $self->result_source->relationship_info($rel);
2210
2211     $self->throw_exception(
2212       "search_related: result source '" . $self->result_source->source_name .
2213         "' has no such relationship $rel")
2214       unless $rel_obj;
2215
2216     my ($from,$seen) = $self->_resolve_from($rel);
2217
2218     my $join_count = $seen->{$rel};
2219     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2220
2221     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2222     my %attrs = %{$self->{attrs}||{}};
2223     delete @attrs{qw(result_class alias)};
2224
2225     my $new_cache;
2226
2227     if (my $cache = $self->get_cache) {
2228       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2229         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2230                         @$cache ];
2231       }
2232     }
2233
2234     my $rel_source = $self->result_source->related_source($rel);
2235
2236     my $new = do {
2237
2238       # The reason we do this now instead of passing the alias to the
2239       # search_rs below is that if you wrap/overload resultset on the
2240       # source you need to know what alias it's -going- to have for things
2241       # to work sanely (e.g. RestrictWithObject wants to be able to add
2242       # extra query restrictions, and these may need to be $alias.)
2243
2244       my $attrs = $rel_source->resultset_attributes;
2245       local $attrs->{alias} = $alias;
2246
2247       $rel_source->resultset
2248                  ->search_rs(
2249                      undef, {
2250                        %attrs,
2251                        join => undef,
2252                        prefetch => undef,
2253                        select => undef,
2254                        as => undef,
2255                        where => $self->{cond},
2256                        seen_join => $seen,
2257                        from => $from,
2258                    });
2259     };
2260     $new->set_cache($new_cache) if $new_cache;
2261     $new;
2262   };
2263 }
2264
2265 =head2 current_source_alias
2266
2267 =over 4
2268
2269 =item Arguments: none
2270
2271 =item Return Value: $source_alias
2272
2273 =back
2274
2275 Returns the current table alias for the result source this resultset is built
2276 on, that will be used in the SQL query. Usually it is C<me>.
2277
2278 Currently the source alias that refers to the result set returned by a
2279 L</search>/L</find> family method depends on how you got to the resultset: it's
2280 C<me> by default, but eg. L</search_related> aliases it to the related result
2281 source name (and keeps C<me> referring to the original result set). The long
2282 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2283 (and make this method unnecessary).
2284
2285 Thus it's currently necessary to use this method in predefined queries (see
2286 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2287 source alias of the current result set:
2288
2289   # in a result set class
2290   sub modified_by {
2291     my ($self, $user) = @_;
2292
2293     my $me = $self->current_source_alias;
2294
2295     return $self->search(
2296       "$me.modified" => $user->id,
2297     );
2298   }
2299
2300 =cut
2301
2302 sub current_source_alias {
2303   my ($self) = @_;
2304
2305   return ($self->{attrs} || {})->{alias} || 'me';
2306 }
2307
2308 sub _resolve_from {
2309   my ($self, $extra_join) = @_;
2310   my $source = $self->result_source;
2311   my $attrs = $self->{attrs};
2312
2313   my $from = $attrs->{from}
2314     || [ { $attrs->{alias} => $source->from } ];
2315
2316   my $seen = { %{$attrs->{seen_join}||{}} };
2317
2318   my $join = ($attrs->{join}
2319                ? [ $attrs->{join}, $extra_join ]
2320                : $extra_join);
2321
2322   # we need to take the prefetch the attrs into account before we
2323   # ->resolve_join as otherwise they get lost - captainL
2324   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2325
2326   $from = [
2327     @$from,
2328     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2329   ];
2330
2331   return ($from,$seen);
2332 }
2333
2334 sub _resolved_attrs {
2335   my $self = shift;
2336   return $self->{_attrs} if $self->{_attrs};
2337
2338   my $attrs  = { %{ $self->{attrs} || {} } };
2339   my $source = $self->result_source;
2340   my $alias  = $attrs->{alias};
2341
2342   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2343   my @colbits;
2344
2345   # build columns (as long as select isn't set) into a set of as/select hashes
2346   unless ( $attrs->{select} ) {
2347       @colbits = map {
2348           ( ref($_) eq 'HASH' )
2349               ? $_
2350               : {
2351                   (
2352                     /^\Q${alias}.\E(.+)$/
2353                       ? "$1"
2354                       : "$_"
2355                   )
2356                 =>
2357                   (
2358                     /\./
2359                       ? "$_"
2360                       : "${alias}.$_"
2361                   )
2362             }
2363       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2364   }
2365   # add the additional columns on
2366   foreach ( 'include_columns', '+columns' ) {
2367       push @colbits, map {
2368           ( ref($_) eq 'HASH' )
2369             ? $_
2370             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2371       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2372   }
2373
2374   # start with initial select items
2375   if ( $attrs->{select} ) {
2376     $attrs->{select} =
2377         ( ref $attrs->{select} eq 'ARRAY' )
2378       ? [ @{ $attrs->{select} } ]
2379       : [ $attrs->{select} ];
2380     $attrs->{as} = (
2381       $attrs->{as}
2382       ? (
2383         ref $attrs->{as} eq 'ARRAY'
2384         ? [ @{ $attrs->{as} } ]
2385         : [ $attrs->{as} ]
2386         )
2387       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2388     );
2389   }
2390   else {
2391
2392     # otherwise we intialise select & as to empty
2393     $attrs->{select} = [];
2394     $attrs->{as}     = [];
2395   }
2396
2397   # now add colbits to select/as
2398   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2399   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2400
2401   my $adds;
2402   if ( $adds = delete $attrs->{'+select'} ) {
2403     $adds = [$adds] unless ref $adds eq 'ARRAY';
2404     push(
2405       @{ $attrs->{select} },
2406       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2407     );
2408   }
2409   if ( $adds = delete $attrs->{'+as'} ) {
2410     $adds = [$adds] unless ref $adds eq 'ARRAY';
2411     push( @{ $attrs->{as} }, @$adds );
2412   }
2413
2414   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2415
2416   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2417     my $join = delete $attrs->{join} || {};
2418
2419     if ( defined $attrs->{prefetch} ) {
2420       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2421
2422     }
2423
2424     $attrs->{from} =    # have to copy here to avoid corrupting the original
2425       [
2426       @{ $attrs->{from} },
2427       $source->resolve_join(
2428         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2429       )
2430       ];
2431
2432   }
2433
2434   $attrs->{group_by} ||= $attrs->{select}
2435     if delete $attrs->{distinct};
2436   if ( $attrs->{order_by} ) {
2437     $attrs->{order_by} = (
2438       ref( $attrs->{order_by} ) eq 'ARRAY'
2439       ? [ @{ $attrs->{order_by} } ]
2440       : [ $attrs->{order_by} ]
2441     );
2442   }
2443   else {
2444     $attrs->{order_by} = [];
2445   }
2446
2447   my $collapse = $attrs->{collapse} || {};
2448   if ( my $prefetch = delete $attrs->{prefetch} ) {
2449     $prefetch = $self->_merge_attr( {}, $prefetch );
2450     my @pre_order;
2451     my $seen = { %{ $attrs->{seen_join} || {} } };
2452     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2453
2454       # bring joins back to level of current class
2455       my @prefetch =
2456         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2457       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2458       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2459     }
2460     push( @{ $attrs->{order_by} }, @pre_order );
2461   }
2462   $attrs->{collapse} = $collapse;
2463
2464   if ( $attrs->{page} ) {
2465     $attrs->{offset} ||= 0;
2466     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2467   }
2468
2469   return $self->{_attrs} = $attrs;
2470 }
2471
2472 sub _rollout_attr {
2473   my ($self, $attr) = @_;
2474
2475   if (ref $attr eq 'HASH') {
2476     return $self->_rollout_hash($attr);
2477   } elsif (ref $attr eq 'ARRAY') {
2478     return $self->_rollout_array($attr);
2479   } else {
2480     return [$attr];
2481   }
2482 }
2483
2484 sub _rollout_array {
2485   my ($self, $attr) = @_;
2486
2487   my @rolled_array;
2488   foreach my $element (@{$attr}) {
2489     if (ref $element eq 'HASH') {
2490       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2491     } elsif (ref $element eq 'ARRAY') {
2492       #  XXX - should probably recurse here
2493       push( @rolled_array, @{$self->_rollout_array($element)} );
2494     } else {
2495       push( @rolled_array, $element );
2496     }
2497   }
2498   return \@rolled_array;
2499 }
2500
2501 sub _rollout_hash {
2502   my ($self, $attr) = @_;
2503
2504   my @rolled_array;
2505   foreach my $key (keys %{$attr}) {
2506     push( @rolled_array, { $key => $attr->{$key} } );
2507   }
2508   return \@rolled_array;
2509 }
2510
2511 sub _calculate_score {
2512   my ($self, $a, $b) = @_;
2513
2514   if (ref $b eq 'HASH') {
2515     my ($b_key) = keys %{$b};
2516     if (ref $a eq 'HASH') {
2517       my ($a_key) = keys %{$a};
2518       if ($a_key eq $b_key) {
2519         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2520       } else {
2521         return 0;
2522       }
2523     } else {
2524       return ($a eq $b_key) ? 1 : 0;
2525     }
2526   } else {
2527     if (ref $a eq 'HASH') {
2528       my ($a_key) = keys %{$a};
2529       return ($b eq $a_key) ? 1 : 0;
2530     } else {
2531       return ($b eq $a) ? 1 : 0;
2532     }
2533   }
2534 }
2535
2536 sub _merge_attr {
2537   my ($self, $orig, $import) = @_;
2538
2539   return $import unless defined($orig);
2540   return $orig unless defined($import);
2541
2542   $orig = $self->_rollout_attr($orig);
2543   $import = $self->_rollout_attr($import);
2544
2545   my $seen_keys;
2546   foreach my $import_element ( @{$import} ) {
2547     # find best candidate from $orig to merge $b_element into
2548     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2549     foreach my $orig_element ( @{$orig} ) {
2550       my $score = $self->_calculate_score( $orig_element, $import_element );
2551       if ($score > $best_candidate->{score}) {
2552         $best_candidate->{position} = $position;
2553         $best_candidate->{score} = $score;
2554       }
2555       $position++;
2556     }
2557     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2558
2559     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2560       push( @{$orig}, $import_element );
2561     } else {
2562       my $orig_best = $orig->[$best_candidate->{position}];
2563       # merge orig_best and b_element together and replace original with merged
2564       if (ref $orig_best ne 'HASH') {
2565         $orig->[$best_candidate->{position}] = $import_element;
2566       } elsif (ref $import_element eq 'HASH') {
2567         my ($key) = keys %{$orig_best};
2568         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2569       }
2570     }
2571     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2572   }
2573
2574   return $orig;
2575 }
2576
2577 sub result_source {
2578     my $self = shift;
2579
2580     if (@_) {
2581         $self->_source_handle($_[0]->handle);
2582     } else {
2583         $self->_source_handle->resolve;
2584     }
2585 }
2586
2587 =head2 throw_exception
2588
2589 See L<DBIx::Class::Schema/throw_exception> for details.
2590
2591 =cut
2592
2593 sub throw_exception {
2594   my $self=shift;
2595   if (ref $self && $self->_source_handle->schema) {
2596     $self->_source_handle->schema->throw_exception(@_)
2597   } else {
2598     croak(@_);
2599   }
2600
2601 }
2602
2603 # XXX: FIXME: Attributes docs need clearing up
2604
2605 =head1 ATTRIBUTES
2606
2607 Attributes are used to refine a ResultSet in various ways when
2608 searching for data. They can be passed to any method which takes an
2609 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2610 L</count>.
2611
2612 These are in no particular order:
2613
2614 =head2 order_by
2615
2616 =over 4
2617
2618 =item Value: ( $order_by | \@order_by | \%order_by )
2619
2620 =back
2621
2622 Which column(s) to order the results by. If a single column name, or
2623 an arrayref of names is supplied, the argument is passed through
2624 directly to SQL. The hashref syntax allows for connection-agnostic
2625 specification of ordering direction:
2626
2627  For descending order:
2628
2629   order_by => { -desc => [qw/col1 col2 col3/] }
2630
2631  For explicit ascending order:
2632
2633   order_by => { -asc => 'col' }
2634
2635 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2636 supported, although you are strongly encouraged to use the hashref
2637 syntax as outlined above.
2638
2639 =head2 columns
2640
2641 =over 4
2642
2643 =item Value: \@columns
2644
2645 =back
2646
2647 Shortcut to request a particular set of columns to be retrieved. Each
2648 column spec may be a string (a table column name), or a hash (in which
2649 case the key is the C<as> value, and the value is used as the C<select>
2650 expression). Adds C<me.> onto the start of any column without a C<.> in
2651 it and sets C<select> from that, then auto-populates C<as> from
2652 C<select> as normal. (You may also use the C<cols> attribute, as in
2653 earlier versions of DBIC.)
2654
2655 =head2 +columns
2656
2657 =over 4
2658
2659 =item Value: \@columns
2660
2661 =back
2662
2663 Indicates additional columns to be selected from storage. Works the same
2664 as L</columns> but adds columns to the selection. (You may also use the
2665 C<include_columns> attribute, as in earlier versions of DBIC). For
2666 example:-
2667
2668   $schema->resultset('CD')->search(undef, {
2669     '+columns' => ['artist.name'],
2670     join => ['artist']
2671   });
2672
2673 would return all CDs and include a 'name' column to the information
2674 passed to object inflation. Note that the 'artist' is the name of the
2675 column (or relationship) accessor, and 'name' is the name of the column
2676 accessor in the related table.
2677
2678 =head2 include_columns
2679
2680 =over 4
2681
2682 =item Value: \@columns
2683
2684 =back
2685
2686 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2687
2688 =head2 select
2689
2690 =over 4
2691
2692 =item Value: \@select_columns
2693
2694 =back
2695
2696 Indicates which columns should be selected from the storage. You can use
2697 column names, or in the case of RDBMS back ends, function or stored procedure
2698 names:
2699
2700   $rs = $schema->resultset('Employee')->search(undef, {
2701     select => [
2702       'name',
2703       { count => 'employeeid' },
2704       { sum => 'salary' }
2705     ]
2706   });
2707
2708 When you use function/stored procedure names and do not supply an C<as>
2709 attribute, the column names returned are storage-dependent. E.g. MySQL would
2710 return a column named C<count(employeeid)> in the above example.
2711
2712 =head2 +select
2713
2714 =over 4
2715
2716 Indicates additional columns to be selected from storage.  Works the same as
2717 L</select> but adds columns to the selection.
2718
2719 =back
2720
2721 =head2 +as
2722
2723 =over 4
2724
2725 Indicates additional column names for those added via L</+select>. See L</as>.
2726
2727 =back
2728
2729 =head2 as
2730
2731 =over 4
2732
2733 =item Value: \@inflation_names
2734
2735 =back
2736
2737 Indicates column names for object inflation. That is, C<as>
2738 indicates the name that the column can be accessed as via the
2739 C<get_column> method (or via the object accessor, B<if one already
2740 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2741
2742 The C<as> attribute is used in conjunction with C<select>,
2743 usually when C<select> contains one or more function or stored
2744 procedure names:
2745
2746   $rs = $schema->resultset('Employee')->search(undef, {
2747     select => [
2748       'name',
2749       { count => 'employeeid' }
2750     ],
2751     as => ['name', 'employee_count'],
2752   });
2753
2754   my $employee = $rs->first(); # get the first Employee
2755
2756 If the object against which the search is performed already has an accessor
2757 matching a column name specified in C<as>, the value can be retrieved using
2758 the accessor as normal:
2759
2760   my $name = $employee->name();
2761
2762 If on the other hand an accessor does not exist in the object, you need to
2763 use C<get_column> instead:
2764
2765   my $employee_count = $employee->get_column('employee_count');
2766
2767 You can create your own accessors if required - see
2768 L<DBIx::Class::Manual::Cookbook> for details.
2769
2770 Please note: This will NOT insert an C<AS employee_count> into the SQL
2771 statement produced, it is used for internal access only. Thus
2772 attempting to use the accessor in an C<order_by> clause or similar
2773 will fail miserably.
2774
2775 To get around this limitation, you can supply literal SQL to your
2776 C<select> attibute that contains the C<AS alias> text, eg:
2777
2778   select => [\'myfield AS alias']
2779
2780 =head2 join
2781
2782 =over 4
2783
2784 =item Value: ($rel_name | \@rel_names | \%rel_names)
2785
2786 =back
2787
2788 Contains a list of relationships that should be joined for this query.  For
2789 example:
2790
2791   # Get CDs by Nine Inch Nails
2792   my $rs = $schema->resultset('CD')->search(
2793     { 'artist.name' => 'Nine Inch Nails' },
2794     { join => 'artist' }
2795   );
2796
2797 Can also contain a hash reference to refer to the other relation's relations.
2798 For example:
2799
2800   package MyApp::Schema::Track;
2801   use base qw/DBIx::Class/;
2802   __PACKAGE__->table('track');
2803   __PACKAGE__->add_columns(qw/trackid cd position title/);
2804   __PACKAGE__->set_primary_key('trackid');
2805   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2806   1;
2807
2808   # In your application
2809   my $rs = $schema->resultset('Artist')->search(
2810     { 'track.title' => 'Teardrop' },
2811     {
2812       join     => { cd => 'track' },
2813       order_by => 'artist.name',
2814     }
2815   );
2816
2817 You need to use the relationship (not the table) name in  conditions,
2818 because they are aliased as such. The current table is aliased as "me", so
2819 you need to use me.column_name in order to avoid ambiguity. For example:
2820
2821   # Get CDs from 1984 with a 'Foo' track
2822   my $rs = $schema->resultset('CD')->search(
2823     {
2824       'me.year' => 1984,
2825       'tracks.name' => 'Foo'
2826     },
2827     { join => 'tracks' }
2828   );
2829
2830 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2831 similarly for a third time). For e.g.
2832
2833   my $rs = $schema->resultset('Artist')->search({
2834     'cds.title'   => 'Down to Earth',
2835     'cds_2.title' => 'Popular',
2836   }, {
2837     join => [ qw/cds cds/ ],
2838   });
2839
2840 will return a set of all artists that have both a cd with title 'Down
2841 to Earth' and a cd with title 'Popular'.
2842
2843 If you want to fetch related objects from other tables as well, see C<prefetch>
2844 below.
2845
2846 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2847
2848 =head2 prefetch
2849
2850 =over 4
2851
2852 =item Value: ($rel_name | \@rel_names | \%rel_names)
2853
2854 =back
2855
2856 Contains one or more relationships that should be fetched along with
2857 the main query (when they are accessed afterwards the data will
2858 already be available, without extra queries to the database).  This is
2859 useful for when you know you will need the related objects, because it
2860 saves at least one query:
2861
2862   my $rs = $schema->resultset('Tag')->search(
2863     undef,
2864     {
2865       prefetch => {
2866         cd => 'artist'
2867       }
2868     }
2869   );
2870
2871 The initial search results in SQL like the following:
2872
2873   SELECT tag.*, cd.*, artist.* FROM tag
2874   JOIN cd ON tag.cd = cd.cdid
2875   JOIN artist ON cd.artist = artist.artistid
2876
2877 L<DBIx::Class> has no need to go back to the database when we access the
2878 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2879 case.
2880
2881 Simple prefetches will be joined automatically, so there is no need
2882 for a C<join> attribute in the above search.
2883
2884 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2885 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2886 with an accessor type of 'single' or 'filter'). A more complex example that
2887 prefetches an artists cds, the tracks on those cds, and the tags associted
2888 with that artist is given below (assuming many-to-many from artists to tags):
2889
2890  my $rs = $schema->resultset('Artist')->search(
2891    undef,
2892    {
2893      prefetch => [
2894        { cds => 'tracks' },
2895        { artist_tags => 'tags' }
2896      ]
2897    }
2898  );
2899
2900
2901 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2902 attributes will be ignored.
2903
2904 =head2 page
2905
2906 =over 4
2907
2908 =item Value: $page
2909
2910 =back
2911
2912 Makes the resultset paged and specifies the page to retrieve. Effectively
2913 identical to creating a non-pages resultset and then calling ->page($page)
2914 on it.
2915
2916 If L<rows> attribute is not specified it defualts to 10 rows per page.
2917
2918 When you have a paged resultset, L</count> will only return the number
2919 of rows in the page. To get the total, use the L</pager> and call
2920 C<total_entries> on it.
2921
2922 =head2 rows
2923
2924 =over 4
2925
2926 =item Value: $rows
2927
2928 =back
2929
2930 Specifes the maximum number of rows for direct retrieval or the number of
2931 rows per page if the page attribute or method is used.
2932
2933 =head2 offset
2934
2935 =over 4
2936
2937 =item Value: $offset
2938
2939 =back
2940
2941 Specifies the (zero-based) row number for the  first row to be returned, or the
2942 of the first row of the first page if paging is used.
2943
2944 =head2 group_by
2945
2946 =over 4
2947
2948 =item Value: \@columns
2949
2950 =back
2951
2952 A arrayref of columns to group by. Can include columns of joined tables.
2953
2954   group_by => [qw/ column1 column2 ... /]
2955
2956 =head2 having
2957
2958 =over 4
2959
2960 =item Value: $condition
2961
2962 =back
2963
2964 HAVING is a select statement attribute that is applied between GROUP BY and
2965 ORDER BY. It is applied to the after the grouping calculations have been
2966 done.
2967
2968   having => { 'count(employee)' => { '>=', 100 } }
2969
2970 =head2 distinct
2971
2972 =over 4
2973
2974 =item Value: (0 | 1)
2975
2976 =back
2977
2978 Set to 1 to group by all columns.
2979
2980 =head2 where
2981
2982 =over 4
2983
2984 Adds to the WHERE clause.
2985
2986   # only return rows WHERE deleted IS NULL for all searches
2987   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2988
2989 Can be overridden by passing C<{ where => undef }> as an attribute
2990 to a resulset.
2991
2992 =back
2993
2994 =head2 cache
2995
2996 Set to 1 to cache search results. This prevents extra SQL queries if you
2997 revisit rows in your ResultSet:
2998
2999   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3000
3001   while( my $artist = $resultset->next ) {
3002     ... do stuff ...
3003   }
3004
3005   $rs->first; # without cache, this would issue a query
3006
3007 By default, searches are not cached.
3008
3009 For more examples of using these attributes, see
3010 L<DBIx::Class::Manual::Cookbook>.
3011
3012 =head2 from
3013
3014 =over 4
3015
3016 =item Value: \@from_clause
3017
3018 =back
3019
3020 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3021 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3022 clauses.
3023
3024 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3025
3026 C<join> will usually do what you need and it is strongly recommended that you
3027 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3028 And we really do mean "cannot", not just tried and failed. Attempting to use
3029 this because you're having problems with C<join> is like trying to use x86
3030 ASM because you've got a syntax error in your C. Trust us on this.
3031
3032 Now, if you're still really, really sure you need to use this (and if you're
3033 not 100% sure, ask the mailing list first), here's an explanation of how this
3034 works.
3035
3036 The syntax is as follows -
3037
3038   [
3039     { <alias1> => <table1> },
3040     [
3041       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3042       [], # nested JOIN (optional)
3043       { <table1.column1> => <table2.column2>, ... (more conditions) },
3044     ],
3045     # More of the above [ ] may follow for additional joins
3046   ]
3047
3048   <table1> <alias1>
3049   JOIN
3050     <table2> <alias2>
3051     [JOIN ...]
3052   ON <table1.column1> = <table2.column2>
3053   <more joins may follow>
3054
3055 An easy way to follow the examples below is to remember the following:
3056
3057     Anything inside "[]" is a JOIN
3058     Anything inside "{}" is a condition for the enclosing JOIN
3059
3060 The following examples utilize a "person" table in a family tree application.
3061 In order to express parent->child relationships, this table is self-joined:
3062
3063     # Person->belongs_to('father' => 'Person');
3064     # Person->belongs_to('mother' => 'Person');
3065
3066 C<from> can be used to nest joins. Here we return all children with a father,
3067 then search against all mothers of those children:
3068
3069   $rs = $schema->resultset('Person')->search(
3070       undef,
3071       {
3072           alias => 'mother', # alias columns in accordance with "from"
3073           from => [
3074               { mother => 'person' },
3075               [
3076                   [
3077                       { child => 'person' },
3078                       [
3079                           { father => 'person' },
3080                           { 'father.person_id' => 'child.father_id' }
3081                       ]
3082                   ],
3083                   { 'mother.person_id' => 'child.mother_id' }
3084               ],
3085           ]
3086       },
3087   );
3088
3089   # Equivalent SQL:
3090   # SELECT mother.* FROM person mother
3091   # JOIN (
3092   #   person child
3093   #   JOIN person father
3094   #   ON ( father.person_id = child.father_id )
3095   # )
3096   # ON ( mother.person_id = child.mother_id )
3097
3098 The type of any join can be controlled manually. To search against only people
3099 with a father in the person table, we could explicitly use C<INNER JOIN>:
3100
3101     $rs = $schema->resultset('Person')->search(
3102         undef,
3103         {
3104             alias => 'child', # alias columns in accordance with "from"
3105             from => [
3106                 { child => 'person' },
3107                 [
3108                     { father => 'person', -join_type => 'inner' },
3109                     { 'father.id' => 'child.father_id' }
3110                 ],
3111             ]
3112         },
3113     );
3114
3115     # Equivalent SQL:
3116     # SELECT child.* FROM person child
3117     # INNER JOIN person father ON child.father_id = father.id
3118
3119 If you need to express really complex joins or you need a subselect, you
3120 can supply literal SQL to C<from> via a scalar reference. In this case
3121 the contents of the scalar will replace the table name asscoiated with the
3122 resultsource.
3123
3124 WARNING: This technique might very well not work as expected on chained
3125 searches - you have been warned.
3126
3127     # Assuming the Event resultsource is defined as:
3128
3129         MySchema::Event->add_columns (
3130             sequence => {
3131                 data_type => 'INT',
3132                 is_auto_increment => 1,
3133             },
3134             location => {
3135                 data_type => 'INT',
3136             },
3137             type => {
3138                 data_type => 'INT',
3139             },
3140         );
3141         MySchema::Event->set_primary_key ('sequence');
3142
3143     # This will get back the latest event for every location. The column
3144     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3145     # combo to limit the resultset
3146
3147     $rs = $schema->resultset('Event');
3148     $table = $rs->result_source->name;
3149     $latest = $rs->search (
3150         undef,
3151         { from => \ "
3152             (SELECT e1.* FROM $table e1
3153                 JOIN $table e2
3154                     ON e1.location = e2.location
3155                     AND e1.sequence < e2.sequence
3156                 WHERE e2.sequence is NULL
3157             ) me",
3158         },
3159     );
3160
3161     # Equivalent SQL (with the DBIC chunks added):
3162
3163     SELECT me.sequence, me.location, me.type FROM
3164        (SELECT e1.* FROM events e1
3165            JOIN events e2
3166                ON e1.location = e2.location
3167                AND e1.sequence < e2.sequence
3168            WHERE e2.sequence is NULL
3169        ) me;
3170
3171 =head2 for
3172
3173 =over 4
3174
3175 =item Value: ( 'update' | 'shared' )
3176
3177 =back
3178
3179 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3180 ... FOR SHARED.
3181
3182 =cut
3183
3184 1;