lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package DBIx::Class::CDBICompat::ImaDBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::ContextualFetch;
   6
   7 use NEXT;
   8 use base qw/Class::Data::Inheritable/;
   9
  10 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  11                             => [ qw/TABLE ESSENTIAL JOIN/ ] );
  12
  13 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  14   {
  15     'TABLE' =>
  16       sub {
  17         my ($self, $class, $data) = @_;
  18         return $class->_table_name unless $data;
  19         my ($f_class, $alias) = split(/=/, $data);
  20         $f_class ||= $class;
  21         $self->{_classes}{$alias} = $f_class;
  22         return $f_class->_table_name." ${alias}";
  23       },
  24     'ESSENTIAL' =>
  25       sub {
  26         my ($self, $class, $data) = @_;
  27         return join(' ', $class->columns('Essential')) unless $data;
  28         return join(' ', $self->{_classes}{$data}->columns('Essential'));
  29       },
  30     'JOIN' =>
  31       sub {
  32         my ($self, $class, $data) = @_;
  33         my ($from, $to) = split(/ /, $data);
  34         my ($from_class, $to_class) = @{$self->{_classes}}{$from, $to};
  35         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  36                           values %{ $from_class->_relationships };
  37         unless ($rel_obj) {
  38           ($from, $to) = ($to, $from);
  39           ($from_class, $to_class) = ($to_class, $from_class);
  40           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  41                          values %{ $from_class->_relationships };
  42         }
  43         $self->throw( "No relationship to JOIN from ${from_class} to ${to_class}" )
  44           unless $rel_obj;
  45         my $attrs = {
  46           %$self,
  47           _aliases => { self => $from, foreign => $to },
  48           _action => 'join',
  49         };
  50         my $join = $from_class->_cond_resolve($rel_obj->{cond}, $attrs);
  51         return $join;
  52       }
  53
  54   } );
  55
  56 sub db_Main {
  57   return $_[0]->storage->dbh;
  58 }
  59
  60 sub connection {
  61   my ($class, @info) = @_;
  62   $info[3] = { %{ $info[3] || {}} };
  63   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  64   return $class->NEXT::connection(@info);
  65 }
  66
  67 sub __driver {
  68   return $_[0]->storage->dbh->{Driver}->{Name};
  69 }
  70
  71 sub set_sql {
  72   my ($class, $name, $sql) = @_;
  73   my $table = $class->_table_name;
  74   #$sql =~ s/__TABLE__/$table/;
  75   no strict 'refs';
  76   *{"${class}::sql_${name}"} =
  77     sub {
  78       my $sql = $sql;
  79       my $class = shift;
  80       return $class->storage->sth($class->transform_sql($sql, @_));
  81     };
  82   if ($sql =~ /select/i) {
  83     my $meth = "sql_${name}";
  84     *{"${class}::search_${name}"} =
  85       sub {
  86         my ($class, @args) = @_;
  87         $class->sth_to_objects($class->$meth, \@args);
  88       };
  89   }
  90 }
  91
  92 sub transform_sql {
  93   my ($class, $sql, @args) = @_;
  94   my $table = $class->_table_name;
  95   my $attrs = { };
  96   foreach my $key (@{$class->_transform_sql_handler_order}) {
  97     my $h = $class->_transform_sql_handlers->{$key};
  98     $sql =~ s/__$key(?:\(([^\)]+)\))?__/$h->($attrs, $class, $1)/eg;
  99   }
 100   return sprintf($sql, @args);
 101 }
 102
 103 package DBIx::ContextualFetch::st;
 104
 105 no warnings 'redefine';
 106
 107 sub _untaint_execute {
 108   my $sth = shift;
 109   my $old_value = $sth->{Taint};
 110   $sth->{Taint} = 0;
 111   my $ret;
 112   {
 113     no warnings 'uninitialized';
 114     $ret = $sth->SUPER::execute(@_);
 115   }
 116   $sth->{Taint} = $old_value;
 117   return $ret;
 118 }
 119
 120 1;