lib/DBIx/Class/Relationship/Accessor.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::Accessor;
   3
   4 use strict;
   5 use warnings;
   6 use Sub::Name ();
   7 use Class::Inspector ();
   8
   9 sub register_relationship {
  10   my ($class, $rel, $info) = @_;
  11   if (my $acc_type = $info->{attrs}{accessor}) {
  12     $class->add_relationship_accessor($rel => $acc_type);
  13   }
  14   $class->next::method($rel => $info);
  15 }
  16
  17 sub add_relationship_accessor {
  18   my ($class, $rel, $acc_type) = @_;
  19   my %meth;
  20   if ($acc_type eq 'single') {
  21     my $rel_cond = $class->relationship_info($rel)->{cond};
  22     $meth{$rel} = sub {
  23       my $self = shift;
  24       if (@_) {
  25         $self->set_from_related($rel, @_);
  26         return $self->{_relationship_data}{$rel} = $_[0];
  27       } elsif (exists $self->{_relationship_data}{$rel}) {
  28         return $self->{_relationship_data}{$rel};
  29       } else {
  30         my $cond = $self->result_source->resolve_condition(
  31           $rel_cond, $rel, $self
  32         );
  33         return if grep { not defined } values %$cond;
  34         my $val = $self->find_related($rel, {}, {});
  35         return unless $val;
  36         return $self->{_relationship_data}{$rel} = $val;
  37       }
  38     };
  39   } elsif ($acc_type eq 'filter') {
  40     $class->throw_exception("No such column $rel to filter")
  41        unless $class->has_column($rel);
  42     my $f_class = $class->relationship_info($rel)->{class};
  43     $class->inflate_column($rel,
  44       { inflate => sub {
  45           my ($val, $self) = @_;
  46           return $self->find_or_new_related($rel, {}, {});
  47         },
  48         deflate => sub {
  49           my ($val, $self) = @_;
  50           $self->throw_exception("$val isn't a $f_class") unless $val->isa($f_class);
  51           return ($val->_ident_values)[0];
  52             # WARNING: probably breaks for multi-pri sometimes. FIXME
  53         }
  54       }
  55     );
  56   } elsif ($acc_type eq 'multi') {
  57     $meth{$rel} = sub { shift->search_related($rel, @_) };
  58     $meth{"${rel}_rs"} = sub { shift->search_related_rs($rel, @_) };
  59     $meth{"add_to_${rel}"} = sub { shift->create_related($rel, @_); };
  60   } else {
  61     $class->throw_exception("No such relationship accessor type $acc_type");
  62   }
  63   {
  64     no strict 'refs';
  65     no warnings 'redefine';
  66     foreach my $meth (keys %meth) {
  67       my $name = join '::', $class, $meth;
  68       *$name = Sub::Name::subname($name, $meth{$meth});
  69     }
  70   }
  71 }
  72
  73 1;