lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  11
  12 =head1 SYNOPSIS
  13
  14 Load this component and then declare one or more
  15 columns to be of the datetime, timestamp or date datatype.
  16
  17   package Event;
  18   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
  19   __PACKAGE__->add_columns(
  20     starts_when => { data_type => 'datetime' }
  21   );
  22
  23 NOTE: You B<must> load C<InflateColumn::DateTime> B<before> C<Core>. See
  24 L<DBIx::Class::Manual::Component> for details.
  25
  26 Then you can treat the specified column as a L<DateTime> object.
  27
  28   print "This event starts the month of ".
  29     $event->starts_when->month_name();
  30
  31 If you want to set a specific timezone and locale for that field, use:
  32
  33   __PACKAGE__->add_columns(
  34     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  35   );
  36
  37 If you want to inflate no matter what data_type your column is,
  38 use inflate_datetime or inflate_date:
  39
  40   __PACKAGE__->add_columns(
  41     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  42   );
  43
  44   __PACKAGE__->add_columns(
  45     starts_when => { data_type => 'varchar', inflate_date => 1 }
  46   );
  47
  48 It's also possible to explicitly skip inflation:
  49
  50   __PACKAGE__->add_columns(
  51     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  52   );
  53
  54 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
  55 The column is set directly for any non-references and C<InflateColumn::DateTime>
  56 is completely bypassed.  Instead, use an input parser to create a DateTime
  57 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
  58 use C<DateTime::Format::ISO8601> thusly:
  59
  60   use DateTime::Format::ISO8601;
  61   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  62
  63 =head1 DESCRIPTION
  64
  65 This module figures out the type of DateTime::Format::* class to
  66 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  67 that you are using.  If you switch from one database to a different
  68 one your code should continue to work without modification (though note
  69 that this feature is new as of 0.07, so it may not be perfect yet - bug
  70 reports to the list very much welcome).
  71
  72 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  73
  74 =cut
  75
  76 __PACKAGE__->load_components(qw/InflateColumn/);
  77
  78 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  79
  80 =head2 register_column
  81
  82 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  83 up datetime columns appropriately.  This would not normally be
  84 directly called by end users.
  85
  86 In the case of an invalid date, L<DateTime> will throw an exception.  To
  87 bypass these exceptions and just have the inflation return undef, use
  88 the C<datetime_undef_if_invalid> option in the column info:
  89
  90     "broken_date",
  91     {
  92         data_type => "datetime",
  93         default_value => '0000-00-00',
  94         is_nullable => 1,
  95         datetime_undef_if_invalid => 1
  96     }
  97
  98 =cut
  99
 100 sub register_column {
 101   my ($self, $column, $info, @rest) = @_;
 102   $self->next::method($column, $info, @rest);
 103   return unless defined($info->{data_type});
 104
 105   my $type;
 106
 107   for (qw/date datetime timestamp/) {
 108     my $key = "inflate_${_}";
 109
 110     next unless exists $info->{$key};
 111     return unless $info->{$key};
 112
 113     $type = $_;
 114     last;
 115   }
 116
 117   unless ($type) {
 118     $type = lc($info->{data_type});
 119     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 120       $type = "timestamp";
 121       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 122     } elsif ($type eq "smalldatetime") {
 123       $type = "datetime";
 124       $info->{_ic_dt_method} ||= "datetime";
 125     }
 126   }
 127
 128   my $timezone;
 129   if ( defined $info->{extra}{timezone} ) {
 130     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 131          "please put it directly into the '$column' column definition.";
 132     $timezone = $info->{extra}{timezone};
 133   }
 134
 135   my $locale;
 136   if ( defined $info->{extra}{locale} ) {
 137     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 138          "please put it directly into the '$column' column definition.";
 139     $locale = $info->{extra}{locale};
 140   }
 141
 142   $locale   = $info->{locale}   if defined $info->{locale};
 143   $timezone = $info->{timezone} if defined $info->{timezone};
 144
 145   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 146
 147   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 148     # This shallow copy of %info avoids t/52_cycle.t treating
 149     # the resulting deflator as a circular reference.
 150     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 151
 152     if (defined $info->{extra}{floating_tz_ok}) {
 153       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 154            "please put it directly into the '$column' column definition.";
 155       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 156     }
 157
 158     $self->inflate_column(
 159       $column =>
 160         {
 161           inflate => sub {
 162             my ($value, $obj) = @_;
 163
 164             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 165             if (my $err = $@ ) {
 166               return undef if ($undef_if_invalid);
 167               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $err");
 168             }
 169
 170             $dt->set_time_zone($timezone) if $timezone;
 171             $dt->set_locale($locale) if $locale;
 172             return $dt;
 173           },
 174           deflate => sub {
 175             my ($value, $obj) = @_;
 176             if ($timezone) {
 177                 carp "You're using a floating timezone, please see the documentation of"
 178                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
 179                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
 180                       and not $info{floating_tz_ok}
 181                       and not $ENV{DBIC_FLOATING_TZ_OK};
 182                 $value->set_time_zone($timezone);
 183                 $value->set_locale($locale) if $locale;
 184             }
 185             $obj->_deflate_from_datetime( $value, \%info );
 186           },
 187         }
 188     );
 189   }
 190 }
 191
 192 sub _flate_or_fallback
 193 {
 194   my( $self, $value, $info, $method_fmt ) = @_;
 195
 196   my $parser = $self->_datetime_parser;
 197   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 198   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 199   return $parser->$method($value);
 200 }
 201
 202 sub _inflate_to_datetime {
 203   my( $self, $value, $info ) = @_;
 204   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 205 }
 206
 207 sub _deflate_from_datetime {
 208   my( $self, $value, $info ) = @_;
 209   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 210 }
 211
 212 sub _datetime_parser {
 213   my $self = shift;
 214   if (my $parser = $self->__datetime_parser) {
 215     return $parser;
 216   }
 217   my $parser = $self->result_source->storage->datetime_parser(@_);
 218   return $self->__datetime_parser($parser);
 219 }
 220
 221 1;
 222 __END__
 223
 224 =head1 USAGE NOTES
 225
 226 If you have a datetime column with an associated C<timezone>, and subsequently
 227 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 228 timezone, you will get a warning (as there is a very good chance this will not have the
 229 result you expect). For example:
 230
 231   __PACKAGE__->add_columns(
 232     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 233   );
 234
 235   my $event = $schema->resultset('EventTZ')->create({
 236     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 237   });
 238
 239 The warning can be avoided in several ways:
 240
 241 =over
 242
 243 =item Fix your broken code
 244
 245 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 246 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 247 to be supply explicit times to the database:
 248
 249   my $event = $schema->resultset('EventTZ')->create({
 250     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 251   });
 252
 253 =item Suppress the check on per-column basis
 254
 255   __PACKAGE__->add_columns(
 256     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 257   );
 258
 259 =item Suppress the check globally
 260
 261 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 262
 263 =back
 264
 265 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 266 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 267 Instead put it directly into the columns definition like in the examples above. If you still
 268 use the old way you'll see a warning - please fix your code then!
 269
 270 =head1 SEE ALSO
 271
 272 =over 4
 273
 274 =item More information about the add_columns method, and column metadata,
 275       can be found in the documentation for L<DBIx::Class::ResultSource>.
 276
 277 =item Further discussion of problems inherent to the Floating timezone:
 278       L<Floating DateTimes|DateTime/Floating_DateTimes>
 279       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 280
 281 =back
 282
 283 =head1 AUTHOR
 284
 285 Matt S. Trout <mst@shadowcatsystems.co.uk>
 286
 287 =head1 CONTRIBUTORS
 288
 289 Aran Deltac <bluefeet@cpan.org>
 290
 291 =head1 LICENSE
 292
 293 You may distribute this code under the same terms as Perl itself.
 294