lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package DBIx::Class::CDBICompat::ImaDBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::ContextualFetch;
   6
   7 use base qw/DBIx::Class/;
   8
   9 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  10                             => [ qw/TABLE ESSENTIAL JOIN/ ] );
  11
  12 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  13   {
  14     'TABLE' =>
  15       sub {
  16         my ($self, $class, $data) = @_;
  17         return $class->_table_name unless $data;
  18         my ($f_class, $alias) = split(/=/, $data);
  19         $f_class ||= $class;
  20         $self->{_classes}{$alias} = $f_class;
  21         return $f_class->_table_name." ${alias}";
  22       },
  23     'ESSENTIAL' =>
  24       sub {
  25         my ($self, $class, $data) = @_;
  26         return join(' ', $class->columns('Essential')) unless $data;
  27         return join(' ', $self->{_classes}{$data}->columns('Essential'));
  28       },
  29     'JOIN' =>
  30       sub {
  31         my ($self, $class, $data) = @_;
  32         my ($from, $to) = split(/ /, $data);
  33         my ($from_class, $to_class) = @{$self->{_classes}}{$from, $to};
  34         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  35                           values %{ $from_class->_relationships };
  36         unless ($rel_obj) {
  37           ($from, $to) = ($to, $from);
  38           ($from_class, $to_class) = ($to_class, $from_class);
  39           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  40                          values %{ $from_class->_relationships };
  41         }
  42         $self->throw( "No relationship to JOIN from ${from_class} to ${to_class}" )
  43           unless $rel_obj;
  44         my $attrs = {
  45           %$self,
  46           _aliases => { self => $from, foreign => $to },
  47           _action => 'join',
  48         };
  49         my $join = $from_class->storage->sql_maker->_join_condition(
  50           $from_class->resolve_condition($rel_obj->{cond}, $attrs) );
  51         return $join;
  52       }
  53
  54   } );
  55
  56 sub db_Main {
  57   return $_[0]->storage->dbh;
  58 }
  59
  60 sub connection {
  61   my ($class, @info) = @_;
  62   $info[3] = { %{ $info[3] || {}} };
  63   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  64   return $class->next::method(@info);
  65 }
  66
  67 sub __driver {
  68   return $_[0]->storage->dbh->{Driver}->{Name};
  69 }
  70
  71 sub set_sql {
  72   my ($class, $name, $sql) = @_;
  73   no strict 'refs';
  74   *{"${class}::sql_${name}"} =
  75     sub {
  76       my $sql = $sql;
  77       my $class = shift;
  78       return $class->storage->sth($class->transform_sql($sql, @_));
  79     };
  80   if ($sql =~ /select/i) {
  81     my $meth = "sql_${name}";
  82     *{"${class}::search_${name}"} =
  83       sub {
  84         my ($class, @args) = @_;
  85         my $sth = $class->$meth;
  86         $sth->execute(@args);
  87         return $class->sth_to_objects($sth);
  88       };
  89   }
  90 }
  91
  92 sub sth_to_objects {
  93   my ($class, $sth) = @_;
  94   my @cols = $class->_select_columns;
  95   my @ret;
  96   while (my @row = $sth->fetchrow_array) {
  97     push(@ret, $class->_row_to_object(\@cols,\@row));
  98   }
  99   return @ret;
 100 }
 101
 102 sub transform_sql {
 103   my ($class, $sql, @args) = @_;
 104   my $attrs = { };
 105   foreach my $key (@{$class->_transform_sql_handler_order}) {
 106     my $h = $class->_transform_sql_handlers->{$key};
 107     $sql =~ s/__$key(?:\(([^\)]+)\))?__/$h->($attrs, $class, $1)/eg;
 108   }
 109   #warn $sql;
 110   return sprintf($sql, @args);
 111 }
 112
 113 package DBIx::ContextualFetch::st;
 114
 115 no warnings 'redefine';
 116
 117 sub _untaint_execute {
 118   my $sth = shift;
 119   my $old_value = $sth->{Taint};
 120   $sth->{Taint} = 0;
 121   my $ret;
 122   {
 123     no warnings 'uninitialized';
 124     $ret = $sth->SUPER::execute(@_);
 125   }
 126   $sth->{Taint} = $old_value;
 127   return $ret;
 128 }
 129
 130 1;