lib/DBIx/Class/PK.pm

   1 package DBIx::Class::PK;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base qw/DBIx::Class::Row/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::PK - Primary Key class
  11
  12 =head1 SYNOPSIS
  13
  14 =head1 DESCRIPTION
  15
  16 This class contains methods for handling primary keys and methods
  17 depending on them.
  18
  19 =head1 METHODS
  20
  21 =cut
  22
  23 sub _ident_values {
  24   my ($self) = @_;
  25   return (map { $self->{_column_data}{$_} } $self->primary_columns);
  26 }
  27
  28 =head2 discard_changes
  29
  30 Re-selects the row from the database, losing any changes that had
  31 been made.
  32
  33 This method can also be used to refresh from storage, retrieving any
  34 changes made since the row was last read from storage.
  35
  36 =cut
  37
  38 sub discard_changes {
  39   my ($self) = @_;
  40   my $storage = $self->result_source->schema->storage;
  41   $storage->reload_row($self);
  42   return $self;
  43 }
  44
  45 =head2 id
  46
  47 Returns the primary key(s) for a row. Can't be called as
  48 a class method.
  49
  50 =cut
  51
  52 sub id {
  53   my ($self) = @_;
  54   $self->throw_exception( "Can't call id() as a class method" )
  55     unless ref $self;
  56   my @pk = $self->_ident_values;
  57   return (wantarray ? @pk : $pk[0]);
  58 }
  59
  60 =head2 ID
  61
  62 Returns a unique id string identifying a row object by primary key.
  63 Used by L<DBIx::Class::CDBICompat::LiveObjectIndex> and
  64 L<DBIx::Class::ObjectCache>.
  65
  66 =cut
  67
  68 sub ID {
  69   my ($self) = @_;
  70   $self->throw_exception( "Can't call ID() as a class method" )
  71     unless ref $self;
  72   return undef unless $self->in_storage;
  73   return $self->_create_ID(map { $_ => $self->{_column_data}{$_} }
  74                              $self->primary_columns);
  75 }
  76
  77 sub _create_ID {
  78   my ($self,%vals) = @_;
  79   return undef unless 0 == grep { !defined } values %vals;
  80   return join '|', ref $self || $self, $self->result_source->name,
  81     map { $_ . '=' . $vals{$_} } sort keys %vals;
  82 }
  83
  84 =head2 ident_condition
  85
  86   my $cond = $result_source->ident_condition();
  87
  88   my $cond = $result_source->ident_condition('alias');
  89
  90 Produces a condition hash to locate a row based on the primary key(s).
  91
  92 =cut
  93
  94 sub ident_condition {
  95   my ($self, $alias) = @_;
  96   my %cond;
  97   my $prefix = defined $alias ? $alias.'.' : '';
  98   $cond{$prefix.$_} = $self->get_column($_) for $self->primary_columns;
  99   return \%cond;
 100 }
 101
 102 1;
 103
 104 =head1 AUTHORS
 105
 106 Matt S. Trout <mst@shadowcatsystems.co.uk>
 107
 108 =head1 LICENSE
 109
 110 You may distribute this code under the same terms as Perl itself.
 111
 112 =cut
 113