lib/DBIx/Class/Relationship/BelongsTo.pm

   1 package DBIx::Class::Relationship::BelongsTo;
   2
   3 use strict;
   4 use warnings;
   5
   6 sub belongs_to {
   7   my ($class, $rel, $f_class, $cond, $attrs) = @_;
   8   eval "require $f_class";
   9   if ($@) {
  10     $class->throw_exception($@) unless $@ =~ /Can't locate/;
  11   }
  12
  13   # no join condition or just a column name
  14   if (!ref $cond) {
  15     my %f_primaries = map { $_ => 1 } eval { $f_class->primary_columns };
  16     $class->throw_exception("Can't infer join condition for ${rel} on ${class}; unable to load ${f_class}")
  17       if $@;
  18
  19     my ($pri, $too_many) = keys %f_primaries;
  20     $class->throw_exception("Can't infer join condition for ${rel} on ${class}; ${f_class} has no primary keys")
  21       unless defined $pri;
  22     $class->throw_exception("Can't infer join condition for ${rel} on ${class}; ${f_class} has multiple primary keys")
  23       if $too_many;
  24
  25     my $fk = defined $cond ? $cond : $rel;
  26     $class->throw_exception("Can't infer join condition for ${rel} on ${class}; $fk is not a column")
  27       unless $class->has_column($fk);
  28
  29     my $acc_type = $class->has_column($rel) ? 'filter' : 'single';
  30     $class->add_relationship($rel, $f_class,
  31       { "foreign.${pri}" => "self.${fk}" },
  32       { accessor => $acc_type, %{$attrs || {}} }
  33     );
  34   }
  35   # explicit join condition
  36   elsif (ref $cond eq 'HASH') {
  37     my $cond_rel;
  38     for (keys %$cond) {
  39       if (m/\./) { # Explicit join condition
  40         $cond_rel = $cond;
  41         last;
  42       }
  43       $cond_rel->{"foreign.$_"} = "self.".$cond->{$_};
  44     }
  45     my $acc_type = (keys %$cond_rel == 1 and $class->has_column($rel)) ? 'filter' : 'single';
  46     $class->add_relationship($rel, $f_class,
  47       $cond_rel,
  48       { accessor => $acc_type, %{$attrs || {}} }
  49     );
  50   }
  51   else {
  52     $class->throw_exception('third argument for belongs_to must be undef, a column name, or a join condition');
  53   }
  54   return 1;
  55 }
  56
  57 =head1 AUTHORS
  58
  59 Alexander Hartmaier <Alexander.Hartmaier@t-systems.at>
  60
  61 Matt S. Trout <mst@shadowcatsystems.co.uk>
  62
  63 =cut
  64
  65 1;