lib/DBIx/Class/FilterColumn.pm

   1 package DBIx::Class::FilterColumn;
   2 use strict;
   3 use warnings;
   4
   5 use base qw/DBIx::Class::Row/;
   6
   7 sub filter_column {
   8   my ($self, $col, $attrs) = @_;
   9
  10   $self->throw_exception("No such column $col to filter")
  11     unless $self->has_column($col);
  12
  13   $self->throw_exception("filter_column needs attr hashref")
  14     unless ref $attrs eq 'HASH';
  15
  16   $self->column_info($col)->{_filter_info} = $attrs;
  17   my $acc = $self->column_info($col)->{accessor};
  18   $self->mk_group_accessors(filtered_column => [ (defined $acc ? $acc : $col), $col]);
  19   return 1;
  20 }
  21
  22 sub _column_from_storage {
  23   my ($self, $col, $value) = @_;
  24
  25   return $value unless defined $value;
  26
  27   my $info = $self->column_info($col)
  28     or $self->throw_exception("No column info for $col");
  29
  30   return $value unless exists $info->{_filter_info};
  31
  32   my $filter = $info->{_filter_info}{filter_from_storage};
  33   $self->throw_exception("No inflator for $col") unless defined $filter;
  34
  35   return $self->$filter($value);
  36 }
  37
  38 sub _column_to_storage {
  39   my ($self, $col, $value) = @_;
  40
  41   my $info = $self->column_info($col) or
  42     $self->throw_exception("No column info for $col");
  43
  44   return $value unless exists $info->{_filter_info};
  45
  46   my $unfilter = $info->{_filter_info}{filter_to_storage};
  47   $self->throw_exception("No unfilter for $col") unless defined $unfilter;
  48   return $self->$unfilter($value);
  49 }
  50
  51 sub get_filtered_column {
  52   my ($self, $col) = @_;
  53
  54   $self->throw_exception("$col is not a filtered column")
  55     unless exists $self->column_info($col)->{_filter_info};
  56
  57   return $self->{_filtered_column}{$col}
  58     if exists $self->{_filtered_column}{$col};
  59
  60   my $val = $self->get_column($col);
  61
  62   return $self->{_filtered_column}{$col} = $self->_column_from_storage($col, $val);
  63 }
  64
  65 sub set_column {
  66   my ($self, $col) = (shift, @_);
  67
  68   # blow cache
  69   delete $self->{_filtered_column}{$col};
  70
  71   $self->next::method(@_);
  72 }
  73
  74 sub set_filtered_column {
  75   my ($self, $col, $filtered) = @_;
  76
  77   # do not blow up the cache via set_column unless necessary
  78   # (filtering may be expensive!)
  79   if (exists $self->{_filtered_column}{$col}) {
  80     return $filtered
  81       if ($self->_eq_column_values ($col, $filtered, $self->{_filtered_column}{$col} ) );
  82
  83     $self->make_column_dirty ($col); # so the comparison won't run again
  84   }
  85
  86   $self->set_column($col, $self->_column_to_storage($col, $filtered));
  87
  88   return $filtered;
  89 }
  90
  91 sub update {
  92   my ($self, $attrs, @rest) = @_;
  93   foreach my $key (keys %{$attrs||{}}) {
  94     if ($self->has_column($key) &&
  95           exists $self->column_info($key)->{_filter_info}) {
  96       my $val = delete $attrs->{$key};
  97       $self->set_filtered_column($key, $val);
  98       $attrs->{$key} = $self->_column_to_storage($key, $val)
  99     }
 100   }
 101   return $self->next::method($attrs, @rest);
 102 }
 103
 104 sub new {
 105   my ($class, $attrs, @rest) = @_;
 106   my $source = $attrs->{-result_source}
 107     or $class->throw_exception('Sourceless rows are not supported with DBIx::Class::FilterColumn');
 108
 109   my $obj = $class->next::method($attrs, @rest);
 110   foreach my $key (keys %{$attrs||{}}) {
 111     if ($obj->has_column($key) &&
 112           exists $obj->column_info($key)->{_filter_info} ) {
 113       my $val = delete $attrs->{$key};
 114       $obj->set_filtered_column($key, $val);
 115     }
 116   }
 117   return $obj;
 118 }
 119
 120 1;
 121
 122 =head1 NAME
 123
 124 DBIx::Class::FilterColumn - Automatically convert column data
 125
 126 =head1 SYNOPSIS
 127
 128  # In your result classes
 129  __PACKAGE__->filter_column( money => {
 130      filter_to_storage => 'to_pennies',
 131      filter_from_storage => 'from_pennies',
 132  });
 133
 134  sub to_pennies   { $_[1] * 100 }
 135
 136  sub from_pennies { $_[1] / 100 }
 137
 138  1;
 139
 140 =head1 DESCRIPTION
 141
 142 This component is meant to be a more powerful, but less DWIM-y,
 143 L<DBIx::Class::InflateColumn>.  One of the major issues with said component is
 144 that it B<only> works with references.  Generally speaking anything that can
 145 be done with L<DBIx::Class::InflateColumn> can be done with this component.
 146
 147 =head1 METHODS
 148
 149 =head2 filter_column
 150
 151  __PACKAGE__->filter_column( colname => {
 152      filter_from_storage => 'method',
 153      filter_to_storage   => 'method',
 154  })
 155
 156 This is the method that you need to call to set up a filtered column.  It takes
 157 exactly two arguments; the first being the column name the second being a
 158 C<HashRef> with C<filter_from_storage> and C<filter_to_storage> having
 159 something that can be called as a method.  The method will be called with
 160 the value of the column as the first non-C<$self> argument.
 161
 162 =head2 get_filtered_column
 163
 164  $obj->get_filtered_column('colname')
 165
 166 Returns the filtered value of the column
 167
 168 =head2 set_filtered_column
 169
 170  $obj->set_filtered_column(colname => 'new_value')
 171
 172 Sets the filtered value of the column