lib/DBIx/Class/Componentised.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Componentised;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Class::C3;
   8 use Class::Inspector;
   9
  10 sub inject_base {
  11   my ($class, $target, @to_inject) = @_;
  12   {
  13     no strict 'refs';
  14     foreach my $to (reverse @to_inject) {
  15       my @comps = qw(DigestColumns ResultSetManager Ordered UTF8Columns);
  16            # Add components here that need to be loaded before Core
  17       foreach my $first_comp (@comps) {
  18         if ($to eq 'DBIx::Class::Core' &&
  19             $target->isa("DBIx::Class::${first_comp}")) {
  20           warn "Possible incorrect order of components in ".
  21                "${target}::load_components($first_comp) call: Core loaded ".
  22                "before $first_comp. See the documentation for ".
  23                "DBIx::Class::$first_comp for more information";
  24         }
  25       }
  26       unshift( @{"${target}::ISA"}, $to )
  27         unless ($target eq $to || $target->isa($to));
  28     }
  29   }
  30
  31   # Yes, this is hack. But it *does* work. Please don't submit tickets about
  32   # it on the basis of the comments in Class::C3, the author was on #dbix-class
  33   # while I was implementing this.
  34
  35   my $table = { Class::C3::_dump_MRO_table };
  36   eval "package $target; import Class::C3;" unless exists $table->{$target};
  37 }
  38
  39 sub load_components {
  40   my $class = shift;
  41   my $base = $class->component_base_class;
  42   my @comp = map { /^\+(.*)$/ ? $1 : "${base}::$_" } grep { $_ !~ /^#/ } @_;
  43   $class->_load_components(@comp);
  44   Class::C3::reinitialize();
  45 }
  46
  47 sub load_own_components {
  48   my $class = shift;
  49   my @comp = map { "${class}::$_" } grep { $_ !~ /^#/ } @_;
  50   $class->_load_components(@comp);
  51 }
  52
  53 sub _load_components {
  54   my ($class, @comp) = @_;
  55   foreach my $comp (@comp) {
  56     $class->ensure_class_loaded($comp);
  57   }
  58   $class->inject_base($class => @comp);
  59 }
  60
  61 # Given a class name, tests to see if it is already loaded or otherwise
  62 # defined. If it is not yet loaded, the package is require'd, and an exception
  63 # is thrown if the class is still not loaded.
  64 #
  65 # TODO: handle ->has_many('rel', 'Class'...) instead of
  66 #              ->has_many('rel', 'Some::Schema::Class'...)
  67 #
  68 # BUG: For some reason, packages with syntax errors are added to %INC on
  69 #      require
  70 sub ensure_class_loaded {
  71   my ($class, $f_class) = @_;
  72   return if Class::Inspector->loaded($f_class);
  73   eval "require $f_class"; # require needs a bareword or filename
  74   $class->throw_exception($@) if ($@);
  75 }
  76
  77 # Returns true if the specified class is installed or already loaded, false
  78 # otherwise
  79 sub ensure_class_found {
  80   my ($class, $f_class) = @_;
  81   return Class::Inspector->loaded($f_class) ||
  82          Class::Inspector->installed($f_class);
  83 }
  84
  85 # Returns a true value if the specified class is installed and loaded
  86 # successfully, throws an exception if the class is found but not loaded
  87 # successfully, and false if the class is not installed
  88 sub load_optional_class {
  89   my ($class, $f_class) = @_;
  90   if ($class->ensure_class_found($f_class)) {
  91     $class->ensure_class_loaded($f_class);
  92     return 1;
  93   } else {
  94     return 0;
  95   }
  96 }
  97
  98 1;