lib/DBIx/Class/Manual/Example.pod

   1 =head1 NAME
   2
   3 DBIx::Class::Manual::Example - Simple CD database example
   4
   5 =head1 DESCRIPTION
   6
   7 This tutorial will guide you through the process of setting up and
   8 testing a very basic CD database using SQLite, with DBIx::Class::Schema
   9 as the database frontend.
  10
  11 The database consists of the following:
  12
  13   table 'artist' with columns:  artistid, name
  14   table 'cd'     with columns:  cdid, artist, title
  15   table 'track'  with columns:  trackid, cd, title
  16
  17
  18 And these rules exists:
  19
  20   one artist can have many cds
  21   one cd belongs to one artist
  22   one cd can have many tracks
  23   one track belongs to one cd
  24
  25
  26 =head2 Installation
  27
  28 Install DBIx::Class via CPAN should be sufficient.
  29
  30 =head3 Create the database/tables.
  31
  32 First make and change the directory:
  33
  34   mkdir app
  35   cd app
  36   mkdir db
  37   cd db
  38
  39 This example uses SQLite which is a dependency of DBIx::Class, so you
  40 shouldn't have to install extra software.
  41
  42 Save the following into a example.sql in the directory db
  43
  44   CREATE TABLE artist (
  45     artistid INTEGER PRIMARY KEY,
  46     name TEXT NOT NULL
  47   );
  48
  49   CREATE TABLE cd (
  50     cdid INTEGER PRIMARY KEY,
  51     artist INTEGER NOT NULL REFERENCES artist(artistid),
  52     title TEXT NOT NULL
  53   );
  54
  55   CREATE TABLE track (
  56     trackid INTEGER PRIMARY KEY,
  57     cd INTEGER NOT NULL REFERENCES cd(cdid),
  58     title TEXT NOT NULL
  59   );
  60
  61 and create the sqlite database file:
  62
  63 sqlite3 example.db < example.sql
  64
  65 =head3 Set up DBIx::Class::Schema
  66
  67 Change directory back from db to the directory app:
  68
  69   cd ../
  70
  71 Now create some more directories:
  72
  73   mkdir MyDatabase
  74   mkdir MyDatabase/Main
  75
  76 Then, create the following DBIx::Class::Schema classes:
  77
  78 MyDatabase/Main.pm:
  79
  80   package MyDatabase::Main;
  81   use base qw/DBIx::Class::Schema/;
  82   __PACKAGE__->load_classes(qw/Artist Cd Track/);
  83
  84   1;
  85
  86
  87 MyDatabase/Main/Artist.pm:
  88
  89   package MyDatabase::Main::Artist;
  90   use base qw/DBIx::Class/;
  91   __PACKAGE__->load_components(qw/PK::Auto Core/);
  92   __PACKAGE__->table('artist');
  93   __PACKAGE__->add_columns(qw/ artistid name /);
  94   __PACKAGE__->set_primary_key('artistid');
  95   __PACKAGE__->has_many('cds' => 'MyDatabase::Main::Cd');
  96
  97   1;
  98
  99
 100 MyDatabase/Main/Cd.pm:
 101
 102   package MyDatabase::Main::Cd;
 103   use base qw/DBIx::Class/;
 104   __PACKAGE__->load_components(qw/PK::Auto Core/);
 105   __PACKAGE__->table('cd');
 106   __PACKAGE__->add_columns(qw/ cdid artist title/);
 107   __PACKAGE__->set_primary_key('cdid');
 108   __PACKAGE__->belongs_to('artist' => 'MyDatabase::Main::Artist');
 109   __PACKAGE__->has_many('tracks' => 'MyDatabase::Main::Track');
 110
 111   1;
 112
 113
 114 MyDatabase/Main/Track.pm:
 115
 116   package MyDatabase::Main::Track;
 117   use base qw/DBIx::Class/;
 118   __PACKAGE__->load_components(qw/PK::Auto Core/);
 119   __PACKAGE__->table('track');
 120   __PACKAGE__->add_columns(qw/ trackid cd title/);
 121   __PACKAGE__->set_primary_key('trackid');
 122   __PACKAGE__->belongs_to('cd' => 'MyDatabase::Main::Cd');
 123
 124   1;
 125
 126
 127 =head3 Write a script to insert some records.
 128
 129 insertdb.pl
 130
 131   #!/usr/bin/perl -w
 132
 133   use MyDatabase::Main;
 134   use strict;
 135
 136   my $schema = MyDatabase::Main->connect('dbi:SQLite:db/example.db');
 137
 138   #  here's some of the sql that is going to be generated by the schema
 139   #  INSERT INTO artist VALUES (NULL,'Michael Jackson');
 140   #  INSERT INTO artist VALUES (NULL,'Eminem');
 141
 142   my @artists = (['Michael Jackson'], ['Eminem']);
 143   $schema->populate('Artist', [
 144      [qw/name/],
 145      @artists,
 146   ]);
 147
 148   my %albums = (
 149     'Thriller' => 'Michael Jackson',
 150     'Bad' => 'Michael Jackson',
 151     'The Marshall Mathers LP' => 'Eminem',
 152   );
 153
 154   my @cds;
 155   foreach my $lp (keys %albums) {
 156     my $artist = $schema->resultset('Artist')->search({
 157       name => $albums{$lp}
 158     });
 159     push @cds, [$lp, $artist->first];
 160   }
 161
 162   $schema->populate('Cd', [
 163     [qw/title artist/],
 164     @cds,
 165   ]);
 166
 167
 168   my %tracks = (
 169     'Beat It'         => 'Thriller',
 170     'Billie Jean'     => 'Thriller',
 171     'Dirty Diana'     => 'Bad',
 172     'Smooth Criminal' => 'Bad',
 173     'Leave Me Alone'  => 'Bad',
 174     'Stan'            => 'The Marshall Mathers LP',
 175     'The Way I Am'    => 'The Marshall Mathers LP',
 176   );
 177
 178   my @tracks;
 179   foreach my $track (keys %tracks) {
 180     my $cdname = $schema->resultset('Cd')->search({
 181       title => $tracks{$track},
 182     });
 183     push @tracks, [$cdname->first, $track];
 184   }
 185
 186   $schema->populate('Track',[
 187     [qw/cd title/],
 188     @tracks,
 189   ]);
 190
 191 =head3 Create and run the test scripts
 192
 193 testdb.pl:
 194
 195   #!/usr/bin/perl -w
 196
 197   use MyDatabase::Main;
 198   use strict;
 199
 200   my $schema = MyDatabase::Main->connect('dbi:SQLite:db/example.db');
 201   # for other DSNs, e.g. MySql, see the perldoc for the relevant dbd
 202   # driver, e.g perldoc L<DBD::mysql>.
 203
 204   get_tracks_by_cd('Bad');
 205   get_tracks_by_artist('Michael Jackson');
 206
 207   get_cd_by_track('Stan');
 208   get_cds_by_artist('Michael Jackson');
 209
 210   get_artist_by_track('Dirty Diana');
 211   get_artist_by_cd('The Marshall Mathers LP');
 212
 213
 214   sub get_tracks_by_cd {
 215     my $cdtitle = shift;
 216     print "get_tracks_by_cd($cdtitle):\n";
 217     my $rs = $schema->resultset('Track')->search(
 218       {
 219         'cd.title' => $cdtitle
 220       },
 221       {
 222         join     => [qw/ cd /],
 223         prefetch => [qw/ cd /]
 224       }
 225     );
 226     while (my $track = $rs->next) {
 227       print $track->title . "\n";
 228     }
 229     print "\n";
 230   }
 231
 232   sub get_tracks_by_artist {
 233     my $artistname = shift;
 234     print "get_tracks_by_artist($artistname):\n";
 235     my $rs = $schema->resultset('Track')->search(
 236       {
 237         'artist.name' => $artistname
 238       },
 239       {
 240         join => {
 241           'cd' => 'artist'
 242         },
 243       }
 244     );
 245     while (my $track = $rs->next) {
 246       print $track->title . "\n";
 247     }
 248     print "\n";
 249   }
 250
 251
 252   sub get_cd_by_track {
 253     my $tracktitle = shift;
 254     print "get_cd_by_track($tracktitle):\n";
 255     my $rs = $schema->resultset('Cd')->search(
 256       {
 257         'tracks.title' => $tracktitle
 258       },
 259       {
 260         join     => [qw/ tracks /],
 261       }
 262     );
 263     my $cd = $rs->first;
 264     print $cd->title . "\n\n";
 265   }
 266
 267   sub get_cds_by_artist {
 268     my $artistname = shift;
 269     print "get_cds_by_artist($artistname):\n";
 270     my $rs = $schema->resultset('Cd')->search(
 271       {
 272         'artist.name' => $artistname
 273       },
 274       {
 275         join     => [qw/ artist /],
 276         prefetch => [qw/ artist /]
 277       }
 278     );
 279     while (my $cd = $rs->next) {
 280       print $cd->title . "\n";
 281     }
 282     print "\n";
 283   }
 284
 285
 286
 287   sub get_artist_by_track {
 288     my $tracktitle = shift;
 289     print "get_artist_by_track($tracktitle):\n";
 290     my $rs = $schema->resultset('Artist')->search(
 291       {
 292         'tracks.title' => $tracktitle
 293       },
 294       {
 295         join => {
 296           'cds' => 'tracks'
 297         }
 298       }
 299     );
 300     my $artist = $rs->first;
 301     print $artist->name . "\n\n";
 302   }
 303
 304   sub get_artist_by_cd {
 305     my $cdtitle = shift;
 306     print "get_artist_by_cd($cdtitle):\n";
 307     my $rs = $schema->resultset('Artist')->search(
 308       {
 309         'cds.title' => $cdtitle
 310       },
 311       {
 312         join     => [qw/ cds /],
 313       }
 314     );
 315     my $artist = $rs->first;
 316     print $artist->name . "\n\n";
 317   }
 318
 319
 320
 321 It should output:
 322
 323   get_tracks_by_cd(Bad):
 324   Dirty Diana
 325   Smooth Criminal
 326   Leave Me Alone
 327
 328   get_tracks_by_artist(Michael Jackson):
 329   Beat it
 330   Billie Jean
 331   Dirty Diana
 332   Smooth Criminal
 333   Leave Me Alone
 334
 335   get_cd_by_track(Stan):
 336   The Marshall Mathers LP
 337
 338   get_cds_by_artist(Michael Jackson):
 339   Thriller
 340   Bad
 341
 342   get_artist_by_track(Dirty Diana):
 343   Michael Jackson
 344
 345   get_artist_by_cd(The Marshall Mathers LP):
 346   Eminem
 347
 348 =head1 Notes
 349
 350 A reference implentation of the database and scripts in this example
 351 are available in the main distribution for DBIx::Class under the
 352 directory t/examples/Schema
 353
 354 With these scripts we're relying on @INC looking in the current
 355 working directory.  You may want to add the MyDatabase namespaces to
 356 @INC in a different way when it comes to deployment.
 357
 358 The testdb.pl script is an excellent start for testing your database
 359 model.
 360
 361 =head1 TODO
 362
 363 =head1 AUTHOR
 364
 365   sc_ from irc.perl.org#dbix-class
 366   Kieren Diment <kd@totaldatasolution.com>
 367
 368 =cut