lib/DBIx/Class/CDBICompat/LazyLoading.pm

   1 package # hide from PAUSE
   2     DBIx::Class::CDBICompat::LazyLoading;
   3
   4 use strict;
   5 use warnings;
   6
   7 use base 'DBIx::Class';
   8
   9 sub resultset_instance {
  10   my $self = shift;
  11   my $rs = $self->next::method(@_);
  12   $rs = $rs->search(undef, { columns => [ $self->columns('Essential') ] });
  13   return $rs;
  14 }
  15
  16
  17 # Emulate that CDBI throws out all changed columns and reloads them on
  18 # request in case the database modifies the new value (say, via a trigger)
  19 sub update {
  20     my $self = shift;
  21
  22     my @dirty_columns = keys %{$self->{_dirty_columns}};
  23
  24     my $ret = $self->next::method(@_);
  25     $self->_clear_column_data(@dirty_columns);
  26
  27     return $ret;
  28 }
  29
  30
  31 # And again for create
  32 sub create {
  33     my $class = shift;
  34     my($data) = @_;
  35
  36     my @columns = keys %$data;
  37
  38     my $obj = $class->next::method(@_);
  39     return $obj unless defined $obj;
  40
  41     my %primary_cols = map { $_ => 1 } $class->primary_columns;
  42     my @data_cols = grep !$primary_cols{$_}, @columns;
  43     $obj->_clear_column_data(@data_cols);
  44
  45     return $obj;
  46 }
  47
  48
  49 sub _clear_column_data {
  50     my $self = shift;
  51
  52     delete $self->{_column_data}{$_}     for @_;
  53     delete $self->{_inflated_column}{$_} for @_;
  54 }
  55
  56
  57 sub get_column {
  58   my ($self, $col) = @_;
  59   if ((ref $self) && (!exists $self->{'_column_data'}{$col})
  60     && $self->{'_in_storage'}) {
  61     $self->_flesh(grep { exists $self->_column_groups->{$_}{$col}
  62                            && $_ ne 'All' }
  63                    keys %{ $self->_column_groups || {} });
  64   }
  65   $self->next::method(@_[1..$#_]);
  66 }
  67
  68 # CDBI does not explicitly declare auto increment columns, so
  69 # we just clear out our primary columns before copying.
  70 sub copy {
  71   my($self, $changes) = @_;
  72
  73   for my $col ($self->primary_columns) {
  74     $changes->{$col} = undef unless exists $changes->{$col};
  75   }
  76
  77   return $self->next::method($changes);
  78 }
  79
  80 sub discard_changes {
  81   my($self) = shift;
  82
  83   delete $self->{_column_data}{$_} for $self->is_changed;
  84   delete $self->{_dirty_columns};
  85   delete $self->{_relationship_data};
  86
  87   return $self;
  88 }
  89
  90 sub _ident_cond {
  91   my ($class) = @_;
  92   return join(" AND ", map { "$_ = ?" } $class->primary_columns);
  93 }
  94
  95 sub _flesh {
  96   my ($self, @groups) = @_;
  97   @groups = ('All') unless @groups;
  98   my %want;
  99   $want{$_} = 1 for map { keys %{$self->_column_groups->{$_}} } @groups;
 100   if (my @want = grep { !exists $self->{'_column_data'}{$_} } keys %want) {
 101     my $cursor = $self->result_source->storage->select(
 102                 $self->result_source->name, \@want,
 103                 \$self->_ident_cond, { bind => [ $self->_ident_values ] });
 104     #my $sth = $self->storage->select($self->_table_name, \@want,
 105     #                                   $self->ident_condition);
 106     # Not sure why the first one works and this doesn't :(
 107     my @val = $cursor->next;
 108
 109     return unless @val; # object must have been deleted from the database
 110
 111     foreach my $w (@want) {
 112       $self->{'_column_data'}{$w} = shift @val;
 113     }
 114   }
 115 }
 116
 117 1;