lib/DBIx/Class/FilterColumn.pm

   1 package DBIx::Class::FilterColumn;
   2 use strict;
   3 use warnings;
   4
   5 use base qw/DBIx::Class::Row/;
   6
   7 sub filter_column {
   8   my ($self, $col, $attrs) = @_;
   9
  10   $self->throw_exception("No such column $col to filter")
  11     unless $self->has_column($col);
  12
  13   $self->throw_exception("filter_column needs attr hashref")
  14     unless ref $attrs eq 'HASH';
  15
  16   $self->column_info($col)->{_filter_info} = $attrs;
  17   my $acc = $self->column_info($col)->{accessor};
  18   $self->mk_group_accessors(filtered_column => [ (defined $acc ? $acc : $col), $col]);
  19   return 1;
  20 }
  21
  22 sub _column_from_storage {
  23   my ($self, $col, $value) = @_;
  24
  25   return $value unless defined $value;
  26
  27   my $info = $self->column_info($col)
  28     or $self->throw_exception("No column info for $col");
  29
  30   return $value unless exists $info->{_filter_info};
  31
  32   my $filter = $info->{_filter_info}{filter_from_storage};
  33   $self->throw_exception("No inflator for $col") unless defined $filter;
  34
  35   return $self->$filter($value);
  36 }
  37
  38 sub _column_to_storage {
  39   my ($self, $col, $value) = @_;
  40
  41   my $info = $self->column_info($col) or
  42     $self->throw_exception("No column info for $col");
  43
  44   return $value unless exists $info->{_filter_info};
  45
  46   my $unfilter = $info->{_filter_info}{filter_to_storage};
  47   $self->throw_exception("No unfilter for $col") unless defined $unfilter;
  48   return $self->$unfilter($value);
  49 }
  50
  51 sub get_filtered_column {
  52   my ($self, $col) = @_;
  53
  54   $self->throw_exception("$col is not a filtered column")
  55     unless exists $self->column_info($col)->{_filter_info};
  56
  57   return $self->{_filtered_column}{$col}
  58     if exists $self->{_filtered_column}{$col};
  59
  60   my $val = $self->get_column($col);
  61
  62   return $self->{_filtered_column}{$col} = $self->_column_from_storage($col, $val);
  63 }
  64
  65 sub set_filtered_column {
  66   my ($self, $col, $filtered) = @_;
  67
  68   $self->set_column($col, $self->_column_to_storage($col, $filtered));
  69
  70   delete $self->{_filtered_column}{$col};
  71
  72   return $filtered;
  73 }
  74
  75 sub update {
  76   my ($self, $attrs, @rest) = @_;
  77   foreach my $key (keys %{$attrs||{}}) {
  78     if ($self->has_column($key) &&
  79           exists $self->column_info($key)->{_filter_info}) {
  80       my $val = delete $attrs->{$key};
  81       $self->set_filtered_column($key, $val);
  82       $attrs->{$key} = $self->_column_to_storage($key, $val)
  83     }
  84   }
  85   return $self->next::method($attrs, @rest);
  86 }
  87
  88 sub new {
  89   my ($class, $attrs, @rest) = @_;
  90   my $source = $attrs->{-result_source}
  91     or $class->throw_exception('Sourceless rows are not supported with DBIx::Class::FilterColumn');
  92
  93   my $obj = $class->next::method($attrs, @rest);
  94   foreach my $key (keys %{$attrs||{}}) {
  95     if ($obj->has_column($key) &&
  96           exists $obj->column_info($key)->{_filter_info} ) {
  97       my $val = delete $attrs->{$key};
  98       $obj->set_filtered_column($key, $val);
  99     }
 100   }
 101   return $obj;
 102 }
 103
 104 1;
 105
 106 =head1 NAME
 107
 108 DBIx::Class::FilterColumn - Automatically convert column data
 109
 110 =head1 SYNOPSIS
 111
 112  # In your result classes
 113  __PACKAGE__->filter_column( money => {
 114      filter_to_storage => 'to_pennies',
 115      filter_from_storage => 'from_pennies',
 116  });
 117
 118  sub to_pennies   { $_[1] * 100 }
 119
 120  sub from_pennies { $_[1] / 100 }
 121
 122  1;
 123
 124 =head1 DESCRIPTION
 125
 126 This component is meant to be a more powerful, but less DWIM-y,
 127 L<DBIx::Class::InflateColumn>.  One of the major issues with said component is
 128 that it B<only> works with references.  Generally speaking anything that can
 129 be done with L<DBIx::Class::InflateColumn> can be done with this component.
 130
 131 =head1 METHODS
 132
 133 =head2 filter_column
 134
 135  __PACKAGE__->filter_column( colname => {
 136      filter_from_storage => 'method',
 137      filter_to_storage   => 'method',
 138  })
 139
 140 This is the method that you need to call to set up a filtered column.  It takes
 141 exactly two arguments; the first being the column name the second being a
 142 C<HashRef> with C<filter_from_storage> and C<filter_to_storage> having
 143 something that can be called as a method.  The method will be called with
 144 the value of the column as the first non-C<$self> argument.
 145
 146 =head2 get_filtered_column
 147
 148  $obj->get_filtered_column('colname')
 149
 150 Returns the filtered value of the column
 151
 152 =head2 set_filtered_column
 153
 154  $obj->set_filtered_column(colname => 'new_value')
 155
 156 Sets the filtered value of the column
 157
 158 =head2 update
 159
 160 Just overridden to filter changed columns through this component
 161
 162 =head2 new
 163
 164 Just overridden to filter columns through this component