lib/DBIx/Class/Relationship/BelongsTo.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::BelongsTo;
   3
   4 # Documentation for these methods can be found in
   5 # DBIx::Class::Relationship
   6
   7 use strict;
   8 use warnings;
   9
  10 sub belongs_to {
  11   my ($class, $rel, $f_class, $cond, $attrs) = @_;
  12   # no join condition or just a column name
  13   if (!ref $cond) {
  14     $class->ensure_class_loaded($f_class);
  15     my %f_primaries = map { $_ => 1 } eval { $f_class->primary_columns };
  16     $class->throw_exception(
  17       "Can't infer join condition for ${rel} on ${class}; ".
  18       "unable to load ${f_class}: $@"
  19     ) if $@;
  20
  21     my ($pri, $too_many) = keys %f_primaries;
  22     $class->throw_exception(
  23       "Can't infer join condition for ${rel} on ${class}; ".
  24       "${f_class} has no primary keys"
  25     ) unless defined $pri;
  26     $class->throw_exception(
  27       "Can't infer join condition for ${rel} on ${class}; ".
  28       "${f_class} has multiple primary keys"
  29     ) if $too_many;
  30
  31     my $fk = defined $cond ? $cond : $rel;
  32     $class->throw_exception(
  33       "Can't infer join condition for ${rel} on ${class}; ".
  34       "$fk is not a column of $class"
  35     ) unless $class->has_column($fk);
  36
  37     my $acc_type = $class->has_column($rel) ? 'filter' : 'single';
  38     $class->add_relationship($rel, $f_class,
  39       { "foreign.${pri}" => "self.${fk}" },
  40       { accessor => $acc_type, %{$attrs || {}} }
  41     );
  42   }
  43   # explicit join condition
  44   elsif (ref $cond eq 'HASH') {
  45     my $cond_rel;
  46     for (keys %$cond) {
  47       if (m/\./) { # Explicit join condition
  48         $cond_rel = $cond;
  49         last;
  50       }
  51       $cond_rel->{"foreign.$_"} = "self.".$cond->{$_};
  52     }
  53     my $acc_type = (keys %$cond_rel == 1 and $class->has_column($rel))
  54       ? 'filter'
  55       : 'single';
  56     $class->add_relationship($rel, $f_class,
  57       $cond_rel,
  58       { accessor => $acc_type, %{$attrs || {}} }
  59     );
  60   }
  61   else {
  62     $class->throw_exception(
  63       'third argument for belongs_to must be undef, a column name, '.
  64       'or a join condition'
  65     );
  66   }
  67   return 1;
  68 }
  69
  70 =head1 AUTHORS
  71
  72 Alexander Hartmaier <Alexander.Hartmaier@t-systems.at>
  73
  74 Matt S. Trout <mst@shadowcatsystems.co.uk>
  75
  76 =cut
  77
  78 1;