lib/DBIx/Class/Relationship/Accessor.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::Accessor;
   3
   4 use strict;
   5 use warnings;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::_Util qw(quote_sub perlstring);
   8 use namespace::clean;
   9
  10 our %_pod_inherit_config =
  11   (
  12    class_map => { 'DBIx::Class::Relationship::Accessor' => 'DBIx::Class::Relationship' }
  13   );
  14
  15 sub register_relationship {
  16   my ($class, $rel, $info) = @_;
  17   if (my $acc_type = $info->{attrs}{accessor}) {
  18     $class->add_relationship_accessor($rel => $acc_type);
  19   }
  20   $class->next::method($rel => $info);
  21 }
  22
  23 sub add_relationship_accessor {
  24   my ($class, $rel, $acc_type) = @_;
  25
  26   if ($acc_type eq 'single') {
  27
  28     my @qsub_args = ( {}, {
  29       attributes => [qw(
  30         DBIC_method_is_single_relationship_accessor
  31         DBIC_method_is_generated_from_resultsource_metadata
  32       )]
  33     });
  34
  35
  36     quote_sub "${class}::${rel}" => sprintf(<<'EOC', perlstring $rel), @qsub_args;
  37       my $self = shift;
  38
  39       if (@_) {
  40         $self->set_from_related( %1$s => @_ );
  41         return $self->{_relationship_data}{%1$s} = $_[0];
  42       }
  43       elsif (exists $self->{_relationship_data}{%1$s}) {
  44         return $self->{_relationship_data}{%1$s};
  45       }
  46       else {
  47         my $rsrc = $self->result_source;
  48
  49         my $jfc;
  50
  51         return undef if (
  52
  53           $rsrc->relationship_info(%1$s)->{attrs}{undef_on_null_fk}
  54
  55             and
  56
  57           $jfc = ( $rsrc->resolve_relationship_condition(
  58             rel_name => %1$s,
  59             foreign_alias => %1$s,
  60             self_alias => 'me',
  61             self_result_object => $self,
  62           )->{join_free_condition} || {} )
  63
  64             and
  65
  66           grep { not defined $_ } values %%$jfc
  67         );
  68
  69         my $val = $self->related_resultset( %1$s )->single;
  70         return $val unless $val;  # $val instead of undef so that null-objects can go through
  71
  72         return $self->{_relationship_data}{%1$s} = $val;
  73       }
  74 EOC
  75   }
  76   elsif ($acc_type eq 'filter') {
  77
  78     my $rsrc = $class->result_source_instance;
  79
  80     $rsrc->throw_exception("No such column '$rel' to filter")
  81        unless $rsrc->has_column($rel);
  82
  83     my $f_class = $rsrc->relationship_info($rel)->{class};
  84
  85     $class->inflate_column($rel, {
  86       inflate => sub {
  87         my ($val, $self) = @_;
  88         return $self->find_or_new_related($rel, {});
  89       },
  90       deflate => sub {
  91         my ($val, $self) = @_;
  92         $self->throw_exception("'$val' isn't a $f_class") unless $val->isa($f_class);
  93
  94         # MASSIVE FIXME - this code assumes we pointed at the PK, but the belongs_to
  95         # helper does not check any of this
  96         # fixup the code a bit to make things saner, but ideally 'filter' needs to
  97         # be deprecated ASAP and removed shortly after
  98         # Not doing so before 0.08250 however, too many things in motion already
  99         my ($pk_col, @rest) = $val->result_source->_pri_cols_or_die;
 100         $self->throw_exception(
 101           "Relationship '$rel' of type 'filter' can not work with a multicolumn primary key on source '$f_class'"
 102         ) if @rest;
 103
 104         my $pk_val = $val->get_column($pk_col);
 105         carp_unique (
 106           "Unable to deflate 'filter'-type relationship '$rel' (related object "
 107         . "primary key not retrieved), assuming undef instead"
 108         ) if ( ! defined $pk_val and $val->in_storage );
 109
 110         return $pk_val;
 111       },
 112     });
 113
 114
 115     # god this is horrible...
 116     my $acc =
 117       $rsrc->columns_info->{$rel}{accessor}
 118         ||
 119       $rel
 120     ;
 121
 122     # because CDBI may elect to never make an accessor at all...
 123     if( my $main_cref = $class->can($acc) ) {
 124
 125       attributes->import(
 126         $class,
 127         $main_cref,
 128         qw(
 129           DBIC_method_is_filter_relationship_accessor
 130           DBIC_method_is_generated_from_resultsource_metadata
 131         ),
 132       );
 133
 134       if( my $extra_cref = $class->can("_${acc}_accessor") ) {
 135         attributes->import(
 136           $class,
 137           $extra_cref,
 138           qw(
 139             DBIC_method_is_filter_relationship_extra_accessor
 140             DBIC_method_is_generated_from_resultsource_metadata
 141           ),
 142         );
 143       }
 144     }
 145   }
 146   elsif ($acc_type eq 'multi') {
 147
 148
 149     my @qsub_args = (
 150       {},
 151       {
 152         attributes => [qw(
 153           DBIC_method_is_multi_relationship_accessor
 154           DBIC_method_is_generated_from_resultsource_metadata
 155           DBIC_method_is_indirect_sugar
 156         )]
 157       },
 158     );
 159
 160
 161     quote_sub "${class}::${rel}", sprintf( <<'EOC', perlstring $rel ), @qsub_args;
 162       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and DBIx::Class::_Util::fail_on_internal_call;
 163       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = DBIx::Class::_Util::fail_on_internal_wantarray;
 164       shift->related_resultset(%s)->search( @_ )
 165 EOC
 166
 167
 168     $qsub_args[1]{attributes}[0]
 169       =~ s/^DBIC_method_is_multi_relationship_accessor$/DBIC_method_is_multi_relationship_extra_accessor/
 170     or die "Unexpected attr '$qsub_args[1]{attributes}[0]' ...";
 171
 172
 173     quote_sub "${class}::${rel}_rs", sprintf( <<'EOC', perlstring $rel ), @qsub_args;
 174       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and DBIx::Class::_Util::fail_on_internal_call;
 175       shift->related_resultset(%s)->search_rs( @_ )
 176 EOC
 177
 178
 179     quote_sub "${class}::add_to_${rel}", sprintf( <<'EOC', perlstring $rel ), @qsub_args;
 180       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and DBIx::Class::_Util::fail_on_internal_call;
 181       shift->create_related( %s => @_ );
 182 EOC
 183
 184   }
 185   else {
 186     $class->throw_exception("No such relationship accessor type '$acc_type'");
 187   }
 188
 189 }
 190
 191 1;