lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  11
  12 =head1 SYNOPSIS
  13
  14 Load this component and then declare one or more
  15 columns to be of the datetime, timestamp or date datatype.
  16
  17   package Event;
  18   use base 'DBIx::Class::Core';
  19
  20   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  21   __PACKAGE__->add_columns(
  22     starts_when => { data_type => 'datetime' }
  23     create_date => { data_type => 'date' }
  24   );
  25
  26 Then you can treat the specified column as a L<DateTime> object.
  27
  28   print "This event starts the month of ".
  29     $event->starts_when->month_name();
  30
  31 If you want to set a specific timezone and locale for that field, use:
  32
  33   __PACKAGE__->add_columns(
  34     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  35   );
  36
  37 If you want to inflate no matter what data_type your column is,
  38 use inflate_datetime or inflate_date:
  39
  40   __PACKAGE__->add_columns(
  41     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  42   );
  43
  44   __PACKAGE__->add_columns(
  45     starts_when => { data_type => 'varchar', inflate_date => 1 }
  46   );
  47
  48 It's also possible to explicitly skip inflation:
  49
  50   __PACKAGE__->add_columns(
  51     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  52   );
  53
  54 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
  55 The column is set directly for any non-references and C<InflateColumn::DateTime>
  56 is completely bypassed.  Instead, use an input parser to create a DateTime
  57 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
  58 use C<DateTime::Format::ISO8601> thusly:
  59
  60   use DateTime::Format::ISO8601;
  61   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  62
  63 =head1 DESCRIPTION
  64
  65 This module figures out the type of DateTime::Format::* class to
  66 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  67 that you are using.  If you switch from one database to a different
  68 one your code should continue to work without modification (though note
  69 that this feature is new as of 0.07, so it may not be perfect yet - bug
  70 reports to the list very much welcome).
  71
  72 If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
  73 a derivative of these datatypes, e.g. C<timestamp with timezone>), this
  74 module will automatically call the appropriate parse/format method for
  75 deflation/inflation as defined in the storage class. For instance, for
  76 a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
  77 would be called on deflation/inflation. If the storage class does not
  78 provide a specialized inflator/deflator, C<[parse|format]_datetime> will
  79 be used as a fallback. See L<DateTime::Format> for more information on
  80 date formatting.
  81
  82 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  83
  84 =cut
  85
  86 __PACKAGE__->load_components(qw/InflateColumn/);
  87
  88 =head2 register_column
  89
  90 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  91 up datetime columns appropriately.  This would not normally be
  92 directly called by end users.
  93
  94 In the case of an invalid date, L<DateTime> will throw an exception.  To
  95 bypass these exceptions and just have the inflation return undef, use
  96 the C<datetime_undef_if_invalid> option in the column info:
  97
  98     "broken_date",
  99     {
 100         data_type => "datetime",
 101         default_value => '0000-00-00',
 102         is_nullable => 1,
 103         datetime_undef_if_invalid => 1
 104     }
 105
 106 =cut
 107
 108 sub register_column {
 109   my ($self, $column, $info, @rest) = @_;
 110   $self->next::method($column, $info, @rest);
 111   return unless defined($info->{data_type});
 112
 113   my $type;
 114
 115   for (qw/date datetime timestamp/) {
 116     my $key = "inflate_${_}";
 117
 118     next unless exists $info->{$key};
 119     return unless $info->{$key};
 120
 121     $type = $_;
 122     last;
 123   }
 124
 125   unless ($type) {
 126     $type = lc($info->{data_type});
 127     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 128       $type = "timestamp";
 129       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 130     } elsif ($type eq "timestamp without time zone") {
 131       $type = "timestamp";
 132       $info->{_ic_dt_method} ||= "timestamp_without_timezone";
 133     } elsif ($type eq "smalldatetime") {
 134       $type = "datetime";
 135       $info->{_ic_dt_method} ||= "smalldatetime";
 136     }
 137   }
 138
 139   if ( defined $info->{extra}{timezone} ) {
 140     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 141          "please put it directly into the '$column' column definition.";
 142     $info->{timezone} = $info->{extra}{timezone} unless defined $info->{timezone};
 143   }
 144
 145   if ( defined $info->{extra}{locale} ) {
 146     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 147          "please put it directly into the '$column' column definition.";
 148     $info->{locale} = $info->{extra}{locale} unless defined $info->{locale};
 149   }
 150
 151   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 152
 153   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 154     # This shallow copy of %info avoids t/52_cycle.t treating
 155     # the resulting deflator as a circular reference.
 156     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 157
 158     if (defined $info->{extra}{floating_tz_ok}) {
 159       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 160            "please put it directly into the '$column' column definition.";
 161       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 162     }
 163
 164     $self->inflate_column(
 165       $column =>
 166         {
 167           inflate => sub {
 168             my ($value, $obj) = @_;
 169
 170             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 171             if (my $err = $@ ) {
 172               return undef if ($undef_if_invalid);
 173               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $err");
 174             }
 175
 176             return $obj->_post_inflate_datetime( $dt, \%info );
 177           },
 178           deflate => sub {
 179             my ($value, $obj) = @_;
 180
 181             $value = $obj->_pre_deflate_datetime( $value, \%info );
 182             $obj->_deflate_from_datetime( $value, \%info );
 183           },
 184         }
 185     );
 186   }
 187 }
 188
 189 sub _flate_or_fallback
 190 {
 191   my( $self, $value, $info, $method_fmt ) = @_;
 192
 193   my $parser = $self->_datetime_parser;
 194   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 195   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 196   return $parser->$method($value);
 197 }
 198
 199 sub _inflate_to_datetime {
 200   my( $self, $value, $info ) = @_;
 201   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 202 }
 203
 204 sub _deflate_from_datetime {
 205   my( $self, $value, $info ) = @_;
 206   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 207 }
 208
 209 sub _datetime_parser {
 210   shift->result_source->storage->datetime_parser (@_);
 211 }
 212
 213 sub _post_inflate_datetime {
 214   my( $self, $dt, $info ) = @_;
 215
 216   $dt->set_time_zone($info->{timezone}) if defined $info->{timezone};
 217   $dt->set_locale($info->{locale}) if defined $info->{locale};
 218
 219   return $dt;
 220 }
 221
 222 sub _pre_deflate_datetime {
 223   my( $self, $dt, $info ) = @_;
 224
 225   if (defined $info->{timezone}) {
 226     carp "You're using a floating timezone, please see the documentation of"
 227       . " DBIx::Class::InflateColumn::DateTime for an explanation"
 228       if ref( $dt->time_zone ) eq 'DateTime::TimeZone::Floating'
 229           and not $info->{floating_tz_ok}
 230           and not $ENV{DBIC_FLOATING_TZ_OK};
 231
 232     $dt->set_time_zone($info->{timezone});
 233   }
 234
 235   $dt->set_locale($info->{locale}) if defined $info->{locale};
 236
 237   return $dt;
 238 }
 239
 240 1;
 241 __END__
 242
 243 =head1 USAGE NOTES
 244
 245 If you have a datetime column with an associated C<timezone>, and subsequently
 246 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 247 timezone, you will get a warning (as there is a very good chance this will not have the
 248 result you expect). For example:
 249
 250   __PACKAGE__->add_columns(
 251     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 252   );
 253
 254   my $event = $schema->resultset('EventTZ')->create({
 255     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 256   });
 257
 258 The warning can be avoided in several ways:
 259
 260 =over
 261
 262 =item Fix your broken code
 263
 264 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 265 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 266 to be supply explicit times to the database:
 267
 268   my $event = $schema->resultset('EventTZ')->create({
 269     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 270   });
 271
 272 =item Suppress the check on per-column basis
 273
 274   __PACKAGE__->add_columns(
 275     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 276   );
 277
 278 =item Suppress the check globally
 279
 280 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 281
 282 =back
 283
 284 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 285 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 286 Instead put it directly into the columns definition like in the examples above. If you still
 287 use the old way you'll see a warning - please fix your code then!
 288
 289 =head1 SEE ALSO
 290
 291 =over 4
 292
 293 =item More information about the add_columns method, and column metadata,
 294       can be found in the documentation for L<DBIx::Class::ResultSource>.
 295
 296 =item Further discussion of problems inherent to the Floating timezone:
 297       L<Floating DateTimes|DateTime/Floating_DateTimes>
 298       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 299
 300 =back
 301
 302 =head1 AUTHOR
 303
 304 Matt S. Trout <mst@shadowcatsystems.co.uk>
 305
 306 =head1 CONTRIBUTORS
 307
 308 Aran Deltac <bluefeet@cpan.org>
 309
 310 =head1 LICENSE
 311
 312 You may distribute this code under the same terms as Perl itself.
 313