lib/DBIx/Class/CDBICompat/LazyLoading.pm

   1 package # hide from PAUSE
   2     DBIx::Class::CDBICompat::LazyLoading;
   3
   4 use strict;
   5 use warnings;
   6
   7 sub resultset_instance {
   8   my $self = shift;
   9   my $rs = $self->next::method(@_);
  10   $rs = $rs->search(undef, { columns => [ $self->columns('Essential') ] });
  11   return $rs;
  12 }
  13
  14
  15 # Emulate that CDBI throws out all changed columns and reloads them on
  16 # request in case the database modifies the new value (say, via a trigger)
  17 sub update {
  18     my $self = shift;
  19
  20     my @dirty_columns = keys %{$self->{_dirty_columns}};
  21
  22     my $ret = $self->next::method(@_);
  23
  24     delete $self->{_column_data}{$_}     for @dirty_columns;
  25     delete $self->{_inflated_column}{$_} for @dirty_columns;
  26
  27     return $ret;
  28 }
  29
  30
  31 sub get_column {
  32   my ($self, $col) = @_;
  33   if ((ref $self) && (!exists $self->{'_column_data'}{$col})
  34     && $self->{'_in_storage'}) {
  35     $self->_flesh(grep { exists $self->_column_groups->{$_}{$col}
  36                            && $_ ne 'All' }
  37                    keys %{ $self->_column_groups || {} });
  38   }
  39   $self->next::method(@_[1..$#_]);
  40 }
  41
  42 # CDBI does not explicitly declare auto increment columns, so
  43 # we just clear out our primary columns before copying.
  44 sub copy {
  45   my($self, $changes) = @_;
  46
  47   for my $col ($self->primary_columns) {
  48     $changes->{$col} = undef unless exists $changes->{$col};
  49   }
  50
  51   return $self->next::method($changes);
  52 }
  53
  54 sub discard_changes {
  55   my($self) = shift;
  56
  57   delete $self->{_column_data}{$_} for $self->is_changed;
  58   delete $self->{_dirty_columns};
  59   delete $self->{_relationship_data};
  60
  61   return $self;
  62 }
  63
  64 sub _ident_cond {
  65   my ($class) = @_;
  66   return join(" AND ", map { "$_ = ?" } $class->primary_columns);
  67 }
  68
  69 sub _flesh {
  70   my ($self, @groups) = @_;
  71   @groups = ('All') unless @groups;
  72   my %want;
  73   $want{$_} = 1 for map { keys %{$self->_column_groups->{$_}} } @groups;
  74   if (my @want = grep { !exists $self->{'_column_data'}{$_} } keys %want) {
  75     my $cursor = $self->result_source->storage->select(
  76                 $self->result_source->name, \@want,
  77                 \$self->_ident_cond, { bind => [ $self->_ident_values ] });
  78     #my $sth = $self->storage->select($self->_table_name, \@want,
  79     #                                   $self->ident_condition);
  80     # Not sure why the first one works and this doesn't :(
  81     my @val = $cursor->next;
  82 #warn "Flesh: ".join(', ', @want, '=>', @val);
  83     foreach my $w (@want) {
  84       $self->{'_column_data'}{$w} = shift @val;
  85     }
  86   }
  87 }
  88
  89 1;