lib/DBIx/Class/Componentised.pm

   1 package DBIx::Class::Componentised;
   2
   3 use Class::C3;
   4
   5 sub inject_base {
   6   my ($class, $target, @to_inject) = @_;
   7   {
   8     no strict 'refs';
   9     unshift(@{"${target}::ISA"}, grep { $target ne $_ && !$target->isa($_)} @to_inject);
  10   }
  11
  12   # Yes, this is hack. But it *does* work. Please don't submit tickets about
  13   # it on the basis of the comments in Class::C3, the author was on #dbix-class
  14   # while I was implementing this.
  15
  16   my $table = { Class::C3::_dump_MRO_table };
  17   eval "package $target; import Class::C3;" unless exists $table->{$target};
  18 }
  19
  20 sub load_components {
  21   my $class = shift;
  22   my $base = $class->component_base_class;
  23   my @comp = map { /^\+(.*)$/ ? $1 : "${base}::$_" } grep { $_ !~ /^#/ } @_;
  24   $class->_load_components(@comp);
  25   Class::C3::reinitialize();
  26 }
  27
  28 sub load_own_components {
  29   my $class = shift;
  30   my @comp = map { "${class}::$_" } grep { $_ !~ /^#/ } @_;
  31   $class->_load_components(@comp);
  32 }
  33
  34 sub _load_components {
  35   my ($class, @comp) = @_;
  36   foreach my $comp (@comp) {
  37     eval "use $comp";
  38     die $@ if $@;
  39   }
  40   $class->inject_base($class => @comp);
  41 }
  42
  43 1;