lib/DBIx/Class/CDBICompat/Relationships.pm

   1 package # hide from PAUSE
   2     DBIx::Class::CDBICompat::Relationships;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base qw/Class::Data::Inheritable/;
   8
   9 use Clone;
  10 use DBIx::Class::CDBICompat::Relationship;
  11
  12 __PACKAGE__->mk_classdata('__meta_info' => {});
  13
  14
  15 =head1 NAME
  16
  17 DBIx::Class::CDBICompat::Relationships
  18
  19 =head1 DESCRIPTION
  20
  21 Emulate C<has_a>, C<has_many>, C<might_have> and C<meta_info>.
  22
  23 =cut
  24
  25 sub has_a {
  26   my ($self, $col, $f_class, %args) = @_;
  27   $self->throw_exception( "No such column ${col}" ) unless $self->has_column($col);
  28   $self->ensure_class_loaded($f_class);
  29
  30   my $rel;
  31
  32   if ($args{'inflate'} || $args{'deflate'}) { # Non-database has_a
  33     if (!ref $args{'inflate'}) {
  34       my $meth = $args{'inflate'};
  35       $args{'inflate'} = sub { $f_class->$meth(shift); };
  36     }
  37     if (!ref $args{'deflate'}) {
  38       my $meth = $args{'deflate'};
  39       $args{'deflate'} = sub { shift->$meth; };
  40     }
  41     $self->inflate_column($col, \%args);
  42
  43     $rel = {
  44         class => $f_class
  45     };
  46   }
  47   else {
  48     $self->belongs_to($col, $f_class);
  49     $rel = $self->result_source_instance->relationship_info($col);
  50   }
  51
  52   $self->_extend_meta(
  53     has_a => $col,
  54     $rel
  55   );
  56
  57   return 1;
  58 }
  59
  60
  61 sub has_many {
  62   my ($class, $rel, $f_class, $f_key, $args) = @_;
  63
  64   my @f_method;
  65
  66   if (ref $f_class eq 'ARRAY') {
  67     ($f_class, @f_method) = @$f_class;
  68   }
  69
  70   if (ref $f_key eq 'HASH' && !$args) { $args = $f_key; undef $f_key; };
  71
  72   $args ||= {};
  73   my $cascade = delete $args->{cascade} || '';
  74   if (delete $args->{no_cascade_delete} || $cascade eq 'None') {
  75     $args->{cascade_delete} = 0;
  76   }
  77   elsif( $cascade eq 'Delete' ) {
  78     $args->{cascade_delete} = 1;
  79   }
  80   elsif( length $cascade ) {
  81     warn "Unemulated cascade option '$cascade' in $class->has_many($rel => $f_class)";
  82   }
  83
  84   if( !$f_key and !@f_method ) {
  85       my $f_source = $f_class->result_source_instance;
  86       ($f_key) = grep { $f_source->relationship_info($_)->{class} eq $class }
  87                       $f_source->relationships;
  88   }
  89
  90   $class->next::method($rel, $f_class, $f_key, $args);
  91
  92   $class->_extend_meta(
  93     has_many => $rel,
  94     $class->result_source_instance->relationship_info($rel)
  95   );
  96
  97   if (@f_method) {
  98     no strict 'refs';
  99     no warnings 'redefine';
 100     my $post_proc = sub { my $o = shift; $o = $o->$_ for @f_method; $o; };
 101     *{"${class}::${rel}"} =
 102       sub {
 103         my $rs = shift->search_related($rel => @_);
 104         $rs->{attrs}{record_filter} = $post_proc;
 105         return (wantarray ? $rs->all : $rs);
 106       };
 107     return 1;
 108   }
 109
 110 }
 111
 112
 113 sub might_have {
 114   my ($class, $rel, $f_class, @columns) = @_;
 115
 116   my $ret;
 117   if (ref $columns[0] || !defined $columns[0]) {
 118     $ret = $class->next::method($rel, $f_class, @columns);
 119   } else {
 120     $ret = $class->next::method($rel, $f_class, undef,
 121                                 { proxy => \@columns });
 122   }
 123
 124   $class->_extend_meta(
 125     might_have => $rel,
 126     $class->result_source_instance->relationship_info($rel)
 127   );
 128
 129   return $ret;
 130 }
 131
 132
 133 sub _extend_meta {
 134     my ($class, $type, $rel, $val) = @_;
 135     my %hash = %{ Clone::clone($class->__meta_info || {}) };
 136
 137     $val->{self_class} = $class;
 138     $val->{type}       = $type;
 139     $val->{accessor}   = $rel;
 140
 141     $hash{$type}{$rel} = DBIx::Class::CDBICompat::Relationship->new($val);
 142     $class->__meta_info(\%hash);
 143 }
 144
 145
 146 sub meta_info {
 147     my ($class, $type, $rel) = @_;
 148     my $meta = $class->__meta_info;
 149     return $meta unless $type;
 150
 151     my $type_meta = $meta->{$type};
 152     return $type_meta unless $rel;
 153     return $type_meta->{$rel};
 154 }
 155
 156
 157 sub search {
 158   my $self = shift;
 159   my $attrs = {};
 160   if (@_ > 1 && ref $_[$#_] eq 'HASH') {
 161     $attrs = { %{ pop(@_) } };
 162   }
 163   my $where = (@_ ? ((@_ == 1) ? ((ref $_[0] eq "HASH") ? { %{+shift} } : shift)
 164                                : {@_})
 165                   : undef());
 166   if (ref $where eq 'HASH') {
 167     foreach my $key (keys %$where) { # has_a deflation hack
 168       $where->{$key} = ''.$where->{$key}
 169         if eval { $where->{$key}->isa('DBIx::Class') };
 170     }
 171   }
 172   $self->next::method($where, $attrs);
 173 }
 174
 175 1;