lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6
   7 =head1 NAME
   8
   9 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from datetime columns.
  10
  11 =head1 SYNOPSIS
  12
  13 Load this component and then declare one or more
  14 columns to be of the datetime datatype.
  15
  16   package Event;
  17   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  18   __PACKAGE__->add_columns(
  19     starts_when => { data_type => 'datetime' }
  20   );
  21
  22 Then you can treat the specified column as a L<DateTime> object.
  23
  24   print "This event starts the month of ".
  25     $event->starts_when->month_name();
  26
  27 =head1 DESCRIPTION
  28
  29 This module figures out the type of DateTime::Format::* class to
  30 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  31 that you are using.  If you switch from one database to a different
  32 one your code will continue to work without modification.
  33
  34 =cut
  35
  36 __PACKAGE__->load_components(qw/InflateColumn/);
  37
  38 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  39
  40 sub register_column {
  41   my ($self, $column, $info, @rest) = @_;
  42   $self->next::method($column, $info, @rest);
  43   if ($info->{data_type} =~ /^datetime$/i) {
  44     $self->inflate_column(
  45       $column =>
  46         {
  47           inflate => sub {
  48             my ($value, $obj) = @_;
  49             $obj->_datetime_parser->parse_datetime($value);
  50           },
  51           deflate => sub {
  52             my ($value, $obj) = @_;
  53             $obj->_datetime_parser->format_datetime($value);
  54           },
  55         }
  56     );
  57   }
  58 }
  59
  60 sub _datetime_parser {
  61   my $self = shift;
  62   if (my $parser = $self->__datetime_parser) {
  63     return $parser;
  64   }
  65   my $parser = $self->result_source->storage->datetime_parser(@_);
  66   return $self->__datetime_parser($parser);
  67 }
  68
  69 1;
  70 __END__
  71
  72 =head1 SEE ALSO
  73
  74 =over 4
  75
  76 =item More information about the add_columns method, and column metadata,
  77       can be found in the documentation for L<DBIx::Class::ResultSource>.
  78
  79 =back
  80
  81 =head1 AUTHOR
  82
  83 Matt S. Trout <mst@shadowcatsystems.co.uk>
  84
  85 =head1 CONTRIBUTORS
  86
  87 Aran Deltac <bluefeet@cpan.org>
  88
  89 =head1 LICENSE
  90
  91 You may distribute this code under the same terms as Perl itself.
  92