lib/DBIx/Class/ResultClass/HashRefInflator.pm

   1 package DBIx::Class::ResultClass::HashRefInflator;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 DBIx::Class::ResultClass::HashRefInflator - Get raw hashrefs from a resultset
   9
  10 =head1 SYNOPSIS
  11
  12  use DBIx::Class::ResultClass::HashRefInflator;
  13
  14  my $rs = $schema->resultset('CD');
  15  $rs->result_class('DBIx::Class::ResultClass::HashRefInflator');
  16  while (my $hashref = $rs->next) {
  17    ...
  18  }
  19
  20   OR as an attribute:
  21
  22  my $rs = $schema->resultset('CD')->search({}, {
  23    result_class => 'DBIx::Class::ResultClass::HashRefInflator',
  24  });
  25  while (my $hashref = $rs->next) {
  26    ...
  27  }
  28
  29 =head1 DESCRIPTION
  30
  31 DBIx::Class is faster than older ORMs like Class::DBI but it still isn't
  32 designed primarily for speed. Sometimes you need to quickly retrieve the data
  33 from a massive resultset, while skipping the creation of fancy row objects.
  34 Specifying this class as a C<result_class> for a resultset will change C<< $rs->next >>
  35 to return a plain data hash-ref (or a list of such hash-refs if C<< $rs->all >> is used).
  36
  37 There are two ways of applying this class to a resultset:
  38
  39 =over
  40
  41 =item *
  42
  43 Specify C<< $rs->result_class >> on a specific resultset to affect only that
  44 resultset (and any chained off of it); or
  45
  46 =item *
  47
  48 Specify C<< __PACKAGE__->result_class >> on your source object to force all
  49 uses of that result source to be inflated to hash-refs - this approach is not
  50 recommended.
  51
  52 =back
  53
  54 =cut
  55
  56 ##############
  57 # NOTE
  58 #
  59 # Generally people use this to gain as much speed as possible. If a new &mk_hash is
  60 # implemented, it should be benchmarked using the maint/benchmark_hashrefinflator.pl
  61 # script (in addition to passing all tests of course :)
  62
  63 # This coderef is a simple recursive function
  64 # Arguments: ($me, $prefetch, $is_root) from inflate_result() below
  65 my $mk_hash;
  66 $mk_hash = sub {
  67
  68   my $hash = {
  69     # the main hash could be an undef if we are processing a skipped-over join
  70     $_[0] ? %{$_[0]} : (),
  71
  72     # the second arg is a hash of arrays for each prefetched relation
  73     map {
  74       ref $_[1]->{$_}[0] eq 'ARRAY' # multi rel or not?
  75         ? ( $_ => [ map
  76             { $mk_hash->(@$_) || () }
  77             @{$_[1]->{$_}}
  78         ] )
  79         : ( $_ => $mk_hash->( @{$_[1]->{$_}} ) )
  80
  81     } ( $_[1] ? ( keys %{$_[1]} ) : () )
  82   };
  83
  84   # if there is at least one defined column *OR* we are at the root of
  85   # the resultset - consider the result real (and not an emtpy has_many
  86   # rel containing one empty hashref)
  87   # an empty arrayref is an empty multi-sub-prefetch - don't consider
  88   # those either
  89   return $hash if $_[2];
  90
  91   for (values %$hash) {
  92     return $hash if (
  93       defined $_
  94         and
  95       (ref $_ ne 'ARRAY' or scalar @$_)
  96     );
  97   }
  98
  99   return undef;
 100 };
 101
 102 =head1 METHODS
 103
 104 =head2 inflate_result
 105
 106 Inflates the result and prefetched data into a hash-ref (invoked by L<DBIx::Class::ResultSet>)
 107
 108 =cut
 109
 110 ##################################################################################
 111 # inflate_result is invoked as:
 112 # HRI->inflate_result ($resultsource_instance, $main_data_hashref, $prefetch_data_hashref)
 113 sub inflate_result {
 114   return $mk_hash->($_[2], $_[3], 'is_root');
 115 }
 116
 117
 118 =head1 CAVEATS
 119
 120 =over
 121
 122 =item *
 123
 124 This will not work for relationships that have been prefetched. Consider the
 125 following:
 126
 127  my $artist = $artitsts_rs->search({}, {prefetch => 'cds' })->first;
 128
 129  my $cds = $artist->cds;
 130  $cds->result_class('DBIx::Class::ResultClass::HashRefInflator');
 131  my $first = $cds->first;
 132
 133 C<$first> will B<not> be a hashref, it will be a normal CD row since
 134 HashRefInflator only affects resultsets at inflation time, and prefetch causes
 135 relations to be inflated when the master C<$artist> row is inflated.
 136
 137 =item *
 138
 139 Column value inflation, e.g., using modules like
 140 L<DBIx::Class::InflateColumn::DateTime>, is not performed.
 141 The returned hash contains the raw database values.
 142
 143 =back
 144
 145 =cut
 146
 147 1;