lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package DBIx::Class::CDBICompat::ImaDBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::ContextualFetch;
   6
   7 use NEXT;
   8 use base qw/Class::Data::Inheritable/;
   9
  10 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  11                             => [ qw/TABLE ESSENTIAL JOIN/ ] );
  12
  13 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  14   {
  15     'TABLE' =>
  16       sub {
  17         my ($self, $class, $data) = @_;
  18         return $class->_table_name unless $data;
  19         my ($f_class, $alias) = split(/=/, $data);
  20         $f_class ||= $class;
  21         $self->{_classes}{$alias} = $f_class;
  22         return $f_class->_table_name." ${alias}";
  23       },
  24     'ESSENTIAL' =>
  25       sub {
  26         my ($self, $class, $data) = @_;
  27         return join(' ', $class->columns('Essential')) unless $data;
  28         return join(' ', $self->{_classes}{$data}->columns('Essential'));
  29       },
  30     'JOIN' =>
  31       sub {
  32         my ($self, $class, $data) = @_;
  33         my ($from, $to) = split(/ /, $data);
  34         my ($from_class, $to_class) = @{$self->{_classes}}{$from, $to};
  35         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  36                           values %{ $from_class->_relationships };
  37         unless ($rel_obj) {
  38           ($from, $to) = ($to, $from);
  39           ($from_class, $to_class) = ($to_class, $from_class);
  40           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  41                          values %{ $from_class->_relationships };
  42         }
  43         $self->throw( "No relationship to JOIN from ${from_class} to ${to_class}" )
  44           unless $rel_obj;
  45         my $attrs = {
  46           %$self,
  47           _aliases => { self => $from, foreign => $to },
  48           _action => 'join',
  49         };
  50         my $join = $from_class->storage->sql_maker->_join_condition(
  51           $from_class->resolve_condition($rel_obj->{cond}, $attrs) );
  52         return $join;
  53       }
  54
  55   } );
  56
  57 sub db_Main {
  58   return $_[0]->storage->dbh;
  59 }
  60
  61 sub connection {
  62   my ($class, @info) = @_;
  63   $info[3] = { %{ $info[3] || {}} };
  64   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  65   return $class->next::method(@info);
  66 }
  67
  68 sub __driver {
  69   return $_[0]->storage->dbh->{Driver}->{Name};
  70 }
  71
  72 sub set_sql {
  73   my ($class, $name, $sql) = @_;
  74   my $table = $class->_table_name;
  75   #$sql =~ s/__TABLE__/$table/;
  76   no strict 'refs';
  77   *{"${class}::sql_${name}"} =
  78     sub {
  79       my $sql = $sql;
  80       my $class = shift;
  81       return $class->storage->sth($class->transform_sql($sql, @_));
  82     };
  83   if ($sql =~ /select/i) {
  84     my $meth = "sql_${name}";
  85     *{"${class}::search_${name}"} =
  86       sub {
  87         my ($class, @args) = @_;
  88         my $sth = $class->$meth;
  89         $sth->execute(@args);
  90         return $class->sth_to_objects($sth);
  91       };
  92   }
  93 }
  94
  95 sub sth_to_objects {
  96   my ($class, $sth) = @_;
  97   my @cols = $class->_select_columns;
  98   my @ret;
  99   while (my @row = $sth->fetchrow_array) {
 100     push(@ret, $class->_row_to_object(\@cols,\@row));
 101   }
 102   return @ret;
 103 }
 104
 105 sub transform_sql {
 106   my ($class, $sql, @args) = @_;
 107   my $table = $class->_table_name;
 108   my $attrs = { };
 109   foreach my $key (@{$class->_transform_sql_handler_order}) {
 110     my $h = $class->_transform_sql_handlers->{$key};
 111     $sql =~ s/__$key(?:\(([^\)]+)\))?__/$h->($attrs, $class, $1)/eg;
 112   }
 113   #warn $sql;
 114   return sprintf($sql, @args);
 115 }
 116
 117 package DBIx::ContextualFetch::st;
 118
 119 no warnings 'redefine';
 120
 121 sub _untaint_execute {
 122   my $sth = shift;
 123   my $old_value = $sth->{Taint};
 124   $sth->{Taint} = 0;
 125   my $ret;
 126   {
 127     no warnings 'uninitialized';
 128     $ret = $sth->SUPER::execute(@_);
 129   }
 130   $sth->{Taint} = $old_value;
 131   return $ret;
 132 }
 133
 134 1;