lib/DBIx/Class/Relationship/Accessor.pm

   1 package DBIx::Class::Relationship::Accessor;
   2
   3 use strict;
   4 use warnings;
   5
   6 sub register_relationship {
   7   my ($class, $rel, $info) = @_;
   8   if (my $acc_type = $info->{attrs}{accessor}) {
   9     $class->add_relationship_accessor($rel => $acc_type);
  10   }
  11   $class->next::method($rel => $info);
  12 }
  13
  14 sub add_relationship_accessor {
  15   my ($class, $rel, $acc_type) = @_;
  16   my %meth;
  17   if ($acc_type eq 'single') {
  18     $meth{$rel} = sub {
  19       my $self = shift;
  20       if (@_) {
  21         $self->set_from_related($rel, @_);
  22         return $self->{_relationship_data}{$rel} = $_[0];
  23       } elsif (exists $self->{_relationship_data}{$rel}) {
  24         return $self->{_relationship_data}{$rel};
  25       } else {
  26         my $val = $self->find_related($rel, {}, {});
  27         return unless $val;
  28         return $self->{_relationship_data}{$rel} = $val;
  29       }
  30     };
  31   } elsif ($acc_type eq 'filter') {
  32     $class->throw("No such column $rel to filter")
  33        unless $class->has_column($rel);
  34     my $f_class = $class->relationship_info($rel)->{class};
  35     $class->inflate_column($rel,
  36       { inflate => sub {
  37           my ($val, $self) = @_;
  38           return $self->find_or_create_related($rel, {}, {});
  39         },
  40         deflate => sub {
  41           my ($val, $self) = @_;
  42           $self->throw("$val isn't a $f_class") unless $val->isa($f_class);
  43           return ($val->_ident_values)[0];
  44             # WARNING: probably breaks for multi-pri sometimes. FIXME
  45         }
  46       }
  47     );
  48   } elsif ($acc_type eq 'multi') {
  49     $meth{$rel} = sub { shift->search_related($rel, @_) };
  50     $meth{"add_to_${rel}"} = sub { shift->create_related($rel, @_); };
  51   } else {
  52     $class->throw("No such relationship accessor type $acc_type");
  53   }
  54   {
  55     no strict 'refs';
  56     no warnings 'redefine';
  57     foreach my $meth (keys %meth) {
  58       *{"${class}::${meth}"} = $meth{$meth};
  59     }
  60   }
  61 }
  62
  63 1;