lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  11
  12 =head1 SYNOPSIS
  13
  14 Load this component and then declare one or more
  15 columns to be of the datetime, timestamp or date datatype.
  16
  17   package Event;
  18   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
  19   __PACKAGE__->add_columns(
  20     starts_when => { data_type => 'datetime' }
  21   );
  22
  23 NOTE: You B<must> load C<InflateColumn::DateTime> B<before> C<Core>. See
  24 L<DBIx::Class::Manual::Component> for details.
  25
  26 Then you can treat the specified column as a L<DateTime> object.
  27
  28   print "This event starts the month of ".
  29     $event->starts_when->month_name();
  30
  31 If you want to set a specific timezone and locale for that field, use:
  32
  33   __PACKAGE__->add_columns(
  34     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  35   );
  36
  37 If you want to inflate no matter what data_type your column is,
  38 use inflate_datetime or inflate_date:
  39
  40   __PACKAGE__->add_columns(
  41     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  42   );
  43
  44   __PACKAGE__->add_columns(
  45     starts_when => { data_type => 'varchar', inflate_date => 1 }
  46   );
  47
  48 It's also possible to explicitly skip inflation:
  49
  50   __PACKAGE__->add_columns(
  51     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  52   );
  53
  54 =head1 DESCRIPTION
  55
  56 This module figures out the type of DateTime::Format::* class to
  57 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  58 that you are using.  If you switch from one database to a different
  59 one your code should continue to work without modification (though note
  60 that this feature is new as of 0.07, so it may not be perfect yet - bug
  61 reports to the list very much welcome).
  62
  63 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  64
  65 =cut
  66
  67 __PACKAGE__->load_components(qw/InflateColumn/);
  68
  69 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  70
  71 =head2 register_column
  72
  73 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  74 up datetime columns appropriately.  This would not normally be
  75 directly called by end users.
  76
  77 In the case of an invalid date, L<DateTime> will throw an exception.  To
  78 bypass these exceptions and just have the inflation return undef, use
  79 the C<datetime_undef_if_invalid> option in the column info:
  80
  81     "broken_date",
  82     {
  83         data_type => "datetime",
  84         default_value => '0000-00-00',
  85         is_nullable => 1,
  86         datetime_undef_if_invalid => 1
  87     }
  88
  89 =cut
  90
  91 sub register_column {
  92   my ($self, $column, $info, @rest) = @_;
  93   $self->next::method($column, $info, @rest);
  94   return unless defined($info->{data_type});
  95
  96   my $type;
  97
  98   for (qw/date datetime timestamp/) {
  99     my $key = "inflate_${_}";
 100
 101     next unless exists $info->{$key};
 102     return unless $info->{$key};
 103
 104     $type = $_;
 105     last;
 106   }
 107
 108   unless ($type) {
 109     $type = lc($info->{data_type});
 110   }
 111
 112   my $timezone;
 113   if ( defined $info->{extra}{timezone} ) {
 114     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 115          "please put it directly into the columns definition.";
 116     $timezone = $info->{extra}{timezone};
 117   }
 118
 119   my $locale;
 120   if ( defined $info->{extra}{locale} ) {
 121     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 122          "please put it directly into the columns definition.";
 123     $locale = $info->{extra}{locale};
 124   }
 125
 126   $locale   = $info->{locale}   if defined $info->{locale};
 127   $timezone = $info->{timezone} if defined $info->{timezone};
 128
 129   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 130
 131   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 132     # This shallow copy of %info avoids t/52_cycle.t treating
 133     # the resulting deflator as a circular reference.
 134     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 135
 136     if (defined $info->{extra}{floating_tz_ok}) {
 137       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 138            "please put it directly into the columns definition.";
 139       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 140     }
 141
 142     $self->inflate_column(
 143       $column =>
 144         {
 145           inflate => sub {
 146             my ($value, $obj) = @_;
 147             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 148             $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $@")
 149               if $@ and not $undef_if_invalid;
 150             $dt->set_time_zone($timezone) if $timezone;
 151             $dt->set_locale($locale) if $locale;
 152             return $dt;
 153           },
 154           deflate => sub {
 155             my ($value, $obj) = @_;
 156             if ($timezone) {
 157                 carp "You're using a floating timezone, please see the documentation of"
 158                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
 159                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
 160                       and not $info{floating_tz_ok}
 161                       and not $ENV{DBIC_FLOATING_TZ_OK};
 162                 $value->set_time_zone($timezone);
 163                 $value->set_locale($locale) if $locale;
 164             }
 165             $obj->_deflate_from_datetime( $value, \%info );
 166           },
 167         }
 168     );
 169   }
 170 }
 171
 172 sub _flate_or_fallback
 173 {
 174   my( $self, $value, $info, $method_fmt ) = @_;
 175
 176   my $parser = $self->_datetime_parser;
 177   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 178   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 179   return $parser->$method($value);
 180 }
 181
 182 sub _inflate_to_datetime {
 183   my( $self, $value, $info ) = @_;
 184   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 185 }
 186
 187 sub _deflate_from_datetime {
 188   my( $self, $value, $info ) = @_;
 189   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 190 }
 191
 192 sub _datetime_parser {
 193   my $self = shift;
 194   if (my $parser = $self->__datetime_parser) {
 195     return $parser;
 196   }
 197   my $parser = $self->result_source->storage->datetime_parser(@_);
 198   return $self->__datetime_parser($parser);
 199 }
 200
 201 1;
 202 __END__
 203
 204 =head1 USAGE NOTES
 205
 206 If you have a datetime column with the C<timezone> extra setting, and subsenquently
 207 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 208 timezone, you will get a warning (as there is a very good chance this will not have the
 209 result you expect). For example:
 210
 211   __PACKAGE__->add_columns(
 212     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 213   );
 214
 215   my $event = $schema->resultset('EventTZ')->create({
 216     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 217   });
 218
 219 The warning can be avoided in several ways:
 220
 221 =over
 222
 223 =item Fix your broken code
 224
 225 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 226 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 227 to be supply explicit times to the database:
 228
 229   my $event = $schema->resultset('EventTZ')->create({
 230     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 231   });
 232
 233 =item Suppress the check on per-column basis
 234
 235   __PACKAGE__->add_columns(
 236     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 237   );
 238
 239 =item Suppress the check globally
 240
 241 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 242
 243 =back
 244
 245 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 246 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 247 Instead put it directly into the columns definition like in the examples above. If you still
 248 use the old way you'll see a warning - please fix your code then!
 249
 250 =head1 SEE ALSO
 251
 252 =over 4
 253
 254 =item More information about the add_columns method, and column metadata,
 255       can be found in the documentation for L<DBIx::Class::ResultSource>.
 256
 257 =item Further discussion of problems inherent to the Floating timezone:
 258       L<Floating DateTimes|DateTime/Floating_DateTimes>
 259       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 260
 261 =back
 262
 263 =head1 AUTHOR
 264
 265 Matt S. Trout <mst@shadowcatsystems.co.uk>
 266
 267 =head1 CONTRIBUTORS
 268
 269 Aran Deltac <bluefeet@cpan.org>
 270
 271 =head1 LICENSE
 272
 273 You may distribute this code under the same terms as Perl itself.
 274