lib/DBIx/Class/Relationship/Accessor.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::Accessor;
   3
   4 use strict;
   5 use warnings;
   6 use Sub::Name;
   7 use DBIx::Class::Carp;
   8 use DBIx::Class::_Util 'fail_on_internal_wantarray';
   9 use namespace::clean;
  10
  11 our %_pod_inherit_config =
  12   (
  13    class_map => { 'DBIx::Class::Relationship::Accessor' => 'DBIx::Class::Relationship' }
  14   );
  15
  16 sub register_relationship {
  17   my ($class, $rel, $info) = @_;
  18   if (my $acc_type = $info->{attrs}{accessor}) {
  19     $class->add_relationship_accessor($rel => $acc_type);
  20   }
  21   $class->next::method($rel => $info);
  22 }
  23
  24 sub add_relationship_accessor {
  25   my ($class, $rel, $acc_type) = @_;
  26   my %meth;
  27   if ($acc_type eq 'single') {
  28     my $rel_info = $class->relationship_info($rel);
  29     $meth{$rel} = sub {
  30       my $self = shift;
  31       if (@_) {
  32         $self->set_from_related($rel, @_);
  33         return $self->{_relationship_data}{$rel} = $_[0];
  34       } elsif (exists $self->{_relationship_data}{$rel}) {
  35         return $self->{_relationship_data}{$rel};
  36       } else {
  37         my $cond = $self->result_source->_resolve_condition(
  38           $rel_info->{cond}, $rel, $self, $rel
  39         );
  40         if ($rel_info->{attrs}->{undef_on_null_fk}){
  41           return undef unless ref($cond) eq 'HASH';
  42           return undef if grep { not defined $_ } values %$cond;
  43         }
  44         my $val = $self->find_related($rel, {}, {});
  45         return $val unless $val;  # $val instead of undef so that null-objects can go through
  46
  47         return $self->{_relationship_data}{$rel} = $val;
  48       }
  49     };
  50   } elsif ($acc_type eq 'filter') {
  51     $class->throw_exception("No such column '$rel' to filter")
  52        unless $class->has_column($rel);
  53     my $f_class = $class->relationship_info($rel)->{class};
  54     $class->inflate_column($rel,
  55       { inflate => sub {
  56           my ($val, $self) = @_;
  57           return $self->find_or_new_related($rel, {}, {});
  58         },
  59         deflate => sub {
  60           my ($val, $self) = @_;
  61           $self->throw_exception("'$val' isn't a $f_class") unless $val->isa($f_class);
  62
  63           # MASSIVE FIXME - this code assumes we pointed at the PK, but the belongs_to
  64           # helper does not check any of this
  65           # fixup the code a bit to make things saner, but ideally 'filter' needs to
  66           # be deprecated ASAP and removed shortly after
  67           # Not doing so before 0.08250 however, too many things in motion already
  68           my ($pk_col, @rest) = $val->result_source->_pri_cols_or_die;
  69           $self->throw_exception(
  70             "Relationship '$rel' of type 'filter' can not work with a multicolumn primary key on source '$f_class'"
  71           ) if @rest;
  72
  73           my $pk_val = $val->get_column($pk_col);
  74           carp_unique (
  75             "Unable to deflate 'filter'-type relationship '$rel' (related object "
  76           . "primary key not retrieved), assuming undef instead"
  77           ) if ( ! defined $pk_val and $val->in_storage );
  78
  79           return $pk_val;
  80         }
  81       }
  82     );
  83   } elsif ($acc_type eq 'multi') {
  84     $meth{$rel} = sub {
  85       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and wantarray and my $sog = fail_on_internal_wantarray($_[0]);
  86       shift->search_related($rel, @_)
  87     };
  88     $meth{"${rel}_rs"} = sub { shift->search_related_rs($rel, @_) };
  89     $meth{"add_to_${rel}"} = sub { shift->create_related($rel, @_); };
  90   } else {
  91     $class->throw_exception("No such relationship accessor type '$acc_type'");
  92   }
  93   {
  94     no strict 'refs';
  95     no warnings 'redefine';
  96     foreach my $meth (keys %meth) {
  97       my $name = join '::', $class, $meth;
  98       *$name = subname($name, $meth{$meth});
  99     }
 100   }
 101 }
 102
 103 1;