lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use Try::Tiny;
   8
   9 =head1 NAME
  10
  11 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  12
  13 =head1 SYNOPSIS
  14
  15 Load this component and then declare one or more
  16 columns to be of the datetime, timestamp or date datatype.
  17
  18   package Event;
  19   use base 'DBIx::Class::Core';
  20
  21   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  22   __PACKAGE__->add_columns(
  23     starts_when => { data_type => 'datetime' }
  24     create_date => { data_type => 'date' }
  25   );
  26
  27 Then you can treat the specified column as a L<DateTime> object.
  28
  29   print "This event starts the month of ".
  30     $event->starts_when->month_name();
  31
  32 If you want to set a specific timezone and locale for that field, use:
  33
  34   __PACKAGE__->add_columns(
  35     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  36   );
  37
  38 If you want to inflate no matter what data_type your column is,
  39 use inflate_datetime or inflate_date:
  40
  41   __PACKAGE__->add_columns(
  42     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  43   );
  44
  45   __PACKAGE__->add_columns(
  46     starts_when => { data_type => 'varchar', inflate_date => 1 }
  47   );
  48
  49 It's also possible to explicitly skip inflation:
  50
  51   __PACKAGE__->add_columns(
  52     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  53   );
  54
  55 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
  56 The column is set directly for any non-references and C<InflateColumn::DateTime>
  57 is completely bypassed.  Instead, use an input parser to create a DateTime
  58 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
  59 use C<DateTime::Format::ISO8601> thusly:
  60
  61   use DateTime::Format::ISO8601;
  62   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  63
  64 =head1 DESCRIPTION
  65
  66 This module figures out the type of DateTime::Format::* class to
  67 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  68 that you are using.  If you switch from one database to a different
  69 one your code should continue to work without modification (though note
  70 that this feature is new as of 0.07, so it may not be perfect yet - bug
  71 reports to the list very much welcome).
  72
  73 If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
  74 a derivative of these datatypes, e.g. C<timestamp with timezone>), this
  75 module will automatically call the appropriate parse/format method for
  76 deflation/inflation as defined in the storage class. For instance, for
  77 a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
  78 would be called on deflation/inflation. If the storage class does not
  79 provide a specialized inflator/deflator, C<[parse|format]_datetime> will
  80 be used as a fallback. See L<DateTime::Format> for more information on
  81 date formatting.
  82
  83 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  84
  85 =cut
  86
  87 __PACKAGE__->load_components(qw/InflateColumn/);
  88
  89 =head2 register_column
  90
  91 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  92 up datetime columns appropriately.  This would not normally be
  93 directly called by end users.
  94
  95 In the case of an invalid date, L<DateTime> will throw an exception.  To
  96 bypass these exceptions and just have the inflation return undef, use
  97 the C<datetime_undef_if_invalid> option in the column info:
  98
  99     "broken_date",
 100     {
 101         data_type => "datetime",
 102         default_value => '0000-00-00',
 103         is_nullable => 1,
 104         datetime_undef_if_invalid => 1
 105     }
 106
 107 =cut
 108
 109 sub register_column {
 110   my ($self, $column, $info, @rest) = @_;
 111   $self->next::method($column, $info, @rest);
 112   return unless defined($info->{data_type});
 113
 114   my $type;
 115
 116   for (qw/date datetime timestamp/) {
 117     my $key = "inflate_${_}";
 118
 119     next unless exists $info->{$key};
 120     return unless $info->{$key};
 121
 122     $type = $_;
 123     last;
 124   }
 125
 126   unless ($type) {
 127     $type = lc($info->{data_type});
 128     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 129       $type = "timestamp";
 130       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 131     } elsif ($type eq "timestamp without time zone") {
 132       $type = "timestamp";
 133       $info->{_ic_dt_method} ||= "timestamp_without_timezone";
 134     } elsif ($type eq "smalldatetime") {
 135       $type = "datetime";
 136       $info->{_ic_dt_method} ||= "smalldatetime";
 137     }
 138   }
 139
 140   if ( defined $info->{extra}{timezone} ) {
 141     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 142          "please put it directly into the '$column' column definition.";
 143     $info->{timezone} = $info->{extra}{timezone} unless defined $info->{timezone};
 144   }
 145
 146   if ( defined $info->{extra}{locale} ) {
 147     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 148          "please put it directly into the '$column' column definition.";
 149     $info->{locale} = $info->{extra}{locale} unless defined $info->{locale};
 150   }
 151
 152   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 153
 154   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 155     # This shallow copy of %info avoids t/52_cycle.t treating
 156     # the resulting deflator as a circular reference.
 157     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 158
 159     if (defined $info->{extra}{floating_tz_ok}) {
 160       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 161            "please put it directly into the '$column' column definition.";
 162       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 163     }
 164
 165     $self->inflate_column(
 166       $column =>
 167         {
 168           inflate => sub {
 169             my ($value, $obj) = @_;
 170
 171             my ($dt, $err);
 172             try { $dt = $obj->_inflate_to_datetime( $value, \%info ) }
 173             catch {
 174               $err = 1;
 175               if (! $undef_if_invalid) {
 176                 $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $_");
 177               }
 178             };
 179             return undef if $err;
 180
 181             return $obj->_post_inflate_datetime( $dt, \%info );
 182           },
 183           deflate => sub {
 184             my ($value, $obj) = @_;
 185
 186             $value = $obj->_pre_deflate_datetime( $value, \%info );
 187             $obj->_deflate_from_datetime( $value, \%info );
 188           },
 189         }
 190     );
 191   }
 192 }
 193
 194 sub _flate_or_fallback
 195 {
 196   my( $self, $value, $info, $method_fmt ) = @_;
 197
 198   my $parser = $self->_datetime_parser;
 199   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 200   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 201   return $parser->$method($value);
 202 }
 203
 204 sub _inflate_to_datetime {
 205   my( $self, $value, $info ) = @_;
 206   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 207 }
 208
 209 sub _deflate_from_datetime {
 210   my( $self, $value, $info ) = @_;
 211   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 212 }
 213
 214 sub _datetime_parser {
 215   shift->result_source->storage->datetime_parser (@_);
 216 }
 217
 218 sub _post_inflate_datetime {
 219   my( $self, $dt, $info ) = @_;
 220
 221   $dt->set_time_zone($info->{timezone}) if defined $info->{timezone};
 222   $dt->set_locale($info->{locale}) if defined $info->{locale};
 223
 224   return $dt;
 225 }
 226
 227 sub _pre_deflate_datetime {
 228   my( $self, $dt, $info ) = @_;
 229
 230   if (defined $info->{timezone}) {
 231     carp "You're using a floating timezone, please see the documentation of"
 232       . " DBIx::Class::InflateColumn::DateTime for an explanation"
 233       if ref( $dt->time_zone ) eq 'DateTime::TimeZone::Floating'
 234           and not $info->{floating_tz_ok}
 235           and not $ENV{DBIC_FLOATING_TZ_OK};
 236
 237     $dt->set_time_zone($info->{timezone});
 238   }
 239
 240   $dt->set_locale($info->{locale}) if defined $info->{locale};
 241
 242   return $dt;
 243 }
 244
 245 1;
 246 __END__
 247
 248 =head1 USAGE NOTES
 249
 250 If you have a datetime column with an associated C<timezone>, and subsequently
 251 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 252 timezone, you will get a warning (as there is a very good chance this will not have the
 253 result you expect). For example:
 254
 255   __PACKAGE__->add_columns(
 256     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 257   );
 258
 259   my $event = $schema->resultset('EventTZ')->create({
 260     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 261   });
 262
 263 The warning can be avoided in several ways:
 264
 265 =over
 266
 267 =item Fix your broken code
 268
 269 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 270 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 271 to be supply explicit times to the database:
 272
 273   my $event = $schema->resultset('EventTZ')->create({
 274     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 275   });
 276
 277 =item Suppress the check on per-column basis
 278
 279   __PACKAGE__->add_columns(
 280     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 281   );
 282
 283 =item Suppress the check globally
 284
 285 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 286
 287 =back
 288
 289 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 290 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 291 Instead put it directly into the columns definition like in the examples above. If you still
 292 use the old way you'll see a warning - please fix your code then!
 293
 294 =head1 SEE ALSO
 295
 296 =over 4
 297
 298 =item More information about the add_columns method, and column metadata,
 299       can be found in the documentation for L<DBIx::Class::ResultSource>.
 300
 301 =item Further discussion of problems inherent to the Floating timezone:
 302       L<Floating DateTimes|DateTime/Floating_DateTimes>
 303       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 304
 305 =back
 306
 307 =head1 AUTHOR
 308
 309 Matt S. Trout <mst@shadowcatsystems.co.uk>
 310
 311 =head1 CONTRIBUTORS
 312
 313 Aran Deltac <bluefeet@cpan.org>
 314
 315 =head1 LICENSE
 316
 317 You may distribute this code under the same terms as Perl itself.
 318