lib/DBIx/Class/PK.pm

   1 package DBIx::Class::PK;
   2
   3 use strict;
   4 use warnings;
   5 use Tie::IxHash;
   6
   7 use base qw/Class::Data::Inheritable/;
   8
   9 __PACKAGE__->mk_classdata('_primaries' => {});
  10
  11 =head1 NAME
  12
  13 DBIx::Class::PK - Primary Key class
  14
  15 =head1 SYNOPSIS
  16
  17 =head1 DESCRIPTION
  18
  19 This class represents methods handling primary keys
  20 and depending on them.
  21
  22 =head1 METHODS
  23
  24 =over 4
  25
  26 =cut
  27
  28 sub _ident_cond {
  29   my ($class) = @_;
  30   return join(" AND ", map { "$_ = ?" } keys %{$class->_primaries});
  31 }
  32
  33 sub _ident_values {
  34   my ($self) = @_;
  35   return (map { $self->{_column_data}{$_} } keys %{$self->_primaries});
  36 }
  37
  38 sub set_primary_key {
  39   my ($class, @cols) = @_;
  40   my %pri;
  41   tie %pri, 'Tie::IxHash', map { $_ => {} } @cols;
  42   $class->_primaries(\%pri);
  43 }
  44
  45 sub find {
  46   my ($class, @vals) = @_;
  47   my $attrs = (@vals > 1 && ref $vals[$#vals] eq 'HASH' ? pop(@vals) : {});
  48   my @pk = keys %{$class->_primaries};
  49   $class->throw( "Can't find unless primary columns are defined" )
  50     unless @pk;
  51   my $query;
  52   if (ref $vals[0] eq 'HASH') {
  53     $query = $vals[0];
  54   } elsif (@pk == @vals) {
  55     $query = {};
  56     @{$query}{@pk} = @vals;
  57     #my $ret = ($class->search_literal($class->_ident_cond, @vals, $attrs))[0];
  58     #warn "$class: ".join(', ', %{$ret->{_column_data}});
  59     #return $ret;
  60   } else {
  61     $query = {@vals};
  62   }
  63   $class->throw( "Can't find unless all primary keys are specified" )
  64     unless (keys %$query >= @pk); # If we check 'em we run afoul of uc/lc
  65                                   # column names etc. Not sure what to do yet
  66   #return $class->search($query)->next;
  67   my @cols = $class->_select_columns;
  68   my @row = $class->storage->select_single($class->_table_name, \@cols, $query);
  69   return (@row ? $class->_row_to_object(\@cols, \@row) : ());
  70 }
  71
  72 sub discard_changes {
  73   my ($self) = @_;
  74   delete $self->{_dirty_columns};
  75   return unless $self->in_storage; # Don't reload if we aren't real!
  76   my ($reload) = $self->find($self->id);
  77   unless ($reload) { # If we got deleted in the mean-time
  78     $self->in_storage(0);
  79     return $self;
  80   }
  81   delete @{$self}{keys %$self};
  82   @{$self}{keys %$reload} = values %$reload;
  83   #$self->store_column($_ => $reload->get_column($_))
  84   #  foreach keys %{$self->_columns};
  85   return $self;
  86 }
  87
  88 sub id {
  89   my ($self) = @_;
  90   $self->throw( "Can't call id() as a class method" ) unless ref $self;
  91   my @pk = $self->_ident_values;
  92   return (wantarray ? @pk : $pk[0]);
  93 }
  94
  95 sub primary_columns {
  96   return keys %{shift->_primaries};
  97 }
  98
  99 sub ID {
 100   my ($self) = @_;
 101   $self->throw( "Can't call ID() as a class method" ) unless ref $self;
 102   return undef unless $self->in_storage;
 103   return $self->_create_ID(map { $_ => $self->{_column_data}{$_} } keys %{$self->_primaries});
 104 }
 105
 106 sub _create_ID {
 107   my ($class,%vals) = @_;
 108   $class = ref $class || $class;
 109   return join '|', $class, map { $_ . '=' . $vals{$_} } sort keys %vals;
 110 }
 111
 112 1;
 113
 114 =back
 115
 116 =head1 AUTHORS
 117
 118 Matt S. Trout <mst@shadowcatsystems.co.uk>
 119
 120 =head1 LICENSE
 121
 122 You may distribute this code under the same terms as Perl itself.
 123
 124 =cut
 125