lib/DBIx/Class/CDBICompat/TempColumns.pm

   1 package DBIx::Class::CDBICompat::TempColumns;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/Class::Data::Inheritable/;
   6
   7 __PACKAGE__->mk_classdata('_temp_columns' => { });
   8
   9 sub _add_column_group {
  10   my ($class, $group, @cols) = @_;
  11   if ($group eq 'TEMP') {
  12     $class->_register_column_group($group => @cols);
  13     $class->mk_group_accessors('temp' => @cols);
  14     my %tmp = %{$class->_temp_columns};
  15     $tmp{$_} = 1 for @cols;
  16     $class->_temp_columns(\%tmp);
  17   } else {
  18     return $class->NEXT::ACTUAL::_add_column_group($group, @cols);
  19   }
  20 }
  21
  22 sub new {
  23   my ($class, $attrs, @rest) = @_;
  24   my %temp;
  25   foreach my $key (keys %$attrs) {
  26     $temp{$key} = delete $attrs->{$key} if $class->_temp_columns->{$key};
  27   }
  28   my $new = $class->NEXT::ACTUAL::new($attrs, @rest);
  29   foreach my $key (keys %temp) {
  30     $new->set_temp($key, $temp{$key});
  31   }
  32   return $new;
  33 }
  34
  35
  36 sub find_column {
  37   my ($class, $col, @rest) = @_;
  38   return $col if $class->_temp_columns->{$col};
  39   return $class->NEXT::ACTUAL::find_column($col, @rest);
  40 }
  41
  42 sub get_temp {
  43   my ($self, $column) = @_;
  44   $self->throw( "Can't fetch data as class method" ) unless ref $self;
  45   $self->throw( "No such TEMP column '${column}'" ) unless $self->_temp_columns->{$column} ;
  46   return $self->{_temp_column_data}{$column}
  47     if exists $self->{_temp_column_data}{$column};
  48   return undef;
  49 }
  50
  51 sub set_temp {
  52   my ($self, $column, $value) = @_;
  53   $self->throw( "No such TEMP column '${column}'" )
  54     unless $self->_temp_columns->{$column};
  55   $self->throw( "set_temp called for ${column} without value" )
  56     if @_ < 3;
  57   return $self->{_temp_column_data}{$column} = $value;
  58 }
  59
  60 sub has_real_column {
  61   return 1 if shift->has_column(shift);
  62 }
  63
  64 1;