lib/DBIx/Class/InflateColumn.pm

   1 package DBIx::Class::InflateColumn;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'DBIx::Class::Row';
   7 use DBIx::Class::_Util 'is_literal_value';
   8 use namespace::clean;
   9
  10 =head1 NAME
  11
  12 DBIx::Class::InflateColumn - Automatically create references from column data
  13
  14 =head1 SYNOPSIS
  15
  16   # In your table classes
  17   __PACKAGE__->inflate_column('column_name', {
  18     inflate => sub {
  19       my ($raw_value_from_db, $result_object) = @_;
  20       ...
  21     },
  22     deflate => sub {
  23       my ($inflated_value_from_user, $result_object) = @_;
  24       ...
  25     },
  26   });
  27
  28 =head1 DESCRIPTION
  29
  30 This component translates column data into references, i.e. "inflating"
  31 the column data. It also "deflates" references into an appropriate format
  32 for the database.
  33
  34 It can be used, for example, to automatically convert to and from
  35 L<DateTime> objects for your date and time fields. There's a
  36 convenience component to actually do that though, try
  37 L<DBIx::Class::InflateColumn::DateTime>.
  38
  39 It will handle all types of references except scalar references. It
  40 will not handle scalar values, these are ignored and thus passed
  41 through to L<SQL::Abstract>. This is to allow setting raw values to
  42 "just work". Scalar references are passed through to the database to
  43 deal with, to allow such settings as C< \'year + 1'> and C< \'DEFAULT' >
  44 to work.
  45
  46 If you want to filter plain scalar values and replace them with
  47 something else, see L<DBIx::Class::FilterColumn>.
  48
  49 =head1 METHODS
  50
  51 =head2 inflate_column
  52
  53 Instruct L<DBIx::Class> to inflate the given column.
  54
  55 In addition to the column name, you must provide C<inflate> and
  56 C<deflate> methods. The C<inflate> method is called when you access
  57 the field, while the C<deflate> method is called when the field needs
  58 to used by the database.
  59
  60 For example, if you have a table C<events> with a timestamp field
  61 named C<insert_time>, you could inflate the column in the
  62 corresponding table class using something like:
  63
  64     __PACKAGE__->inflate_column('insert_time', {
  65         inflate => sub {
  66           my ($insert_time_raw_value, $event_result_object) = @_;
  67           DateTime->from_epoch( epoch => $insert_time_raw_value );
  68         },
  69         deflate => sub {
  70           my ($insert_time_dt_object, $event_result_object) = @_;
  71           $insert_time_dt_object->epoch;
  72         },
  73     });
  74
  75 The coderefs you set for inflate and deflate are called with two parameters,
  76 the first is the value of the column to be inflated/deflated, the second is
  77 the result object itself.
  78
  79 In this example, calls to an event's C<insert_time> accessor return a
  80 L<DateTime> object. This L<DateTime> object is later "deflated" back
  81 to the integer epoch representation when used in the database layer.
  82 For a much more thorough handling of the above example, please see
  83 L<DBIx::Class::DateTime::Epoch>
  84
  85 =cut
  86
  87 sub inflate_column {
  88   my ($self, $col, $attrs) = @_;
  89
  90   my $colinfo = $self->column_info($col);
  91
  92   $self->throw_exception("InflateColumn can not be used on a column with a declared FilterColumn filter")
  93     if defined $colinfo->{_filter_info} and $self->isa('DBIx::Class::FilterColumn');
  94
  95   $self->throw_exception("No such column $col to inflate")
  96     unless $self->has_column($col);
  97   $self->throw_exception("inflate_column needs attr hashref")
  98     unless ref $attrs eq 'HASH';
  99   $colinfo->{_inflate_info} = $attrs;
 100   my $acc = $colinfo->{accessor};
 101   $self->mk_group_accessors('inflated_column' => [ (defined $acc ? $acc : $col), $col]);
 102   return 1;
 103 }
 104
 105 sub _inflated_column {
 106   my ($self, $col, $value) = @_;
 107   return $value unless defined $value; # NULL is NULL is NULL
 108
 109   my $info = $self->column_info($col)
 110     or $self->throw_exception("No column info for $col");
 111
 112   return $value unless exists $info->{_inflate_info};
 113
 114   return (
 115     $info->{_inflate_info}{inflate}
 116       ||
 117     $self->throw_exception("No inflator found for '$col'")
 118   )->($value, $self);
 119 }
 120
 121 sub _deflated_column {
 122   my ($self, $col, $value) = @_;
 123
 124   ## Deflate any refs except for literals, pass through plain values
 125   return $value if (
 126     ! length ref $value
 127       or
 128     is_literal_value($value)
 129   );
 130
 131   my $info = $self->column_info($col) or
 132     $self->throw_exception("No column info for $col");
 133
 134   return $value unless exists $info->{_inflate_info};
 135
 136   return (
 137     $info->{_inflate_info}{deflate}
 138       ||
 139     $self->throw_exception("No deflator found for '$col'")
 140   )->($value, $self);
 141 }
 142
 143 =head2 get_inflated_column
 144
 145   my $val = $obj->get_inflated_column($col);
 146
 147 Fetch a column value in its inflated state.  This is directly
 148 analogous to L<DBIx::Class::Row/get_column> in that it only fetches a
 149 column already retrieved from the database, and then inflates it.
 150 Throws an exception if the column requested is not an inflated column.
 151
 152 =cut
 153
 154 sub get_inflated_column {
 155   my ($self, $col) = @_;
 156
 157   $self->throw_exception("$col is not an inflated column")
 158     unless exists $self->column_info($col)->{_inflate_info};
 159
 160   # we take care of keeping things in sync
 161   return $self->{_inflated_column}{$col}
 162     if exists $self->{_inflated_column}{$col};
 163
 164   my $val = $self->get_column($col);
 165
 166   return $val if is_literal_value($val);  #that would be a not-yet-reloaded literal update
 167
 168   return $self->{_inflated_column}{$col} = $self->_inflated_column($col, $val);
 169 }
 170
 171 =head2 set_inflated_column
 172
 173   my $copy = $obj->set_inflated_column($col => $val);
 174
 175 Sets a column value from an inflated value.  This is directly
 176 analogous to L<DBIx::Class::Row/set_column>.
 177
 178 =cut
 179
 180 sub set_inflated_column {
 181   my ($self, $col, $value) = @_;
 182
 183   $self->set_column($col, $self->_deflated_column($col, $value));
 184
 185   if (length ref $value and ! is_literal_value($value) ) {
 186     $self->{_inflated_column}{$col} = $value;
 187   } else {
 188     delete $self->{_inflated_column}{$col};
 189   }
 190   return $value;
 191 }
 192
 193 =head2 store_inflated_column
 194
 195   my $copy = $obj->store_inflated_column($col => $val);
 196
 197 Sets a column value from an inflated value without marking the column
 198 as dirty. This is directly analogous to L<DBIx::Class::Row/store_column>.
 199
 200 =cut
 201
 202 sub store_inflated_column {
 203   my ($self, $col, $value) = @_;
 204
 205   if (is_literal_value($value)) {
 206     delete $self->{_inflated_column}{$col};
 207     $self->store_column($col => $value);
 208   }
 209   else {
 210     delete $self->{_column_data}{$col};
 211     $self->{_inflated_column}{$col} = $value;
 212   }
 213
 214   return $value;
 215 }
 216
 217 =head1 SEE ALSO
 218
 219 =over 4
 220
 221 =item L<DBIx::Class::Core> - This component is loaded as part of the
 222       C<core> L<DBIx::Class> components; generally there is no need to
 223       load it directly
 224
 225 =back
 226
 227 =head1 AUTHOR
 228
 229 Matt S. Trout <mst@shadowcatsystems.co.uk>
 230
 231 =head1 CONTRIBUTORS
 232
 233 Daniel Westermann-Clark <danieltwc@cpan.org> (documentation)
 234
 235 Jess Robinson <cpan@desert-island.demon.co.uk>
 236
 237 =head1 LICENSE
 238
 239 You may distribute this code under the same terms as Perl itself.
 240
 241 =cut
 242
 243 1;