lib/DBIx/Class/Relationship/Accessor.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::Accessor;
   3
   4 use strict;
   5 use warnings;
   6 use Sub::Name ();
   7 use Class::Inspector ();
   8
   9 sub register_relationship {
  10   my ($class, $rel, $info) = @_;
  11   if (my $acc_type = $info->{attrs}{accessor}) {
  12     $class->add_relationship_accessor($rel => $acc_type);
  13   }
  14   $class->next::method($rel => $info);
  15 }
  16
  17 sub add_relationship_accessor {
  18   my ($class, $rel, $acc_type) = @_;
  19   my %meth;
  20   if ($acc_type eq 'single') {
  21     my $rel_info = $class->relationship_info($rel);
  22     $meth{$rel} = sub {
  23       my $self = shift;
  24       if (@_) {
  25         $self->set_from_related($rel, @_);
  26         return $self->{_relationship_data}{$rel} = $_[0];
  27       } elsif (exists $self->{_relationship_data}{$rel}) {
  28         return $self->{_relationship_data}{$rel};
  29       } else {
  30         my $cond = $self->result_source->resolve_condition(
  31           $rel_info->{cond}, $rel, $self
  32         );
  33         if ($rel_info->{attrs}->{undef_on_null_fk}){
  34           return unless ref($cond) eq 'HASH';
  35           return if grep { not defined } values %$cond;
  36         }
  37         my $val = $self->find_related($rel, {}, {});
  38
  39         # this really should have been:
  40         # return $val unless $val
  41         # however someone might already be relying on return() as in:
  42         # my @things = map { $_->might_have_acc } ($rs->all)
  43         # thus keeping the quirky behavior
  44         return unless defined $val;
  45
  46         return $self->{_relationship_data}{$rel} = $val;
  47       }
  48     };
  49   } elsif ($acc_type eq 'filter') {
  50     $class->throw_exception("No such column $rel to filter")
  51        unless $class->has_column($rel);
  52     my $f_class = $class->relationship_info($rel)->{class};
  53     $class->inflate_column($rel,
  54       { inflate => sub {
  55           my ($val, $self) = @_;
  56           return $self->find_or_new_related($rel, {}, {});
  57         },
  58         deflate => sub {
  59           my ($val, $self) = @_;
  60           $self->throw_exception("$val isn't a $f_class") unless $val->isa($f_class);
  61           return ($val->_ident_values)[0];
  62             # WARNING: probably breaks for multi-pri sometimes. FIXME
  63         }
  64       }
  65     );
  66   } elsif ($acc_type eq 'multi') {
  67     $meth{$rel} = sub { shift->search_related($rel, @_) };
  68     $meth{"${rel}_rs"} = sub { shift->search_related_rs($rel, @_) };
  69     $meth{"add_to_${rel}"} = sub { shift->create_related($rel, @_); };
  70   } else {
  71     $class->throw_exception("No such relationship accessor type $acc_type");
  72   }
  73   {
  74     no strict 'refs';
  75     no warnings 'redefine';
  76     foreach my $meth (keys %meth) {
  77       my $name = join '::', $class, $meth;
  78       *$name = Sub::Name::subname($name, $meth{$meth});
  79     }
  80   }
  81 }
  82
  83 1;