lib/DBIx/Class/CDBICompat/AccessorMapping.pm

   1 package # hide from PAUSE Indexer
   2   DBIx::Class::CDBICompat::AccessorMapping;
   3
   4 use strict;
   5 use warnings;
   6
   7 use Scalar::Util 'blessed';
   8 use namespace::clean;
   9
  10 sub mk_group_accessors {
  11     my ($class, $group, @cols) = @_;
  12
  13     foreach my $col (@cols) {
  14         my($accessor, $col) = ref $col eq 'ARRAY' ? @$col : (undef, $col);
  15
  16         my($ro_meth, $wo_meth);
  17         if (defined blessed $col and $col->isa('Class::DBI::Column')) {
  18             $ro_meth = $col->accessor;
  19             $wo_meth = $col->mutator;
  20         }
  21         elsif (defined $accessor and ($accessor ne $col)) {
  22             $ro_meth = $wo_meth = $accessor;
  23         }
  24         else {
  25             $ro_meth = $class->accessor_name_for($col);
  26             $wo_meth = $class->mutator_name_for($col);
  27         }
  28
  29         # warn "class: $class / col: $col / ro: $ro_meth / wo: $wo_meth\n";
  30         if ($ro_meth eq $wo_meth or # they're the same
  31             $wo_meth eq $col)     # or only the accessor is custom
  32         {
  33             $class->next::method($group => [ $ro_meth => $col ]);
  34         }
  35         else {
  36             $class->mk_group_ro_accessors($group => [ $ro_meth => $col ]);
  37             $class->mk_group_wo_accessors($group => [ $wo_meth => $col ]);
  38         }
  39     }
  40 }
  41
  42
  43 sub accessor_name_for {
  44     my ($class, $column) = @_;
  45     if ($class->can('accessor_name')) {
  46         return $class->accessor_name($column)
  47     }
  48
  49     return $column;
  50 }
  51
  52 sub mutator_name_for {
  53     my ($class, $column) = @_;
  54     if ($class->can('mutator_name')) {
  55         return $class->mutator_name($column)
  56     }
  57
  58     return $column;
  59 }
  60
  61
  62 sub new {
  63     my ($class, $attrs, @rest) = @_;
  64     $class->throw_exception( "create needs a hashref" ) unless ref $attrs eq 'HASH';
  65     foreach my $col ($class->columns) {
  66         my $acc = $class->accessor_name_for($col);
  67         $attrs->{$col} = delete $attrs->{$acc} if exists $attrs->{$acc};
  68
  69         my $mut = $class->mutator_name_for($col);
  70         $attrs->{$col} = delete $attrs->{$mut} if exists $attrs->{$mut};
  71     }
  72     return $class->next::method($attrs, @rest);
  73 }
  74
  75 1;