lib/DBIx/Class/Relationship.pm

   1 package DBIx::Class::Relationship;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class/;
   7
   8 __PACKAGE__->load_own_components(qw/
   9   Helpers
  10   Accessor
  11   CascadeActions
  12   ProxyMethods
  13   Base
  14 /);
  15
  16 =head1 NAME
  17
  18 DBIx::Class::Relationship - Inter-table relationships
  19
  20 =head1 SYNOPSIS
  21
  22   ## Creating relationships
  23   MyDB::Schema::Actor->has_many('actorroles' => 'MyDB::Schema::ActorRole',
  24                                 'actor');
  25   MyDB::Schema::Role->has_many('actorroles' => 'MyDB::Schema::ActorRole',
  26                                 'role');
  27   MyDB::Schema::ActorRole->belongs_to('role' => 'MyDB::Schema::Role');
  28   MyDB::Schema::ActorRole->belongs_to('actor' => 'MyDB::Schema::Actor');
  29
  30   MyDB::Schema::Role->many_to_many('actors' => 'actorroles', 'actor');
  31   MyDB::Schema::Actor->many_to_many('roles' => 'actorroles', 'role');
  32
  33   ## Using relationships
  34   $schema->resultset('Actor')->roles();
  35   $schema->resultset('Role')->search_related('actors', { Name => 'Fred' });
  36   $schema->resultset('ActorRole')->add_to_roles({ Name => 'Sherlock Holmes'});
  37
  38 See L<DBIx::Class::Manual::Cookbook> for more.
  39
  40 =head1 DESCRIPTION
  41
  42 This class provides methods to set up relationships between the tables
  43 in your database model. Relationships are the most useful and powerful
  44 technique that L<DBIx::Class> provides. To create efficient database queries,
  45 create relationships between any and all tables that have something in
  46 common, for example if you have a table Authors:
  47
  48   ID  | Name | Age
  49  ------------------
  50    1  | Fred | 30
  51    2  | Joe  | 32
  52
  53 and a table Books:
  54
  55   ID  | Author | Name
  56  --------------------
  57    1  |      1 | Rulers of the universe
  58    2  |      1 | Rulers of the galaxy
  59
  60 Then without relationships, the method of getting all books by Fred goes like
  61 this:
  62
  63  my $fred = $schema->resultset('Author')->find({ Name => 'Fred' });
  64  my $fredsbooks = $schema->resultset('Book')->search({ Author => $fred->ID });
  65
  66 With a has_many relationship called "books" on Author (see below for details),
  67 we can do this instead:
  68
  69  my $fredsbooks = $schema->resultset('Author')->find({ Name => 'Fred' })->books;
  70
  71 Each relationship sets up an accessor method on the
  72 L<DBIx::Class::Manual::Glossary/"Row"> objects that represent the items
  73 of your table. From L<DBIx::Class::Manual::Glossary/"ResultSet"> objects,
  74 the relationships can be searched using the "search_related" method.
  75 In list context, each returns a list of Row objects for the related class,
  76 in scalar context, a new ResultSet representing the joined tables is
  77 returned. Thus, the calls can be chained to produce complex queries.
  78 Since the database is not actually queried until you attempt to retrieve
  79 the data for an actual item, no time is wasted producing them.
  80
  81  my $cheapfredbooks = $schema->resultset('Author')->find({
  82    Name => 'Fred',
  83  })->books->search_related('prices', {
  84    Price => { '<=' => '5.00' },
  85  });
  86
  87 will produce a query something like:
  88
  89  SELECT * FROM Author me
  90  LEFT JOIN Books books ON books.author = me.id
  91  LEFT JOIN Prices prices ON prices.book = books.id
  92  WHERE prices.Price <= 5.00
  93
  94 all without needing multiple fetches.
  95
  96 Only the helper methods for setting up standard relationship types
  97 are documented here. For the basic, lower-level methods, and a description
  98 of all the useful *_related methods that you get for free, see
  99 L<DBIx::Class::Relationship::Base>.
 100
 101 =head1 METHODS
 102
 103 All helper methods are called similar to the following template:
 104
 105   __PACKAGE__->$method_name('relname', 'Foreign::Class', $cond, $attrs);
 106
 107 Both C<$cond> and C<$attrs> are optional. Pass C<undef> for C<$cond> if
 108 you want to use the default value for it, but still want to set C<$attrs>.
 109
 110 See L<DBIx::Class::Relationship::Base> for documentation on the
 111 attrubutes that are allowed in the C<$attrs> argument.
 112
 113
 114 =head2 belongs_to
 115
 116 =over 4
 117
 118 =item Arguments: $accessor_name, $related_class, $fk_column|\%cond|\@cond?, \%attr?
 119
 120 =back
 121
 122 Creates a relationship where the calling class stores the foreign
 123 class's primary key in one (or more) of its columns. This relationship
 124 defaults to using C<$accessor_name> as the column in this class
 125 to resolve the join against the primary key from C<$related_class>,
 126 unless C<$fk_column> specifies the foreign key column in this class or
 127 C<cond> specifies a reference to a join condition hash.
 128
 129 =over
 130
 131 =item accessor_name
 132
 133 This argument is the name of the method you can call on a
 134 L<DBIx::Class::Row> object to retrieve the instance of the foreign
 135 class matching this relationship. This is often called the
 136 C<relation(ship) name>.
 137
 138 Use this accessor_name in L<DBIx::Class::ResultSet/join>
 139 or L<DBIx::Class::ResultSet/prefetch> to join to the foreign table
 140 indicated by this relationship.
 141
 142 =item related_class
 143
 144 This is the class name of the table referenced by the foreign key in
 145 this class.
 146
 147 =item fk_column
 148
 149 The column name on this class that contains the foreign key.
 150
 151 OR
 152
 153 =item cond
 154
 155 A hashref where the keys are C<foreign.$column_on_related_table> and
 156 the values are C<self.$foreign_key_column>. This is useful for
 157 relations that are across multiple columns.
 158
 159 =back
 160
 161
 162   # in a Book class (where Author has many Books)
 163   My::DBIC::Schema::Book->belongs_to(
 164     author =>
 165     'My::DBIC::Schema::Author',
 166     'author_id'
 167   );
 168
 169   # OR (same result)
 170   My::DBIC::Schema::Book->belongs_to(
 171     author =>
 172     'My::DBIC::Schema::Author',
 173     { 'foreign.author_id' => 'self.author_id' }
 174   );
 175
 176   # OR (similar result but uglier accessor name)
 177   My::DBIC::Schema::Book->belongs_to(
 178     author_id =>
 179     'My::DBIC::Schema::Author'
 180   );
 181
 182   # Usage
 183   my $author_obj = $book->author; # get author object
 184   $book->author( $new_author_obj ); # set author object
 185   $book->author_id(); # get the plain id
 186
 187   # To retrieve the plain id if you used the ugly version:
 188   $book->get_column('author_id');
 189
 190
 191 If the relationship is optional -- i.e. the column containing the foreign key
 192 can be NULL -- then the belongs_to relationship does the right thing. Thus, in
 193 the example above C<$obj-E<gt>author> would return C<undef>.  However in this
 194 case you would probably want to set the C<join_type> attribute so that a C<LEFT
 195 JOIN> is done, which makes complex resultsets involving C<join> or C<prefetch>
 196 operations work correctly.  The modified declaration is shown below:
 197
 198   # in a Book class (where Author has_many Books)
 199   __PACKAGE__->belongs_to(
 200     author =>
 201     'My::DBIC::Schema::Author',
 202     'author',
 203     { join_type => 'left' }
 204   );
 205
 206
 207 Cascading deletes are off by default on a C<belongs_to>
 208 relationship. To turn them on, pass C<< cascade_delete => 1 >>
 209 in the $attr hashref.
 210
 211 NOTE: If you are used to L<Class::DBI> relationships, this is the equivalent
 212 of C<has_a>.
 213
 214 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 215 methods and valid relationship attributes.
 216
 217 =head2 has_many
 218
 219 =over 4
 220
 221 =item Arguments: $accessor_name, $related_class, $foreign_key_column|\%cond|\@cond?, \%attr?
 222
 223 =back
 224
 225 Creates a one-to-many relationship, where the corresponding elements
 226 of the foreign class store the calling class's primary key in one (or
 227 more) of its columns. This relationship defaults to using the end of
 228 this classes namespace as the foreign key in C<$related_class> to
 229 resolve the join, unless C<$foreign_key_column> specifies the foreign
 230 key column in C<$related_class> or C<cond> specifies a reference to a
 231 join condition hash.
 232
 233 =over
 234
 235 =item accessor_name
 236
 237 This argument is the name of the method you can call on a
 238 L<DBIx::Class::Row> object to retrieve a resultset of the related
 239 class restricted to the ones related to the row object. In list
 240 context it returns the row objects. This is often called the
 241 C<relation(ship) name>.
 242
 243 Use this accessor_name in L<DBIx::Class::ResultSet/join>
 244 or L<DBIx::Class::ResultSet/prefetch> to join to the foreign table
 245 indicated by this relationship.
 246
 247 =item related_class
 248
 249 This is the class name of the table which contains a foreign key
 250 column containing PK values of this class.
 251
 252 =item foreign_key_column
 253
 254 The column name on the related class that contains the foreign key.
 255
 256 OR
 257
 258 =item cond
 259
 260 A hashref where the keys are C<foreign.$foreign_key_column> and
 261 the values are C<self.$matching_column>. This is useful for
 262 relations that are across multiple columns.
 263
 264 OR
 265
 266 An arrayref containing an SQL::Abstract-like condition. For example a
 267 link table where two columns link back to the same table. This is an
 268 OR condition.
 269
 270   My::Schema::Item->has_many('rels', 'My::Schema::Relationships',
 271                              [ { 'foreign.LItemID' => 'self.ID' },
 272                                { 'foreign.RItemID' => 'self.ID'} ]);
 273
 274 =back
 275
 276   # in an Author class (where Author has_many Books)
 277   # assuming related class is storing our PK in "author_id"
 278   My::DBIC::Schema::Author->has_many(
 279     books =>
 280     'My::DBIC::Schema::Book',
 281     'author_id'
 282   );
 283
 284   # OR (same result)
 285   My::DBIC::Schema::Author->has_many(
 286     books =>
 287     'My::DBIC::Schema::Book',
 288     { 'foreign.author_id' => 'self.id' },
 289   );
 290
 291   # OR (similar result, assuming related_class is storing our PK, in "author")
 292   # (the "author" is guessed at from "Author" in the class namespace)
 293   My::DBIC::Schema::Author->has_many(
 294     books =>
 295     'My::DBIC::Schema::Book',
 296   );
 297
 298
 299   # Usage
 300   # resultset of Books belonging to author
 301   my $booklist = $author->books;
 302
 303   # resultset of Books belonging to author, restricted by author name
 304   my $booklist = $author->books({
 305     name => { LIKE => '%macaroni%' },
 306     { prefetch => [qw/book/],
 307   });
 308
 309   # array of Book objects belonging to author
 310   my @book_objs = $author->books;
 311
 312   # force resultset even in list context
 313   my $books_rs = $author->books;
 314   ( $books_rs ) = $obj->books_rs;
 315
 316   # create a new book for this author, the relation fields are auto-filled
 317   $author->create_related('books', \%col_data);
 318   # alternative method for the above
 319   $author->add_to_books(\%col_data);
 320
 321
 322 Three methods are created when you create a has_many relationship.  The first
 323 method is the expected accessor method, C<$accessor_name()>.  The second is
 324 almost exactly the same as the accessor method but "_rs" is added to the end of
 325 the method name.  This method works just like the normal accessor, except that
 326 it always returns a resultset, even in list context. The third method,
 327 named C<< add_to_$relname >>, will also be added to your Row items; this
 328 allows you to insert new related items, using the same mechanism as in
 329 L<DBIx::Class::Relationship::Base/"create_related">.
 330
 331 If you delete an object in a class with a C<has_many> relationship, all
 332 the related objects will be deleted as well.  To turn this behaviour off,
 333 pass C<< cascade_delete => 0 >> in the C<attr> hashref. However, any
 334 database-level cascade or restrict will take precedence over a
 335 DBIx-Class-based cascading delete.
 336
 337 If you copy an object in a class with a C<has_many> relationship, all
 338 the related objects will be copied as well. To turn this behaviour off,
 339 pass C<< cascade_copy => 0 >> in the C<$attr> hashref. The behaviour
 340 defaults to C<< cascade_copy => 1 >>.
 341
 342 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 343 methods and valid relationship attributes.
 344
 345 =head2 might_have
 346
 347 =over 4
 348
 349 =item Arguments: $accessor_name, $related_class, $foreign_key_column|\%cond|\@cond?, \%attr?
 350
 351 =back
 352
 353 Creates an optional one-to-one relationship with a class. This relationship
 354 defaults to using C<$accessor_name> as the foreign key in C<$related_class> to
 355 resolve the join, unless C<$foreign_key_column> specifies the foreign key
 356 column in C<$related_class> or C<cond> specifies a reference to a join
 357 condition hash.
 358
 359 =over
 360
 361 =item accessor_name
 362
 363 This argument is the name of the method you can call on a
 364 L<DBIx::Class::Row> object to retrieve the instance of the foreign
 365 class matching this relationship. This is often called the
 366 C<relation(ship) name>.
 367
 368 Use this accessor_name in L<DBIx::Class::ResultSet/join>
 369 or L<DBIx::Class::ResultSet/prefetch> to join to the foreign table
 370 indicated by this relationship.
 371
 372 =item related_class
 373
 374 This is the class name of the table which contains a foreign key
 375 column containing PK values of this class.
 376
 377 =item foreign_key_column
 378
 379 The column name on the related class that contains the foreign key.
 380
 381 OR
 382
 383 =item cond
 384
 385 A hashref where the keys are C<foreign.$column_on_related_table> and
 386 the values are C<self.$matching_column>. This is useful for
 387 relations that are across multiple columns.
 388
 389 =back
 390
 391   # Author may have an entry in the pseudonym table
 392   My::DBIC::Schema::Author->might_have(
 393     pseudonym =>
 394     'My::DBIC::Schema::Pseudonym',
 395     'author_id',
 396   );
 397
 398   # OR (same result, assuming the related_class stores our PK)
 399   My::DBIC::Schema::Author->might_have(
 400     pseudonym =>
 401     'My::DBIC::Schema::Pseudonym',
 402   );
 403
 404   # OR (same result)
 405   My::DBIC::Schema::Author->might_have(
 406     pseudonym =>
 407     'My::DBIC::Schema::Pseudonym',
 408     { 'foreign.author_id' => 'self.id' },
 409   );
 410
 411   # Usage
 412   my $pname = $author->pseudonym; # to get the Pseudonym object
 413
 414 If you update or delete an object in a class with a C<might_have>
 415 relationship, the related object will be updated or deleted as well. To
 416 turn off this behavior, add C<< cascade_delete => 0 >> to the C<$attr>
 417 hashref. Any database-level update or delete constraints will override
 418 this behavior.
 419
 420 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 421 methods and valid relationship attributes.
 422
 423 =head2 has_one
 424
 425 =over 4
 426
 427 =item Arguments: $accessor_name, $related_class, $foreign_key_column|\%cond|\@cond?, \%attr?
 428
 429 =back
 430
 431 Creates a one-to-one relationship with a class. This relationship
 432 defaults to using C<$accessor_name> as the foreign key in C<$related_class> to
 433 resolve the join, unless C<$foreign_key_column> specifies the foreign key
 434 column in C<$related_class> or C<cond> specifies a reference to a join
 435 condition hash.
 436
 437 =over
 438
 439 =item accessor_name
 440
 441 This argument is the name of the method you can call on a
 442 L<DBIx::Class::Row> object to retrieve the instance of the foreign
 443 class matching this relationship. This is often called the
 444 C<relation(ship) name>.
 445
 446 Use this accessor_name in L<DBIx::Class::ResultSet/join>
 447 or L<DBIx::Class::ResultSet/prefetch> to join to the foreign table
 448 indicated by this relationship.
 449
 450 =item related_class
 451
 452 This is the class name of the table which contains a foreign key
 453 column containing PK values of this class.
 454
 455 =item foreign_key_column
 456
 457 The column name on the related class that contains the foreign key.
 458
 459 OR
 460
 461 =item cond
 462
 463 A hashref where the keys are C<foreign.$column_on_related_table> and
 464 the values are C<self.$matching_column>. This is useful for
 465 relations that are across multiple columns.
 466
 467 =back
 468
 469   # Every book has exactly one ISBN
 470   My::DBIC::Schema::Book->has_one(
 471     isbn =>
 472     'My::DBIC::Schema::ISBN',
 473     'book_id',
 474   );
 475
 476   # OR (same result, assuming related_class stores our PK)
 477   My::DBIC::Schema::Book->has_one(
 478     isbn =>
 479     'My::DBIC::Schema::ISBN',
 480   );
 481
 482   # OR (same result)
 483   My::DBIC::Schema::Book->has_one(
 484     isbn =>
 485     'My::DBIC::Schema::ISBN',
 486     { 'foreign.book_id' => 'self.id' },
 487   );
 488
 489   # Usage
 490   my $isbn_obj = $book->isbn; # to get the ISBN object
 491
 492 Creates a one-to-one relationship with another class. This is just
 493 like C<might_have>, except the implication is that the other object is
 494 always present. The only difference between C<has_one> and
 495 C<might_have> is that C<has_one> uses an (ordinary) inner join,
 496 whereas C<might_have> defaults to a left join.
 497
 498 The has_one relationship should be used when a row in the table has exactly one
 499 related row in another table. If the related row might not exist in the foreign
 500 table, use the L<DBIx::Class::Relationship/might_have> relationship.
 501
 502 In the above example, each Book in the database is associated with exactly one
 503 ISBN object.
 504
 505 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 506 methods and valid relationship attributes.
 507
 508 =head2 many_to_many
 509
 510 =over 4
 511
 512 =item Arguments: $accessor_name, $link_rel_name, $foreign_rel_name, \%attr?
 513
 514 =back
 515
 516 C<many_to_many> is not strictly a relationship in its own right. Instead, it is
 517 a bridge between two resultsets which provide the same kind of convenience
 518 accessors as true relationships provide. Although the accessor will return a
 519 resultset or collection of objects just like has_many does, you cannot call
 520 C<related_resultset> and similar methods which operate on true relationships.
 521
 522 =over
 523
 524 =item accessor_name
 525
 526 This argument is the name of the method you can call on a
 527 L<DBIx::Class::Row> object to retrieve the rows matching this
 528 relationship.
 529
 530 On a many_to_many, unlike other relationships, this cannot be used in
 531 L<DBIx::Class::ResultSet/search> to join tables. Use the relations
 532 bridged across instead.
 533
 534 =item link_rel_name
 535
 536 This is the accessor_name from the has_many relationship we are
 537 bridging from.
 538
 539 =item foreign_rel_name
 540
 541 This is the accessor_name of the belongs_to relationship in the link
 542 table that we are bridging across (which gives us the table we are
 543 bridging to).
 544
 545 =back
 546
 547 To create a many_to_many relationship from Actor to Role:
 548
 549   My::DBIC::Schema::Actor->has_many( actor_roles =>
 550                                      'My::DBIC::Schema::ActorRoles',
 551                                      'actor' );
 552   My::DBIC::Schema::ActorRoles->belongs_to( role =>
 553                                             'My::DBIC::Schema::Role' );
 554   My::DBIC::Schema::ActorRoles->belongs_to( actor =>
 555                                             'My::DBIC::Schema::Actor' );
 556
 557   My::DBIC::Schema::Actor->many_to_many( roles => 'actor_roles',
 558                                          'role' );
 559
 560 And, for the reverse relationship, from Role to Actor:
 561
 562   My::DBIC::Schema::Role->has_many( actor_roles =>
 563                                     'My::DBIC::Schema::ActorRoles',
 564                                     'role' );
 565
 566   My::DBIC::Schema::Role->many_to_many( actors => 'actor_roles', 'actor' );
 567
 568 To add a role for your actor, and fill in the year of the role in the
 569 actor_roles table:
 570
 571   $actor->add_to_roles($role, { year => 1995 });
 572
 573 In the above example, ActorRoles is the link table class, and Role is the
 574 foreign class. The C<$link_rel_name> parameter is the name of the accessor for
 575 the has_many relationship from this table to the link table, and the
 576 C<$foreign_rel_name> parameter is the accessor for the belongs_to relationship
 577 from the link table to the foreign table.
 578
 579 To use many_to_many, existing relationships from the original table to the link
 580 table, and from the link table to the end table must already exist, these
 581 relation names are then used in the many_to_many call.
 582
 583 In the above example, the Actor class will have 3 many_to_many accessor methods
 584 set: C<roles>, C<add_to_roles>, C<set_roles>, and similarly named accessors
 585 will be created for the Role class for the C<actors> many_to_many
 586 relationship.
 587
 588 See L<DBIx::Class::Relationship::Base> for documentation on relationship
 589 methods and valid relationship attributes.
 590
 591 =cut
 592
 593 1;
 594
 595 =head1 AUTHORS
 596
 597 see L<DBIx::Class>
 598
 599 =head1 LICENSE
 600
 601 You may distribute this code under the same terms as Perl itself.
 602
 603 =cut
 604