lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package DBIx::Class::CDBICompat::ImaDBI;
   2
   3 use strict;
   4 use warnings;
   5
   6 use NEXT;
   7 use base qw/Class::Data::Inheritable/;
   8
   9 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  10                             => [ qw/TABLE ESSENTIAL JOIN/ ] );
  11
  12 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  13   {
  14     'TABLE' =>
  15       sub {
  16         my ($self, $class, $data) = @_;
  17         return $class->_table_name unless $data;
  18         my ($f_class, $alias) = split(/=/, $data);
  19         $f_class ||= $class;
  20         $self->{_aliases}{$alias} = $f_class;
  21         return $f_class->_table_name." ${alias}";
  22       },
  23     'ESSENTIAL' =>
  24       sub {
  25         my ($self, $class, $data) = @_;
  26         return join(' ', $class->columns('Essential')) unless $data;
  27         return join(' ', $self->{_aliases}{$data}->columns('Essential'));
  28       },
  29     'JOIN' =>
  30       sub {
  31         my ($self, $class, $data) = @_;
  32         my ($from, $to) = split(/ /, $data);
  33         my ($from_class, $to_class) = @{$self->{_aliases}}{$from, $to};
  34         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  35                           values %{ $from_class->_relationships };
  36         unless ($rel_obj) {
  37           ($from, $to) = ($to, $from);
  38           ($from_class, $to_class) = ($to_class, $from_class);
  39           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  40                          values %{ $from_class->_relationships };
  41         }
  42         die "No relationship to JOIN from ${from_class} to ${to_class}"
  43           unless $rel_obj;
  44         my $attrs = {
  45           _aliases => { self => $from, foreign => $to },
  46           _action => 'join',
  47         };
  48         my $join = $from_class->_cond_resolve($rel_obj->{cond}, $attrs);
  49         return $join;
  50       }
  51
  52   } );
  53
  54 sub db_Main {
  55   return $_[0]->_get_dbh;
  56 }
  57
  58 sub _dbi_connect {
  59   my ($class, @info) = @_;
  60   $info[3] = { %{ $info[3] || {}} };
  61   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  62   return $class->NEXT::_dbi_connect(@info);
  63 }
  64
  65 sub __driver {
  66   return $_[0]->_get_dbh->{Driver}->{Name};
  67 }
  68
  69 sub set_sql {
  70   my ($class, $name, $sql) = @_;
  71   my $table = $class->_table_name;
  72   #$sql =~ s/__TABLE__/$table/;
  73   no strict 'refs';
  74   *{"${class}::sql_${name}"} =
  75     sub {
  76       my $sql = $sql;
  77       my $class = shift;
  78       return $class->_sql_to_sth($class->transform_sql($sql, @_));
  79     };
  80   if ($sql =~ /select/i) {
  81     my $meth = "sql_${name}";
  82     *{"${class}::search_${name}"} =
  83       sub {
  84         my ($class, @args) = @_;
  85         $class->sth_to_objects($class->$meth, \@args);
  86       };
  87   }
  88 }
  89
  90 sub transform_sql {
  91   my ($class, $sql, @args) = @_;
  92   my $table = $class->_table_name;
  93   my $attrs = { };
  94   foreach my $key (@{$class->_transform_sql_handler_order}) {
  95     my $h = $class->_transform_sql_handlers->{$key};
  96     $sql =~ s/__$key(?:\(([^\)]+)\))?__/$h->($attrs, $class, $1)/eg;
  97   }
  98   return sprintf($sql, @args);
  99 }
 100
 101 1;