lib/DBIx/Class/Relationship/BelongsTo.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::BelongsTo;
   3
   4 # Documentation for these methods can be found in
   5 # DBIx::Class::Relationship
   6
   7 use strict;
   8 use warnings;
   9 use Try::Tiny;
  10 use namespace::clean;
  11
  12 our %_pod_inherit_config =
  13   (
  14    class_map => { 'DBIx::Class::Relationship::BelongsTo' => 'DBIx::Class::Relationship' }
  15   );
  16
  17 sub belongs_to {
  18   my ($class, $rel, $f_class, $cond, $attrs) = @_;
  19
  20   # assume a foreign key constraint unless defined otherwise
  21   $attrs->{is_foreign_key_constraint} = 1
  22     if not exists $attrs->{is_foreign_key_constraint};
  23   $attrs->{undef_on_null_fk} = 1
  24     if not exists $attrs->{undef_on_null_fk};
  25
  26   # no join condition or just a column name
  27   if (!ref $cond) {
  28     $class->ensure_class_loaded($f_class);
  29     my %f_primaries = map { $_ => 1 } try { $f_class->_pri_cols }
  30       catch {
  31         $class->throw_exception( "Can't infer join condition for '$rel' on ${class}: $_");
  32       };
  33
  34     my ($pri, $too_many) = keys %f_primaries;
  35     $class->throw_exception(
  36       "Can't infer join condition for '$rel' on ${class}: "
  37     . "${f_class} has multiple primary keys"
  38     ) if $too_many;
  39
  40     my $fk = defined $cond ? $cond : $rel;
  41     $class->throw_exception(
  42       "Can't infer join condition for '$rel' on ${class}: "
  43     . "'$fk' is not a column of $class"
  44     ) unless $class->has_column($fk);
  45
  46     $cond = { "foreign.${pri}" => "self.${fk}" };
  47
  48   }
  49   # explicit join condition
  50   elsif (ref $cond) {
  51     if (ref $cond eq 'HASH') { # ARRAY is also valid
  52       my $cond_rel;
  53       for (keys %$cond) {
  54         if (m/\./) { # Explicit join condition
  55           $cond_rel = $cond;
  56           last;
  57         }
  58         $cond_rel->{"foreign.$_"} = "self.".$cond->{$_};
  59       }
  60       $cond = $cond_rel;
  61     }
  62   }
  63   # dunno
  64   else {
  65     $class->throw_exception(
  66       'third argument for belongs_to must be undef, a column name, '.
  67       'or a join condition'
  68     );
  69   }
  70
  71   my $acc_type = (
  72     ref $cond eq 'HASH'
  73       and
  74     keys %$cond == 1
  75       and
  76     (keys %$cond)[0] =~ /^foreign\./
  77       and
  78     $class->has_column($rel)
  79   ) ? 'filter' : 'single';
  80
  81   my $fk_columns = ($acc_type eq 'single' and ref $cond eq 'HASH')
  82     ? { map { $_ =~ /^self\.(.+)/ ? ( $1 => 1 ) : () } (values %$cond ) }
  83     : undef
  84   ;
  85
  86   $class->add_relationship($rel, $f_class,
  87     $cond,
  88     {
  89       accessor => $acc_type,
  90       $fk_columns ? ( fk_columns => $fk_columns ) : (),
  91       %{$attrs || {}}
  92     }
  93   );
  94
  95   return 1;
  96 }
  97
  98 # Attempt to remove the POD so it (maybe) falls off the indexer
  99
 100 #=head1 AUTHORS
 101 #
 102 #Alexander Hartmaier <Alexander.Hartmaier@t-systems.at>
 103 #
 104 #Matt S. Trout <mst@shadowcatsystems.co.uk>
 105 #
 106 #=cut
 107
 108 1;