lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6
   7 =head1 NAME
   8
   9 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  10
  11 =head1 SYNOPSIS
  12
  13 Load this component and then declare one or more
  14 columns to be of the datetime, timestamp or date datatype.
  15
  16   package Event;
  17   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  18   __PACKAGE__->add_columns(
  19     starts_when => { data_type => 'datetime' }
  20   );
  21
  22 Then you can treat the specified column as a L<DateTime> object.
  23
  24   print "This event starts the month of ".
  25     $event->starts_when->month_name();
  26
  27 =head1 DESCRIPTION
  28
  29 This module figures out the type of DateTime::Format::* class to
  30 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  31 that you are using.  If you switch from one database to a different
  32 one your code should continue to work without modification (though note
  33 that this feature is new as of 0.07, so it may not be perfect yet - bug
  34 reports to the list very much welcome).
  35
  36 =cut
  37
  38 __PACKAGE__->load_components(qw/InflateColumn/);
  39
  40 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  41
  42 =head2 register_column
  43
  44 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  45 up datetime columns appropriately.  This would not normally be
  46 directly called by end users.
  47
  48 =cut
  49
  50 sub register_column {
  51   my ($self, $column, $info, @rest) = @_;
  52   $self->next::method($column, $info, @rest);
  53   return unless defined($info->{data_type});
  54   my $type = lc($info->{data_type});
  55   $type = 'datetime' if ($type eq 'timestamp');
  56   if ($type eq 'datetime' || $type eq 'date') {
  57     my ($parse, $format) = ("parse_${type}", "format_${type}");
  58     $self->inflate_column(
  59       $column =>
  60         {
  61           inflate => sub {
  62             my ($value, $obj) = @_;
  63             $obj->_datetime_parser->$parse($value);
  64           },
  65           deflate => sub {
  66             my ($value, $obj) = @_;
  67             $obj->_datetime_parser->$format($value);
  68           },
  69         }
  70     );
  71   }
  72 }
  73
  74 sub _datetime_parser {
  75   my $self = shift;
  76   if (my $parser = $self->__datetime_parser) {
  77     return $parser;
  78   }
  79   my $parser = $self->result_source->storage->datetime_parser(@_);
  80   return $self->__datetime_parser($parser);
  81 }
  82
  83 1;
  84 __END__
  85
  86 =head1 SEE ALSO
  87
  88 =over 4
  89
  90 =item More information about the add_columns method, and column metadata,
  91       can be found in the documentation for L<DBIx::Class::ResultSource>.
  92
  93 =back
  94
  95 =head1 AUTHOR
  96
  97 Matt S. Trout <mst@shadowcatsystems.co.uk>
  98
  99 =head1 CONTRIBUTORS
 100
 101 Aran Deltac <bluefeet@cpan.org>
 102
 103 =head1 LICENSE
 104
 105 You may distribute this code under the same terms as Perl itself.
 106