lib/DBIx/Class/Relationship/ManyToMany.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::ManyToMany;
   3
   4 use strict;
   5 use warnings;
   6
   7 use DBIx::Class::Carp;
   8 use DBIx::Class::_Util qw( quote_sub perlstring );
   9
  10 # FIXME - this souldn't be needed
  11 my $cu;
  12 BEGIN { $cu = \&carp_unique }
  13
  14 use namespace::clean;
  15
  16 our %_pod_inherit_config =
  17   (
  18    class_map => { 'DBIx::Class::Relationship::ManyToMany' => 'DBIx::Class::Relationship' }
  19   );
  20
  21 sub many_to_many {
  22   my ($class, $meth, $rel, $f_rel, $rel_attrs) = @_;
  23
  24   $class->throw_exception(
  25     "missing relation in many-to-many"
  26   ) unless $rel;
  27
  28   $class->throw_exception(
  29     "missing foreign relation in many-to-many"
  30   ) unless $f_rel;
  31
  32     my $add_meth = "add_to_${meth}";
  33     my $remove_meth = "remove_from_${meth}";
  34     my $set_meth = "set_${meth}";
  35     my $rs_meth = "${meth}_rs";
  36
  37     for ($add_meth, $remove_meth, $set_meth, $rs_meth) {
  38       if ( $class->can ($_) ) {
  39         carp (<<"EOW") unless $ENV{DBIC_OVERWRITE_HELPER_METHODS_OK};
  40
  41 ***************************************************************************
  42 The many-to-many relationship '$meth' is trying to create a utility method
  43 called $_.
  44 This will completely overwrite one such already existing method on class
  45 $class.
  46
  47 You almost certainly want to rename your method or the many-to-many
  48 relationship, as the functionality of the original method will not be
  49 accessible anymore.
  50
  51 To disable this warning set to a true value the environment variable
  52 DBIC_OVERWRITE_HELPER_METHODS_OK
  53
  54 ***************************************************************************
  55 EOW
  56       }
  57     }
  58
  59     quote_sub "${class}::${meth}", sprintf( <<'EOC', $rs_meth );
  60
  61       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and DBIx::Class::_Util::fail_on_internal_call;
  62       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = DBIx::Class::_Util::fail_on_internal_wantarray;
  63
  64       my $rs = shift->%s( @_ );
  65
  66       wantarray ? $rs->all : $rs;
  67 EOC
  68
  69
  70     my $qsub_attrs = {
  71       '$rel_attrs' => \{ alias => $f_rel, %{ $rel_attrs||{} } },
  72       '$carp_unique' => \$cu,
  73     };
  74
  75
  76     quote_sub "${class}::${rs_meth}", sprintf( <<'EOC', map { perlstring $_ } ( "${class}::${meth}", $rel, $f_rel ) ), $qsub_attrs;
  77
  78       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS
  79         and
  80       # allow nested calls from our ->many_to_many, see comment below
  81       ( (CORE::caller(1))[3] ne %s )
  82         and
  83       DBIx::Class::_Util::fail_on_internal_call;
  84
  85       # this little horror is there replicating a deprecation from
  86       # within search_rs() itself
  87       shift->related_resultset( %s )
  88             ->related_resultset( %s )
  89              ->search_rs (
  90                undef,
  91                ( @_ > 1 and ref $_[-1] eq 'HASH' )
  92                  ? { %%$rel_attrs, %%{ pop @_ } }
  93                  : $rel_attrs
  94              )->search_rs(@_)
  95       ;
  96 EOC
  97
  98
  99     quote_sub "${class}::${add_meth}", sprintf( <<'EOC', $add_meth, $rel, $f_rel ), $qsub_attrs;
 100
 101       ( @_ >= 2 and @_ <= 3 ) or $_[0]->throw_exception(
 102         "'%1$s' expects an object or hashref to link to, and an optional hashref of link data"
 103       );
 104
 105       $_[0]->throw_exception(
 106         "The optional link data supplied to '%1$s' is not a hashref (it was previously ignored)"
 107       ) if $_[2] and ref $_[2] ne 'HASH';
 108
 109       my( $self, $far_obj ) = @_;
 110
 111       my $guard;
 112
 113       # the API is always expected to return the far object, possibly
 114       # creating it in the process
 115       if( not defined Scalar::Util::blessed( $far_obj ) ) {
 116
 117         $guard = $self->result_source->schema->storage->txn_scope_guard;
 118
 119         # reify the hash into an actual object
 120         $far_obj = $self->result_source
 121                          ->related_source( q{%2$s} )
 122                           ->related_source( q{%3$s} )
 123                            ->resultset
 124                             ->search_rs( undef, $rel_attrs )
 125                              ->find_or_create( $far_obj );
 126       }
 127
 128       my $link = $self->new_related(
 129         q{%2$s},
 130         $_[2] || {},
 131       );
 132
 133       $link->set_from_related( q{%3$s}, $far_obj );
 134
 135       $link->insert();
 136
 137       $guard->commit if $guard;
 138
 139       $far_obj;
 140 EOC
 141
 142
 143     quote_sub "${class}::${set_meth}", sprintf( <<'EOC', $set_meth, $add_meth, $rel, $f_rel ), $qsub_attrs;
 144
 145       my $self = shift;
 146
 147       my $set_to = ( ref $_[0] eq 'ARRAY' )
 148         ? ( shift @_ )
 149         : do {
 150           $carp_unique->(
 151             "Calling '%1$s' with a list of items to link to is deprecated, use an arrayref instead"
 152           );
 153
 154           # gobble up everything from @_ into a new arrayref
 155           [ splice @_ ]
 156         }
 157       ;
 158
 159       # make sure folks are not invoking a bizarre mix of deprecated and curent syntax
 160       $self->throw_exception(
 161         "'%1$s' expects an arrayref of objects or hashrefs to link to, and an optional hashref of link data"
 162       ) if (
 163         @_ > 1
 164           or
 165         ( defined $_[0] and ref $_[0] ne 'HASH' )
 166       );
 167
 168       my $guard;
 169
 170       # there will only be a single delete() op, unless we have what to set to
 171       $guard = $self->result_source->schema->storage->txn_scope_guard
 172         if @$set_to;
 173
 174       # if there is a where clause in the attributes, ensure we only delete
 175       # rows that are within the where restriction
 176       $self->related_resultset( q{%3$s} )
 177             ->search_rs(
 178               ( $rel_attrs->{where}
 179                 ? ( $rel_attrs->{where}, { join => q{%4$s} } )
 180                 : ()
 181               )
 182             )->delete;
 183
 184       # add in the set rel objects
 185       $self->%2$s(
 186         $_,
 187         @_, # at this point @_ is either empty or contains a lone link-data hash
 188       ) for @$set_to;
 189
 190       $guard->commit if $guard;
 191 EOC
 192
 193
 194     quote_sub "${class}::${remove_meth}", sprintf( <<'EOC', $remove_meth, $rel, $f_rel );
 195
 196       $_[0]->throw_exception("'%1$s' expects an object")
 197         unless defined Scalar::Util::blessed( $_[1] );
 198
 199       $_[0]->related_resultset( q{%2$s} )
 200             ->search_rs( $_[1]->ident_condition( q{%3$s} ), { join => q{%3$s} } )
 201              ->delete;
 202 EOC
 203
 204 }
 205
 206 1;