lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6
   7 =head1 NAME
   8
   9 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  10
  11 =head1 SYNOPSIS
  12
  13 Load this component and then declare one or more
  14 columns to be of the datetime or date datatype.
  15
  16   package Event;
  17   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  18   __PACKAGE__->add_columns(
  19     starts_when => { data_type => 'datetime' }
  20   );
  21
  22 Then you can treat the specified column as a L<DateTime> object.
  23
  24   print "This event starts the month of ".
  25     $event->starts_when->month_name();
  26
  27 =head1 DESCRIPTION
  28
  29 This module figures out the type of DateTime::Format::* class to
  30 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  31 that you are using.  If you switch from one database to a different
  32 one your code should continue to work without modification (though note
  33 that this feature is new as of 0.07, so it may not be perfect yet - bug
  34 reports to the list very much welcome).
  35
  36 =cut
  37
  38 __PACKAGE__->load_components(qw/InflateColumn/);
  39
  40 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  41
  42 =head2 register_column
  43
  44 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  45 up datetime columns appropriately.  This would not normally be
  46 directly called by end users.
  47
  48 =cut
  49
  50 sub register_column {
  51   my ($self, $column, $info, @rest) = @_;
  52   $self->next::method($column, $info, @rest);
  53   return unless defined($info->{data_type});
  54   my $type = lc($info->{data_type});
  55   if ($type eq 'datetime' || $type eq 'date') {
  56     my ($parse, $format) = ("parse_${type}", "format_${type}");
  57     $self->inflate_column(
  58       $column =>
  59         {
  60           inflate => sub {
  61             my ($value, $obj) = @_;
  62             $obj->_datetime_parser->$parse($value);
  63           },
  64           deflate => sub {
  65             my ($value, $obj) = @_;
  66             $obj->_datetime_parser->$format($value);
  67           },
  68         }
  69     );
  70   }
  71 }
  72
  73 sub _datetime_parser {
  74   my $self = shift;
  75   if (my $parser = $self->__datetime_parser) {
  76     return $parser;
  77   }
  78   my $parser = $self->result_source->storage->datetime_parser(@_);
  79   return $self->__datetime_parser($parser);
  80 }
  81
  82 1;
  83 __END__
  84
  85 =head1 SEE ALSO
  86
  87 =over 4
  88
  89 =item More information about the add_columns method, and column metadata,
  90       can be found in the documentation for L<DBIx::Class::ResultSource>.
  91
  92 =back
  93
  94 =head1 AUTHOR
  95
  96 Matt S. Trout <mst@shadowcatsystems.co.uk>
  97
  98 =head1 CONTRIBUTORS
  99
 100 Aran Deltac <bluefeet@cpan.org>
 101
 102 =head1 LICENSE
 103
 104 You may distribute this code under the same terms as Perl itself.
 105