lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package DBIx::Class::CDBICompat::ImaDBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::ContextualFetch;
   6
   7 use base qw/DBIx::Class/;
   8
   9 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  10                             => [ qw/TABLE ESSENTIAL JOIN/ ] );
  11
  12 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  13   {
  14     'TABLE' =>
  15       sub {
  16         my ($self, $class, $data) = @_;
  17         return $class->result_source_instance->name unless $data;
  18         my ($f_class, $alias) = split(/=/, $data);
  19         $f_class ||= $class;
  20         $self->{_classes}{$alias} = $f_class;
  21         return $f_class->result_source_instance->name." ${alias}";
  22       },
  23     'ESSENTIAL' =>
  24       sub {
  25         my ($self, $class, $data) = @_;
  26         return join(' ', $class->columns('Essential')) unless $data;
  27         return join(' ', $self->{_classes}{$data}->columns('Essential'));
  28       },
  29     'JOIN' =>
  30       sub {
  31         my ($self, $class, $data) = @_;
  32         my ($from, $to) = split(/ /, $data);
  33         my ($from_class, $to_class) = @{$self->{_classes}}{$from, $to};
  34         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  35                           map { $from_class->relationship_info($_) }
  36                             $from_class->relationships;
  37         unless ($rel_obj) {
  38           ($from, $to) = ($to, $from);
  39           ($from_class, $to_class) = ($to_class, $from_class);
  40           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  41                           map { $from_class->relationship_info($_) }
  42                             $from_class->relationships;
  43         }
  44         $self->throw( "No relationship to JOIN from ${from_class} to ${to_class}" )
  45           unless $rel_obj;
  46         my $join = $from_class->storage->sql_maker->_join_condition(
  47           $from_class->result_source_instance->resolve_condition(
  48             $rel_obj->{cond}, $to, $from) );
  49         return $join;
  50       }
  51
  52   } );
  53
  54 sub db_Main {
  55   return $_[0]->storage->dbh;
  56 }
  57
  58 sub connection {
  59   my ($class, @info) = @_;
  60   $info[3] = { %{ $info[3] || {}} };
  61   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  62   return $class->next::method(@info);
  63 }
  64
  65 sub __driver {
  66   return $_[0]->storage->dbh->{Driver}->{Name};
  67 }
  68
  69 sub set_sql {
  70   my ($class, $name, $sql) = @_;
  71   no strict 'refs';
  72   *{"${class}::sql_${name}"} =
  73     sub {
  74       my $sql = $sql;
  75       my $class = shift;
  76       return $class->storage->sth($class->transform_sql($sql, @_));
  77     };
  78   if ($sql =~ /select/i) {
  79     my $meth = "sql_${name}";
  80     *{"${class}::search_${name}"} =
  81       sub {
  82         my ($class, @args) = @_;
  83         my $sth = $class->$meth;
  84         $sth->execute(@args);
  85         return $class->sth_to_objects($sth);
  86       };
  87   }
  88 }
  89
  90 sub sth_to_objects {
  91   my ($class, $sth) = @_;
  92   my @ret;
  93   while (my $row = $sth->fetchrow_hashref) {
  94     push(@ret, $class->inflate_result($class->result_source_instance, $row));
  95   }
  96   return @ret;
  97 }
  98
  99 sub transform_sql {
 100   my ($class, $sql, @args) = @_;
 101   my $attrs = { };
 102   foreach my $key (@{$class->_transform_sql_handler_order}) {
 103     my $h = $class->_transform_sql_handlers->{$key};
 104     $sql =~ s/__$key(?:\(([^\)]+)\))?__/$h->($attrs, $class, $1)/eg;
 105   }
 106   #warn $sql;
 107   return sprintf($sql, @args);
 108 }
 109
 110 package DBIx::ContextualFetch::st;
 111
 112 no warnings 'redefine';
 113
 114 sub _untaint_execute {
 115   my $sth = shift;
 116   my $old_value = $sth->{Taint};
 117   $sth->{Taint} = 0;
 118   my $ret;
 119   {
 120     no warnings 'uninitialized';
 121     $ret = $sth->SUPER::execute(@_);
 122   }
 123   $sth->{Taint} = $old_value;
 124   return $ret;
 125 }
 126
 127 1;