lib/DBIx/Class/CDBICompat/Retrieve.pm

   1 package # hide from PAUSE
   2     DBIx::Class::CDBICompat::Retrieve;
   3
   4 use strict;
   5 use warnings FATAL => 'all';
   6
   7
   8 sub retrieve {
   9   my $self = shift;
  10   die "No args to retrieve" unless @_ > 0;
  11
  12   my @cols = $self->primary_columns;
  13
  14   my $query;
  15   if (ref $_[0] eq 'HASH') {
  16     $query = { %{$_[0]} };
  17   }
  18   elsif (@_ == @cols) {
  19     $query = {};
  20     @{$query}{@cols} = @_;
  21   }
  22   else {
  23     $query = {@_};
  24   }
  25
  26   $query = $self->_build_query($query);
  27   $self->find($query);
  28 }
  29
  30 sub find_or_create {
  31   my $self = shift;
  32   my $query = ref $_[0] eq 'HASH' ? shift : {@_};
  33
  34   $query = $self->_build_query($query);
  35   $self->next::method($query);
  36 }
  37
  38 # _build_query
  39 #
  40 # Build a query hash. Defaults to a no-op; ColumnCase overrides.
  41
  42 sub _build_query {
  43   my ($self, $query) = @_;
  44
  45   return $query;
  46 }
  47
  48 sub retrieve_from_sql {
  49   my ($class, $cond, @rest) = @_;
  50
  51   $cond =~ s/^\s*WHERE//i;
  52
  53   if( $cond =~ s/\bLIMIT (\d+)\s*$//i ) {
  54       push @rest, { rows => $1 };
  55   }
  56
  57   if ( $cond =~ s/\bORDER\s+BY\s+(.*)$//i ) {
  58     push @rest, { order_by => $1 };
  59   }
  60
  61   return $class->search_literal($cond, @rest);
  62 }
  63
  64 sub construct {
  65     my $class = shift;
  66     my $obj = $class->resultset_instance->new_result(@_);
  67     $obj->in_storage(1);
  68
  69     return $obj;
  70 }
  71
  72 sub retrieve_all      { shift->search              }
  73 sub count_all         { shift->count               }
  74
  75 sub maximum_value_of  {
  76     my($class, $col) = @_;
  77     return $class->resultset_instance->get_column($col)->max;
  78 }
  79
  80 sub minimum_value_of  {
  81     my($class, $col) = @_;
  82     return $class->resultset_instance->get_column($col)->min;
  83 }
  84
  85 1;