lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package # hide from PAUSE
   2     DBIx::Class::CDBICompat::ImaDBI;
   3
   4 use strict;
   5 use warnings;
   6 use DBIx::ContextualFetch;
   7 use Sub::Name ();
   8
   9 use base qw(Class::Data::Inheritable);
  10
  11 __PACKAGE__->mk_classdata('sql_transformer_class' =>
  12                           'DBIx::Class::CDBICompat::SQLTransformer');
  13
  14 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  15                             => [ qw/TABLE ESSENTIAL JOIN IDENTIFIER/ ] );
  16
  17 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  18   {
  19     'TABLE' =>
  20       sub {
  21         my ($self, $class, $data) = @_;
  22         return $class->result_source_instance->name unless $data;
  23         my ($f_class, $alias) = split(/=/, $data);
  24         $f_class ||= $class;
  25         $self->{_classes}{$alias} = $f_class;
  26         return $f_class->result_source_instance->name." ${alias}";
  27       },
  28     'ESSENTIAL' =>
  29       sub {
  30         my ($self, $class, $data) = @_;
  31         $class = $data ? $self->{_classes}{$data} : $class;
  32         return join(', ', $class->columns('Essential'));
  33       },
  34     'IDENTIFIER' =>
  35       sub {
  36         my ($self, $class, $data) = @_;
  37         $class = $data ? $self->{_classes}{$data} : $class;
  38         return join ' AND ', map  "$_ = ?", $class->primary_columns;
  39       },
  40     'JOIN' =>
  41       sub {
  42         my ($self, $class, $data) = @_;
  43         my ($from, $to) = split(/ /, $data);
  44         my ($from_class, $to_class) = @{$self->{_classes}}{$from, $to};
  45         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  46                           map { $from_class->relationship_info($_) }
  47                             $from_class->relationships;
  48         unless ($rel_obj) {
  49           ($from, $to) = ($to, $from);
  50           ($from_class, $to_class) = ($to_class, $from_class);
  51           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  52                           map { $from_class->relationship_info($_) }
  53                             $from_class->relationships;
  54         }
  55         $self->throw_exception( "No relationship to JOIN from ${from_class} to ${to_class}" )
  56           unless $rel_obj;
  57         my $join = $from_class->storage->sql_maker->_join_condition(
  58           scalar $from_class->result_source_instance->_resolve_condition(
  59             $rel_obj->{cond}, $to, $from
  60           )
  61         );
  62         return $join;
  63       }
  64
  65   } );
  66
  67 sub db_Main {
  68   return $_[0]->storage->dbh;
  69 }
  70
  71 sub connection {
  72   my ($class, @info) = @_;
  73   $info[3] = { %{ $info[3] || {}} };
  74   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  75   return $class->next::method(@info);
  76 }
  77
  78 sub __driver {
  79   return $_[0]->storage->dbh->{Driver}->{Name};
  80 }
  81
  82 sub set_sql {
  83   my ($class, $name, $sql) = @_;
  84   no strict 'refs';
  85   my $sql_name = "sql_${name}";
  86   my $full_sql_name = join '::', $class, $sql_name;
  87   *$full_sql_name = Sub::Name::subname $full_sql_name,
  88     sub {
  89       my $sql = $sql;
  90       my $class = shift;
  91       return $class->storage->_sth($class->transform_sql($sql, @_));
  92     };
  93   if ($sql =~ /select/i) {
  94     my $search_name = "search_${name}";
  95     my $full_search_name = join '::', $class, $search_name;
  96     *$full_search_name = Sub::Name::subname $full_search_name,
  97       sub {
  98         my ($class, @args) = @_;
  99         my $sth = $class->$sql_name;
 100         return $class->sth_to_objects($sth, \@args);
 101       };
 102   }
 103 }
 104
 105 sub sth_to_objects {
 106   my ($class, $sth, $execute_args) = @_;
 107
 108   $sth->execute(@$execute_args);
 109
 110   my @ret;
 111   while (my $row = $sth->fetchrow_hashref) {
 112     push(@ret, $class->inflate_result($class->result_source_instance, $row));
 113   }
 114
 115   return @ret;
 116 }
 117
 118 sub transform_sql {
 119   my ($class, $sql, @args) = @_;
 120
 121   my $tclass = $class->sql_transformer_class;
 122   $class->ensure_class_loaded($tclass);
 123   my $t = $tclass->new($class, $sql, @args);
 124
 125   return sprintf($t->sql, $t->args);
 126 }
 127
 128 package
 129   DBIx::ContextualFetch::st; # HIDE FROM PAUSE THIS IS NOT OUR CLASS
 130
 131 no warnings 'redefine';
 132
 133 sub _untaint_execute {
 134   my $sth = shift;
 135   my $old_value = $sth->{Taint};
 136   $sth->{Taint} = 0;
 137   my $ret;
 138   {
 139     no warnings 'uninitialized';
 140     $ret = $sth->SUPER::execute(@_);
 141   }
 142   $sth->{Taint} = $old_value;
 143   return $ret;
 144 }
 145
 146 1;