lib/DBIx/Class/Relationship/HasMany.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::HasMany;
   3
   4 use strict;
   5 use warnings;
   6 use Try::Tiny;
   7 use namespace::clean;
   8
   9 our %_pod_inherit_config =
  10   (
  11    class_map => { 'DBIx::Class::Relationship::HasMany' => 'DBIx::Class::Relationship' }
  12   );
  13
  14 sub has_many {
  15   my ($class, $rel, $f_class, $cond, $attrs) = @_;
  16
  17   unless (ref $cond) {
  18     $class->ensure_class_loaded($f_class);
  19
  20     my $pri = $class->result_source_instance->_single_pri_col_or_die;
  21
  22     my ($f_key,$guess);
  23     if (defined $cond && length $cond) {
  24       $f_key = $cond;
  25       $guess = "caller specified foreign key '$f_key'";
  26     } else {
  27       $class =~ /([^\:]+)$/;  # match is safe - $class can't be ''
  28       $f_key = lc $1; # go ahead and guess; best we can do
  29       $guess = "using our class name '$class' as foreign key source";
  30     }
  31
  32     my $f_class_loaded = try { $f_class->columns };
  33     $class->throw_exception(
  34       "No such column '$f_key' on foreign class ${f_class} ($guess)"
  35     ) if $f_class_loaded && !$f_class->has_column($f_key);
  36
  37     $cond = { "foreign.${f_key}" => "self.${pri}" };
  38   }
  39
  40   my $default_cascade = ref $cond eq 'CODE' ? 0 : 1;
  41
  42   $class->add_relationship($rel, $f_class, $cond, {
  43     accessor => 'multi',
  44     join_type => 'LEFT',
  45     cascade_delete => $default_cascade,
  46     cascade_copy => $default_cascade,
  47     %{$attrs||{}}
  48   });
  49 }
  50
  51 1;