lib/DBIx/Class/Componentised.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Componentised;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base 'Class::C3::Componentised';
   8 use Carp::Clan qw/^DBIx::Class/;
   9
  10 sub inject_base {
  11   my ($class, $target, @to_inject) = @_;
  12   {
  13     no strict 'refs';
  14     foreach my $to (reverse @to_inject) {
  15       my @comps = qw(DigestColumns ResultSetManager Ordered UTF8Columns);
  16            # Add components here that need to be loaded before Core
  17       foreach my $first_comp (@comps) {
  18         if ($to eq 'DBIx::Class::Core' &&
  19             $target->isa("DBIx::Class::${first_comp}")) {
  20           warn "Possible incorrect order of components in ".
  21                "${target}::load_components($first_comp) call: Core loaded ".
  22                "before $first_comp. See the documentation for ".
  23                "DBIx::Class::$first_comp for more information";
  24         }
  25       }
  26       unshift( @{"${target}::ISA"}, $to )
  27         unless ($target eq $to || $target->isa($to));
  28     }
  29   }
  30
  31   $class->next::method($target, @to_inject);
  32 }
  33
  34 # Returns a true value if the specified class is installed and loaded
  35 # successfully, throws an exception if the class is found but not loaded
  36 # successfully, and false if the class is not installed
  37 sub load_optional_class {
  38   my ($class, $f_class) = @_;
  39   if ($class->ensure_class_found($f_class)) {
  40     $class->ensure_class_loaded($f_class);
  41     return 1;
  42   } else {
  43     return 0;
  44   }
  45 }
  46
  47 1;