lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use Try::Tiny;
   8 use namespace::clean;
   9
  10 =head1 NAME
  11
  12 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  13
  14 =head1 SYNOPSIS
  15
  16 Load this component and then declare one or more
  17 columns to be of the datetime, timestamp or date datatype.
  18
  19   package Event;
  20   use base 'DBIx::Class::Core';
  21
  22   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  23   __PACKAGE__->add_columns(
  24     starts_when => { data_type => 'datetime' }
  25     create_date => { data_type => 'date' }
  26   );
  27
  28 Then you can treat the specified column as a L<DateTime> object.
  29
  30   print "This event starts the month of ".
  31     $event->starts_when->month_name();
  32
  33 If you want to set a specific timezone and locale for that field, use:
  34
  35   __PACKAGE__->add_columns(
  36     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  37   );
  38
  39 If you want to inflate no matter what data_type your column is,
  40 use inflate_datetime or inflate_date:
  41
  42   __PACKAGE__->add_columns(
  43     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  44   );
  45
  46   __PACKAGE__->add_columns(
  47     starts_when => { data_type => 'varchar', inflate_date => 1 }
  48   );
  49
  50 It's also possible to explicitly skip inflation:
  51
  52   __PACKAGE__->add_columns(
  53     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  54   );
  55
  56 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
  57 The column is set directly for any non-references and C<InflateColumn::DateTime>
  58 is completely bypassed.  Instead, use an input parser to create a DateTime
  59 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
  60 use C<DateTime::Format::ISO8601> thusly:
  61
  62   use DateTime::Format::ISO8601;
  63   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  64
  65 =head1 DESCRIPTION
  66
  67 This module figures out the type of DateTime::Format::* class to
  68 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  69 that you are using.  If you switch from one database to a different
  70 one your code should continue to work without modification (though note
  71 that this feature is new as of 0.07, so it may not be perfect yet - bug
  72 reports to the list very much welcome).
  73
  74 If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
  75 a derivative of these datatypes, e.g. C<timestamp with timezone>), this
  76 module will automatically call the appropriate parse/format method for
  77 deflation/inflation as defined in the storage class. For instance, for
  78 a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
  79 would be called on deflation/inflation. If the storage class does not
  80 provide a specialized inflator/deflator, C<[parse|format]_datetime> will
  81 be used as a fallback. See L<DateTime::Format> for more information on
  82 date formatting.
  83
  84 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  85
  86 =cut
  87
  88 __PACKAGE__->load_components(qw/InflateColumn/);
  89
  90 =head2 register_column
  91
  92 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  93 up datetime columns appropriately.  This would not normally be
  94 directly called by end users.
  95
  96 In the case of an invalid date, L<DateTime> will throw an exception.  To
  97 bypass these exceptions and just have the inflation return undef, use
  98 the C<datetime_undef_if_invalid> option in the column info:
  99
 100     "broken_date",
 101     {
 102         data_type => "datetime",
 103         default_value => '0000-00-00',
 104         is_nullable => 1,
 105         datetime_undef_if_invalid => 1
 106     }
 107
 108 =cut
 109
 110 sub register_column {
 111   my ($self, $column, $info, @rest) = @_;
 112
 113   $self->next::method($column, $info, @rest);
 114
 115   return unless defined($info->{data_type});
 116
 117   my $requested_type;
 118   for (qw/date datetime timestamp/) {
 119     my $key = "inflate_${_}";
 120
 121     next unless exists $info->{$key};
 122
 123     return if ! $info->{$key};
 124
 125     $requested_type = $_;
 126     last;
 127   }
 128
 129   my $data_type = lc($info->{data_type} || '');
 130
 131   # _ic_dt_method will follow whatever the registration requests
 132   # thus = instead of ||=
 133   if ($data_type eq 'timestamp with time zone' || $data_type eq 'timestamptz') {
 134     $info->{_ic_dt_method} = 'timestamp_with_timezone';
 135   }
 136   elsif ($data_type eq 'timestamp without time zone') {
 137     $info->{_ic_dt_method} = 'timestamp_without_timezone';
 138   }
 139   elsif ($data_type eq 'smalldatetime') {
 140     $info->{_ic_dt_method} = 'smalldatetime';
 141   }
 142   elsif ($data_type =~ /^ (?: date | datetime | timestamp ) $/x) {
 143     $info->{_ic_dt_method} = $data_type;
 144   }
 145   else {
 146     $info->{_ic_dt_method} = $requested_type;
 147   }
 148
 149   return unless $info->{_ic_dt_method};
 150
 151   if ($info->{extra}) {
 152     for my $slot (qw/timezone locale floating_tz_ok/) {
 153       if ( defined $info->{extra}{$slot} ) {
 154         carp "Putting $slot into extra => { $slot => '...' } has been deprecated, ".
 155              "please put it directly into the '$column' column definition.";
 156         $info->{$slot} = $info->{extra}{$slot} unless defined $info->{$slot};
 157       }
 158     }
 159   }
 160
 161   # shallow copy to avoid unfounded(?) Devel::Cycle complaints
 162   my $infcopy = {%$info};
 163
 164   $self->inflate_column(
 165     $column =>
 166       {
 167         inflate => sub {
 168           my ($value, $obj) = @_;
 169
 170           my $dt = try
 171             { $obj->_inflate_to_datetime( $value, $infcopy ) }
 172             catch {
 173               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $_")
 174                 unless $infcopy->{datetime_undef_if_invalid};
 175               undef;  # rv
 176             };
 177
 178           return (defined $dt)
 179             ? $obj->_post_inflate_datetime( $dt, $infcopy )
 180             : undef
 181           ;
 182         },
 183         deflate => sub {
 184           my ($value, $obj) = @_;
 185
 186           $value = $obj->_pre_deflate_datetime( $value, $infcopy );
 187           $obj->_deflate_from_datetime( $value, $infcopy );
 188         },
 189       }
 190   );
 191 }
 192
 193 sub _flate_or_fallback
 194 {
 195   my( $self, $value, $info, $method_fmt ) = @_;
 196
 197   my $parser = $self->_datetime_parser;
 198   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 199   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 200   return $parser->$method($value);
 201 }
 202
 203 sub _inflate_to_datetime {
 204   my( $self, $value, $info ) = @_;
 205   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 206 }
 207
 208 sub _deflate_from_datetime {
 209   my( $self, $value, $info ) = @_;
 210   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 211 }
 212
 213 sub _datetime_parser {
 214   shift->result_source->storage->datetime_parser (@_);
 215 }
 216
 217 sub _post_inflate_datetime {
 218   my( $self, $dt, $info ) = @_;
 219
 220   $dt->set_time_zone($info->{timezone}) if defined $info->{timezone};
 221   $dt->set_locale($info->{locale}) if defined $info->{locale};
 222
 223   return $dt;
 224 }
 225
 226 sub _pre_deflate_datetime {
 227   my( $self, $dt, $info ) = @_;
 228
 229   if (defined $info->{timezone}) {
 230     carp "You're using a floating timezone, please see the documentation of"
 231       . " DBIx::Class::InflateColumn::DateTime for an explanation"
 232       if ref( $dt->time_zone ) eq 'DateTime::TimeZone::Floating'
 233           and not $info->{floating_tz_ok}
 234           and not $ENV{DBIC_FLOATING_TZ_OK};
 235
 236     $dt->set_time_zone($info->{timezone});
 237   }
 238
 239   $dt->set_locale($info->{locale}) if defined $info->{locale};
 240
 241   return $dt;
 242 }
 243
 244 1;
 245 __END__
 246
 247 =head1 USAGE NOTES
 248
 249 If you have a datetime column with an associated C<timezone>, and subsequently
 250 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 251 timezone, you will get a warning (as there is a very good chance this will not have the
 252 result you expect). For example:
 253
 254   __PACKAGE__->add_columns(
 255     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 256   );
 257
 258   my $event = $schema->resultset('EventTZ')->create({
 259     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 260   });
 261
 262 The warning can be avoided in several ways:
 263
 264 =over
 265
 266 =item Fix your broken code
 267
 268 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 269 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 270 to be supply explicit times to the database:
 271
 272   my $event = $schema->resultset('EventTZ')->create({
 273     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 274   });
 275
 276 =item Suppress the check on per-column basis
 277
 278   __PACKAGE__->add_columns(
 279     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 280   );
 281
 282 =item Suppress the check globally
 283
 284 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 285
 286 =back
 287
 288 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 289 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 290 Instead put it directly into the columns definition like in the examples above. If you still
 291 use the old way you'll see a warning - please fix your code then!
 292
 293 =head1 SEE ALSO
 294
 295 =over 4
 296
 297 =item More information about the add_columns method, and column metadata,
 298       can be found in the documentation for L<DBIx::Class::ResultSource>.
 299
 300 =item Further discussion of problems inherent to the Floating timezone:
 301       L<Floating DateTimes|DateTime/Floating_DateTimes>
 302       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 303
 304 =back
 305
 306 =head1 AUTHOR
 307
 308 Matt S. Trout <mst@shadowcatsystems.co.uk>
 309
 310 =head1 CONTRIBUTORS
 311
 312 Aran Deltac <bluefeet@cpan.org>
 313
 314 =head1 LICENSE
 315
 316 You may distribute this code under the same terms as Perl itself.
 317