lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7 use Try::Tiny;
   8 use namespace::clean;
   9
  10 =head1 NAME
  11
  12 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  13
  14 =head1 SYNOPSIS
  15
  16 Load this component and then declare one or more
  17 columns to be of the datetime, timestamp or date datatype.
  18
  19   package Event;
  20   use base 'DBIx::Class::Core';
  21
  22   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  23   __PACKAGE__->add_columns(
  24     starts_when => { data_type => 'datetime' }
  25     create_date => { data_type => 'date' }
  26   );
  27
  28 Then you can treat the specified column as a L<DateTime> object.
  29
  30   print "This event starts the month of ".
  31     $event->starts_when->month_name();
  32
  33 If you want to set a specific timezone and locale for that field, use:
  34
  35   __PACKAGE__->add_columns(
  36     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  37   );
  38
  39 If you want to inflate no matter what data_type your column is,
  40 use inflate_datetime or inflate_date:
  41
  42   __PACKAGE__->add_columns(
  43     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  44   );
  45
  46   __PACKAGE__->add_columns(
  47     starts_when => { data_type => 'varchar', inflate_date => 1 }
  48   );
  49
  50 It's also possible to explicitly skip inflation:
  51
  52   __PACKAGE__->add_columns(
  53     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  54   );
  55
  56 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
  57 The column is set directly for any non-references and C<InflateColumn::DateTime>
  58 is completely bypassed.  Instead, use an input parser to create a DateTime
  59 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
  60 use C<DateTime::Format::ISO8601> thusly:
  61
  62   use DateTime::Format::ISO8601;
  63   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  64
  65 =head1 DESCRIPTION
  66
  67 This module figures out the type of DateTime::Format::* class to
  68 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  69 that you are using.  If you switch from one database to a different
  70 one your code should continue to work without modification (though note
  71 that this feature is new as of 0.07, so it may not be perfect yet - bug
  72 reports to the list very much welcome).
  73
  74 If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
  75 a derivative of these datatypes, e.g. C<timestamp with timezone>), this
  76 module will automatically call the appropriate parse/format method for
  77 deflation/inflation as defined in the storage class. For instance, for
  78 a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
  79 would be called on deflation/inflation. If the storage class does not
  80 provide a specialized inflator/deflator, C<[parse|format]_datetime> will
  81 be used as a fallback. See L<DateTime::Format> for more information on
  82 date formatting.
  83
  84 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  85
  86 =cut
  87
  88 __PACKAGE__->load_components(qw/InflateColumn/);
  89
  90 =head2 register_column
  91
  92 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  93 up datetime columns appropriately.  This would not normally be
  94 directly called by end users.
  95
  96 In the case of an invalid date, L<DateTime> will throw an exception.  To
  97 bypass these exceptions and just have the inflation return undef, use
  98 the C<datetime_undef_if_invalid> option in the column info:
  99
 100     "broken_date",
 101     {
 102         data_type => "datetime",
 103         default_value => '0000-00-00',
 104         is_nullable => 1,
 105         datetime_undef_if_invalid => 1
 106     }
 107
 108 =cut
 109
 110 sub register_column {
 111   my ($self, $column, $info, @rest) = @_;
 112   $self->next::method($column, $info, @rest);
 113   return unless defined($info->{data_type});
 114
 115   my $type;
 116
 117   for (qw/date datetime timestamp/) {
 118     my $key = "inflate_${_}";
 119
 120     next unless exists $info->{$key};
 121     return unless $info->{$key};
 122
 123     $type = $_;
 124     last;
 125   }
 126
 127   unless ($type) {
 128     $type = lc($info->{data_type});
 129     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 130       $type = "timestamp";
 131       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 132     } elsif ($type eq "timestamp without time zone") {
 133       $type = "timestamp";
 134       $info->{_ic_dt_method} ||= "timestamp_without_timezone";
 135     } elsif ($type eq "smalldatetime") {
 136       $type = "datetime";
 137       $info->{_ic_dt_method} ||= "smalldatetime";
 138     }
 139   }
 140
 141   if ( defined $info->{extra}{timezone} ) {
 142     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 143          "please put it directly into the '$column' column definition.";
 144     $info->{timezone} = $info->{extra}{timezone} unless defined $info->{timezone};
 145   }
 146
 147   if ( defined $info->{extra}{locale} ) {
 148     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 149          "please put it directly into the '$column' column definition.";
 150     $info->{locale} = $info->{extra}{locale} unless defined $info->{locale};
 151   }
 152
 153   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 154
 155   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 156     # This shallow copy of %info avoids t/52_cycle.t treating
 157     # the resulting deflator as a circular reference.
 158     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 159
 160     if (defined $info->{extra}{floating_tz_ok}) {
 161       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 162            "please put it directly into the '$column' column definition.";
 163       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 164     }
 165
 166     $self->inflate_column(
 167       $column =>
 168         {
 169           inflate => sub {
 170             my ($value, $obj) = @_;
 171
 172             my $dt = try
 173               { $obj->_inflate_to_datetime( $value, \%info ) }
 174               catch {
 175                 $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $_")
 176                   unless $undef_if_invalid;
 177                 undef;  # rv
 178               };
 179
 180             return (defined $dt)
 181               ? $obj->_post_inflate_datetime( $dt, \%info )
 182               : undef
 183             ;
 184           },
 185           deflate => sub {
 186             my ($value, $obj) = @_;
 187
 188             $value = $obj->_pre_deflate_datetime( $value, \%info );
 189             $obj->_deflate_from_datetime( $value, \%info );
 190           },
 191         }
 192     );
 193   }
 194 }
 195
 196 sub _flate_or_fallback
 197 {
 198   my( $self, $value, $info, $method_fmt ) = @_;
 199
 200   my $parser = $self->_datetime_parser;
 201   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 202   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 203   return $parser->$method($value);
 204 }
 205
 206 sub _inflate_to_datetime {
 207   my( $self, $value, $info ) = @_;
 208   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 209 }
 210
 211 sub _deflate_from_datetime {
 212   my( $self, $value, $info ) = @_;
 213   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 214 }
 215
 216 sub _datetime_parser {
 217   shift->result_source->storage->datetime_parser (@_);
 218 }
 219
 220 sub _post_inflate_datetime {
 221   my( $self, $dt, $info ) = @_;
 222
 223   $dt->set_time_zone($info->{timezone}) if defined $info->{timezone};
 224   $dt->set_locale($info->{locale}) if defined $info->{locale};
 225
 226   return $dt;
 227 }
 228
 229 sub _pre_deflate_datetime {
 230   my( $self, $dt, $info ) = @_;
 231
 232   if (defined $info->{timezone}) {
 233     carp "You're using a floating timezone, please see the documentation of"
 234       . " DBIx::Class::InflateColumn::DateTime for an explanation"
 235       if ref( $dt->time_zone ) eq 'DateTime::TimeZone::Floating'
 236           and not $info->{floating_tz_ok}
 237           and not $ENV{DBIC_FLOATING_TZ_OK};
 238
 239     $dt->set_time_zone($info->{timezone});
 240   }
 241
 242   $dt->set_locale($info->{locale}) if defined $info->{locale};
 243
 244   return $dt;
 245 }
 246
 247 1;
 248 __END__
 249
 250 =head1 USAGE NOTES
 251
 252 If you have a datetime column with an associated C<timezone>, and subsequently
 253 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 254 timezone, you will get a warning (as there is a very good chance this will not have the
 255 result you expect). For example:
 256
 257   __PACKAGE__->add_columns(
 258     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 259   );
 260
 261   my $event = $schema->resultset('EventTZ')->create({
 262     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 263   });
 264
 265 The warning can be avoided in several ways:
 266
 267 =over
 268
 269 =item Fix your broken code
 270
 271 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 272 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 273 to be supply explicit times to the database:
 274
 275   my $event = $schema->resultset('EventTZ')->create({
 276     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 277   });
 278
 279 =item Suppress the check on per-column basis
 280
 281   __PACKAGE__->add_columns(
 282     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 283   );
 284
 285 =item Suppress the check globally
 286
 287 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 288
 289 =back
 290
 291 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 292 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 293 Instead put it directly into the columns definition like in the examples above. If you still
 294 use the old way you'll see a warning - please fix your code then!
 295
 296 =head1 SEE ALSO
 297
 298 =over 4
 299
 300 =item More information about the add_columns method, and column metadata,
 301       can be found in the documentation for L<DBIx::Class::ResultSource>.
 302
 303 =item Further discussion of problems inherent to the Floating timezone:
 304       L<Floating DateTimes|DateTime/Floating_DateTimes>
 305       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 306
 307 =back
 308
 309 =head1 AUTHOR
 310
 311 Matt S. Trout <mst@shadowcatsystems.co.uk>
 312
 313 =head1 CONTRIBUTORS
 314
 315 Aran Deltac <bluefeet@cpan.org>
 316
 317 =head1 LICENSE
 318
 319 You may distribute this code under the same terms as Perl itself.
 320