lib/DBIx/Class/Relationship/HasOne.pm

   1 package DBIx::Class::Relationship::HasOne;
   2
   3 use strict;
   4 use warnings;
   5
   6 sub might_have {
   7   shift->_has_one('LEFT' => @_);
   8 }
   9
  10 sub has_one {
  11   shift->_has_one(undef() => @_);
  12 }
  13
  14 sub _has_one {
  15   my ($class, $join_type, $rel, $f_class, $cond, $attrs) = @_;
  16   eval "require $f_class";
  17   if ($@) {
  18     $class->throw_exception($@) unless $@ =~ /Can't locate/;
  19   }
  20
  21   unless (ref $cond) {
  22     my ($pri, $too_many) = $class->primary_columns;
  23     $class->throw_exception( "might_have/has_one can only infer join for a single primary key; ${class} has more" )
  24       if $too_many;
  25     my $f_class_loaded = eval { $f_class->columns };
  26     my ($f_key,$guess);
  27     if (defined $cond && length $cond) {
  28       $f_key = $cond;
  29       $guess = "caller specified foreign key '$f_key'";
  30     } elsif ($f_class_loaded && $f_class->has_column($rel)) {
  31       $f_key = $rel;
  32       $guess = "using given relationship '$rel' for foreign key";
  33     } else {
  34       ($f_key, $too_many) = $f_class->primary_columns;
  35       $class->throw_exception( "might_have/has_one can only infer join for a single primary key; ${f_class} has more" )
  36         if $too_many;
  37       $guess = "using primary key of foreign class for foreign key";
  38     }
  39     $class->throw_exception("No such column ${f_key} on foreign class ${f_class} ($guess)")
  40       if $f_class_loaded && !$f_class->has_column($f_key);
  41     $cond = { "foreign.${f_key}" => "self.${pri}" };
  42   }
  43   $class->add_relationship($rel, $f_class,
  44    $cond,
  45    { accessor => 'single',
  46      cascade_update => 1, cascade_delete => 1,
  47      ($join_type ? ('join_type' => $join_type) : ()),
  48      %{$attrs || {}} });
  49   1;
  50 }
  51
  52 1;