lib/DBIx/Class/Relationship/HasOne.pm

   1 package DBIx::Class::Relationship::HasOne;
   2
   3 use strict;
   4 use warnings;
   5
   6 sub might_have {
   7   shift->_has_one('LEFT' => @_);
   8 }
   9
  10 sub has_one {
  11   shift->_has_one(undef => @_);
  12 }
  13
  14 sub _has_one {
  15   my ($class, $join_type, $rel, $f_class, $cond, $attrs) = @_;
  16   eval "require $f_class";
  17   unless (ref $cond) {
  18     my ($pri, $too_many) = $class->primary_columns;
  19     $class->throw( "might_have/has_one can only infer join for a single primary key; ${class} has more" )
  20       if $too_many;
  21     my $f_key;
  22     my $f_class_loaded = eval { $f_class->columns };
  23     my $guess;
  24     if (defined $cond && length $cond) {
  25       $f_key = $cond;
  26       $guess = "caller specified foreign key '$f_key'";
  27     } elsif ($f_class_loaded && $f_class->has_column($rel)) {
  28       $f_key = $rel;
  29       $guess = "using given relationship '$rel' for foreign key";
  30     } else {
  31       ($f_key, $too_many) = $f_class->primary_columns;
  32       $class->throw( "might_have/has_one can only infer join for a single primary key; ${f_class} has more" )
  33         if $too_many;
  34       $guess = "using primary key of foreign class for foreign key";
  35     }
  36     $class->throw("No such column ${f_key} on foreign class ${f_class} ($guess)")
  37       if $f_class_loaded && !$f_class->has_column($f_key);
  38     $cond = { "foreign.${f_key}" => "self.${pri}" };
  39   }
  40   $class->add_relationship($rel, $f_class,
  41    $cond,
  42    { accessor => 'single',
  43      cascade_update => 1, cascade_delete => 1,
  44      ($join_type ? ('join_type' => $join_type) : ()),
  45      %{$attrs || {}} });
  46   1;
  47 }
  48
  49 1;