lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  11
  12 =head1 SYNOPSIS
  13
  14 Load this component and then declare one or more
  15 columns to be of the datetime, timestamp or date datatype.
  16
  17   package Event;
  18   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
  19   __PACKAGE__->add_columns(
  20     starts_when => { data_type => 'datetime' }
  21   );
  22
  23 NOTE: You B<must> load C<InflateColumn::DateTime> B<before> C<Core>. See
  24 L<DBIx::Class::Manual::Component> for details.
  25
  26 Then you can treat the specified column as a L<DateTime> object.
  27
  28   print "This event starts the month of ".
  29     $event->starts_when->month_name();
  30
  31 If you want to set a specific timezone and locale for that field, use:
  32
  33   __PACKAGE__->add_columns(
  34     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  35   );
  36
  37 If you want to inflate no matter what data_type your column is,
  38 use inflate_datetime or inflate_date:
  39
  40   __PACKAGE__->add_columns(
  41     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  42   );
  43
  44   __PACKAGE__->add_columns(
  45     starts_when => { data_type => 'varchar', inflate_date => 1 }
  46   );
  47
  48 It's also possible to explicitly skip inflation:
  49
  50   __PACKAGE__->add_columns(
  51     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  52   );
  53
  54 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
  55 The column is set directly for any non-references and C<InflateColumn::DateTime>
  56 is completely bypassed.  Instead, use an input parser to create a DateTime
  57 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
  58 use C<DateTime::Format::ISO8601> thusly:
  59
  60   use DateTime::Format::ISO8601;
  61   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  62
  63 =head1 DESCRIPTION
  64
  65 This module figures out the type of DateTime::Format::* class to
  66 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  67 that you are using.  If you switch from one database to a different
  68 one your code should continue to work without modification (though note
  69 that this feature is new as of 0.07, so it may not be perfect yet - bug
  70 reports to the list very much welcome).
  71
  72 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  73
  74 =cut
  75
  76 __PACKAGE__->load_components(qw/InflateColumn/);
  77
  78 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  79
  80 =head2 register_column
  81
  82 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  83 up datetime columns appropriately.  This would not normally be
  84 directly called by end users.
  85
  86 In the case of an invalid date, L<DateTime> will throw an exception.  To
  87 bypass these exceptions and just have the inflation return undef, use
  88 the C<datetime_undef_if_invalid> option in the column info:
  89
  90     "broken_date",
  91     {
  92         data_type => "datetime",
  93         default_value => '0000-00-00',
  94         is_nullable => 1,
  95         datetime_undef_if_invalid => 1
  96     }
  97
  98 =cut
  99
 100 sub register_column {
 101   my ($self, $column, $info, @rest) = @_;
 102   $self->next::method($column, $info, @rest);
 103   return unless defined($info->{data_type});
 104
 105   my $type;
 106
 107   for (qw/date datetime timestamp/) {
 108     my $key = "inflate_${_}";
 109
 110     next unless exists $info->{$key};
 111     return unless $info->{$key};
 112
 113     $type = $_;
 114     last;
 115   }
 116
 117   unless ($type) {
 118     $type = lc($info->{data_type});
 119     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 120       $type = "timestamp";
 121       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 122     }
 123   }
 124
 125   my $timezone;
 126   if ( defined $info->{extra}{timezone} ) {
 127     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 128          "please put it directly into the '$column' column definition.";
 129     $timezone = $info->{extra}{timezone};
 130   }
 131
 132   my $locale;
 133   if ( defined $info->{extra}{locale} ) {
 134     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 135          "please put it directly into the '$column' column definition.";
 136     $locale = $info->{extra}{locale};
 137   }
 138
 139   $locale   = $info->{locale}   if defined $info->{locale};
 140   $timezone = $info->{timezone} if defined $info->{timezone};
 141
 142   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 143
 144   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 145     # This shallow copy of %info avoids t/52_cycle.t treating
 146     # the resulting deflator as a circular reference.
 147     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 148
 149     if (defined $info->{extra}{floating_tz_ok}) {
 150       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 151            "please put it directly into the '$column' column definition.";
 152       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 153     }
 154
 155     $self->inflate_column(
 156       $column =>
 157         {
 158           inflate => sub {
 159             my ($value, $obj) = @_;
 160
 161             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 162             if (my $err = $@ ) {
 163               return undef if ($undef_if_invalid);
 164               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $err");
 165             }
 166
 167             $dt->set_time_zone($timezone) if $timezone;
 168             $dt->set_locale($locale) if $locale;
 169             return $dt;
 170           },
 171           deflate => sub {
 172             my ($value, $obj) = @_;
 173             if ($timezone) {
 174                 carp "You're using a floating timezone, please see the documentation of"
 175                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
 176                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
 177                       and not $info{floating_tz_ok}
 178                       and not $ENV{DBIC_FLOATING_TZ_OK};
 179                 $value->set_time_zone($timezone);
 180                 $value->set_locale($locale) if $locale;
 181             }
 182             $obj->_deflate_from_datetime( $value, \%info );
 183           },
 184         }
 185     );
 186   }
 187 }
 188
 189 sub _flate_or_fallback
 190 {
 191   my( $self, $value, $info, $method_fmt ) = @_;
 192
 193   my $parser = $self->_datetime_parser;
 194   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 195   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 196   return $parser->$method($value);
 197 }
 198
 199 sub _inflate_to_datetime {
 200   my( $self, $value, $info ) = @_;
 201   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 202 }
 203
 204 sub _deflate_from_datetime {
 205   my( $self, $value, $info ) = @_;
 206   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 207 }
 208
 209 sub _datetime_parser {
 210   my $self = shift;
 211   if (my $parser = $self->__datetime_parser) {
 212     return $parser;
 213   }
 214   my $parser = $self->result_source->storage->datetime_parser(@_);
 215   return $self->__datetime_parser($parser);
 216 }
 217
 218 1;
 219 __END__
 220
 221 =head1 USAGE NOTES
 222
 223 If you have a datetime column with an associated C<timezone>, and subsequently
 224 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 225 timezone, you will get a warning (as there is a very good chance this will not have the
 226 result you expect). For example:
 227
 228   __PACKAGE__->add_columns(
 229     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 230   );
 231
 232   my $event = $schema->resultset('EventTZ')->create({
 233     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 234   });
 235
 236 The warning can be avoided in several ways:
 237
 238 =over
 239
 240 =item Fix your broken code
 241
 242 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 243 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 244 to be supply explicit times to the database:
 245
 246   my $event = $schema->resultset('EventTZ')->create({
 247     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 248   });
 249
 250 =item Suppress the check on per-column basis
 251
 252   __PACKAGE__->add_columns(
 253     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 254   );
 255
 256 =item Suppress the check globally
 257
 258 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 259
 260 =back
 261
 262 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 263 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 264 Instead put it directly into the columns definition like in the examples above. If you still
 265 use the old way you'll see a warning - please fix your code then!
 266
 267 =head1 SEE ALSO
 268
 269 =over 4
 270
 271 =item More information about the add_columns method, and column metadata,
 272       can be found in the documentation for L<DBIx::Class::ResultSource>.
 273
 274 =item Further discussion of problems inherent to the Floating timezone:
 275       L<Floating DateTimes|DateTime/Floating_DateTimes>
 276       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 277
 278 =back
 279
 280 =head1 AUTHOR
 281
 282 Matt S. Trout <mst@shadowcatsystems.co.uk>
 283
 284 =head1 CONTRIBUTORS
 285
 286 Aran Deltac <bluefeet@cpan.org>
 287
 288 =head1 LICENSE
 289
 290 You may distribute this code under the same terms as Perl itself.
 291