lib/DBIx/Class/CDBICompat/TempColumns.pm

   1 package # hide from PAUSE
   2     DBIx::Class::CDBICompat::TempColumns;
   3
   4 use strict;
   5 use warnings;
   6 use base qw/DBIx::Class/;
   7
   8 __PACKAGE__->mk_classdata('_temp_columns' => { });
   9
  10 sub _add_column_group {
  11   my ($class, $group, @cols) = @_;
  12   if ($group eq 'TEMP') {
  13     $class->_register_column_group($group => @cols);
  14     $class->mk_group_accessors('temp' => @cols);
  15     my %tmp = %{$class->_temp_columns};
  16     $tmp{$_} = 1 for @cols;
  17     $class->_temp_columns(\%tmp);
  18   } else {
  19     return $class->next::method($group, @cols);
  20   }
  21 }
  22
  23 sub new {
  24   my ($class, $attrs, @rest) = @_;
  25
  26   my $temp = $class->_extract_temp_data($attrs);
  27
  28   my $new = $class->next::method($attrs, @rest);
  29
  30   $new->set_temp($_, $temp->{$_}) for keys %$temp;
  31
  32   return $new;
  33 }
  34
  35 sub _extract_temp_data {
  36   my($self, $data) = @_;
  37
  38   my %temp;
  39   foreach my $key (keys %$data) {
  40     $temp{$key} = delete $data->{$key} if $self->_temp_columns->{$key};
  41   }
  42
  43   return \%temp;
  44 }
  45
  46 sub find_column {
  47   my ($class, $col, @rest) = @_;
  48   return $col if $class->_temp_columns->{$col};
  49   return $class->next::method($col, @rest);
  50 }
  51
  52 sub set {
  53   my($self, %data) = @_;
  54
  55   my $temp_data = $self->_extract_temp_data(\%data);
  56
  57   $self->set_temp($_, $temp_data->{$_}) for keys %$temp_data;
  58
  59   return $self->next::method(%data);
  60 }
  61
  62 sub get_temp {
  63   my ($self, $column) = @_;
  64   $self->throw_exception( "Can't fetch data as class method" ) unless ref $self;
  65   $self->throw_exception( "No such TEMP column '${column}'" ) unless $self->_temp_columns->{$column} ;
  66   return $self->{_temp_column_data}{$column}
  67     if exists $self->{_temp_column_data}{$column};
  68   return undef;
  69 }
  70
  71 sub set_temp {
  72   my ($self, $column, $value) = @_;
  73   $self->throw_exception( "No such TEMP column '${column}'" )
  74     unless $self->_temp_columns->{$column};
  75   $self->throw_exception( "set_temp called for ${column} without value" )
  76     if @_ < 3;
  77   return $self->{_temp_column_data}{$column} = $value;
  78 }
  79
  80 sub has_real_column {
  81   return 1 if shift->has_column(shift);
  82 }
  83
  84 1;