lib/DBIx/Class/InflateColumn.pm

   1 package DBIx::Class::InflateColumn;
   2
   3 use strict;
   4 use warnings;
   5 use Scalar::Util qw/blessed/;
   6
   7 use base qw/DBIx::Class::Row/;
   8
   9 =head1 NAME
  10
  11 DBIx::Class::InflateColumn - Automatically create references from column data
  12
  13 =head1 SYNOPSIS
  14
  15     # In your table classes
  16     __PACKAGE__->inflate_column('column_name', {
  17         inflate => sub { ... },
  18         deflate => sub { ... },
  19     });
  20
  21 =head1 DESCRIPTION
  22
  23 This component translates column data into references, i.e. "inflating"
  24 the column data. It also "deflates" references into an appropriate format
  25 for the database.
  26
  27 It can be used, for example, to automatically convert to and from
  28 L<DateTime> objects for your date and time fields. There's a
  29 convenience component to actually do that though, try
  30 L<DBIx::Class::InflateColumn::DateTime>.
  31
  32 It will handle all types of references except scalar references. It
  33 will not handle scalar values, these are ignored and thus passed
  34 through to L<SQL::Abstract>. This is to allow setting raw values to
  35 "just work". Scalar references are passed through to the database to
  36 deal with, to allow such settings as C< \'year + 1'> and C< \'DEFAULT' >
  37 to work.
  38
  39 If you want to filter plain scalar values and replace them with
  40 something else, see L<DBIx::Class::FilterColumn>.
  41
  42 =head1 METHODS
  43
  44 =head2 inflate_column
  45
  46 Instruct L<DBIx::Class> to inflate the given column.
  47
  48 In addition to the column name, you must provide C<inflate> and
  49 C<deflate> methods. The C<inflate> method is called when you access
  50 the field, while the C<deflate> method is called when the field needs
  51 to used by the database.
  52
  53 For example, if you have a table C<events> with a timestamp field
  54 named C<insert_time>, you could inflate the column in the
  55 corresponding table class using something like:
  56
  57     __PACKAGE__->inflate_column('insert_time', {
  58         inflate => sub { DateTime::Format::Pg->parse_datetime(shift); },
  59         deflate => sub { DateTime::Format::Pg->format_datetime(shift); },
  60     });
  61
  62 (Replace L<DateTime::Format::Pg> with the appropriate module for your
  63 database, or consider L<DateTime::Format::DBI>.)
  64
  65 The coderefs you set for inflate and deflate are called with two parameters,
  66 the first is the value of the column to be inflated/deflated, the second is the
  67 row object itself. Thus you can call C<< ->result_source->schema->storage->dbh >> in your inflate/defalte subs, to feed to L<DateTime::Format::DBI>.
  68
  69 In this example, calls to an event's C<insert_time> accessor return a
  70 L<DateTime> object. This L<DateTime> object is later "deflated" when
  71 used in the database layer.
  72
  73 =cut
  74
  75 sub inflate_column {
  76   my ($self, $col, $attrs) = @_;
  77
  78   $self->throw_exception("InflateColumn does not work with FilterColumn")
  79     if $self->isa('DBIx::Class::FilterColumn') &&
  80       defined $self->column_info($col)->{_filter_info};
  81
  82   $self->throw_exception("No such column $col to inflate")
  83     unless $self->has_column($col);
  84   $self->throw_exception("inflate_column needs attr hashref")
  85     unless ref $attrs eq 'HASH';
  86   $self->column_info($col)->{_inflate_info} = $attrs;
  87   my $acc = $self->column_info($col)->{accessor};
  88   $self->mk_group_accessors('inflated_column' => [ (defined $acc ? $acc : $col), $col]);
  89   return 1;
  90 }
  91
  92 sub _inflated_column {
  93   my ($self, $col, $value) = @_;
  94   return $value unless defined $value; # NULL is NULL is NULL
  95   my $info = $self->column_info($col)
  96     or $self->throw_exception("No column info for $col");
  97   return $value unless exists $info->{_inflate_info};
  98   my $inflate = $info->{_inflate_info}{inflate};
  99   $self->throw_exception("No inflator for $col") unless defined $inflate;
 100   return $inflate->($value, $self);
 101 }
 102
 103 sub _deflated_column {
 104   my ($self, $col, $value) = @_;
 105 #  return $value unless ref $value && blessed($value); # If it's not an object, don't touch it
 106   ## Leave scalar refs (ala SQL::Abstract literal SQL), untouched, deflate all other refs
 107   return $value unless (ref $value && ref($value) ne 'SCALAR');
 108   my $info = $self->column_info($col) or
 109     $self->throw_exception("No column info for $col");
 110   return $value unless exists $info->{_inflate_info};
 111   my $deflate = $info->{_inflate_info}{deflate};
 112   $self->throw_exception("No deflator for $col") unless defined $deflate;
 113   return $deflate->($value, $self);
 114 }
 115
 116 =head2 get_inflated_column
 117
 118   my $val = $obj->get_inflated_column($col);
 119
 120 Fetch a column value in its inflated state.  This is directly
 121 analogous to L<DBIx::Class::Row/get_column> in that it only fetches a
 122 column already retrieved from the database, and then inflates it.
 123 Throws an exception if the column requested is not an inflated column.
 124
 125 =cut
 126
 127 sub get_inflated_column {
 128   my ($self, $col) = @_;
 129   $self->throw_exception("$col is not an inflated column")
 130     unless exists $self->column_info($col)->{_inflate_info};
 131   return $self->{_inflated_column}{$col}
 132     if exists $self->{_inflated_column}{$col};
 133
 134   my $val = $self->get_column($col);
 135   return $val if ref $val eq 'SCALAR';  #that would be a not-yet-reloaded sclarref update
 136
 137   return $self->{_inflated_column}{$col} = $self->_inflated_column($col, $val);
 138 }
 139
 140 =head2 set_inflated_column
 141
 142   my $copy = $obj->set_inflated_column($col => $val);
 143
 144 Sets a column value from an inflated value.  This is directly
 145 analogous to L<DBIx::Class::Row/set_column>.
 146
 147 =cut
 148
 149 sub set_inflated_column {
 150   my ($self, $col, $inflated) = @_;
 151   $self->set_column($col, $self->_deflated_column($col, $inflated));
 152 #  if (blessed $inflated) {
 153   if (ref $inflated && ref($inflated) ne 'SCALAR') {
 154     $self->{_inflated_column}{$col} = $inflated;
 155   } else {
 156     delete $self->{_inflated_column}{$col};
 157   }
 158   return $inflated;
 159 }
 160
 161 =head2 store_inflated_column
 162
 163   my $copy = $obj->store_inflated_column($col => $val);
 164
 165 Sets a column value from an inflated value without marking the column
 166 as dirty. This is directly analogous to L<DBIx::Class::Row/store_column>.
 167
 168 =cut
 169
 170 sub store_inflated_column {
 171   my ($self, $col, $inflated) = @_;
 172 #  unless (blessed $inflated) {
 173   unless (ref $inflated && ref($inflated) ne 'SCALAR') {
 174       delete $self->{_inflated_column}{$col};
 175       $self->store_column($col => $inflated);
 176       return $inflated;
 177   }
 178   delete $self->{_column_data}{$col};
 179   return $self->{_inflated_column}{$col} = $inflated;
 180 }
 181
 182 =head1 SEE ALSO
 183
 184 =over 4
 185
 186 =item L<DBIx::Class::Core> - This component is loaded as part of the
 187       C<core> L<DBIx::Class> components; generally there is no need to
 188       load it directly
 189
 190 =back
 191
 192 =head1 AUTHOR
 193
 194 Matt S. Trout <mst@shadowcatsystems.co.uk>
 195
 196 =head1 CONTRIBUTORS
 197
 198 Daniel Westermann-Clark <danieltwc@cpan.org> (documentation)
 199
 200 Jess Robinson <cpan@desert-island.demon.co.uk>
 201
 202 =head1 LICENSE
 203
 204 You may distribute this code under the same terms as Perl itself.
 205
 206 =cut
 207
 208 1;