lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 use warnings;
   4 use strict;
   5
   6 # check deps
   7 BEGIN {
   8   require DBIx::Class::Optional::Dependencies;
   9   if (my $missing = DBIx::Class::Optional::Dependencies->req_missing_for ('admin') ) {
  10     die "The following extra modules are required for DBIx::Class::Admin: $missing\n";
  11   }
  12 }
  13
  14 use JSON::Any qw(DWIW PP JSON CPANEL XS);
  15 use Moose;
  16 use MooseX::Types::Moose qw/Int Str Any Bool/;
  17 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  18 use MooseX::Types::JSON qw(JSON);
  19 use MooseX::Types::Path::Class qw(Dir File);
  20 use MooseX::Types::LoadableClass qw(LoadableClass);
  21 use namespace::clean;
  22
  23 =head1 NAME
  24
  25 DBIx::Class::Admin - Administration object for schemas
  26
  27 =head1 SYNOPSIS
  28
  29   $ dbicadmin --help
  30
  31   $ dbicadmin --schema=MyApp::Schema \
  32     --connect='["dbi:SQLite:my.db", "", ""]' \
  33     --deploy
  34
  35   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  36     --connect='["dbi:SQLite:my.db", "", ""]' \
  37     --op=update --set='{ "name": "New_Employee" }'
  38
  39   use DBIx::Class::Admin;
  40
  41   # ddl manipulation
  42   my $admin = DBIx::Class::Admin->new(
  43     schema_class=> 'MY::Schema',
  44     sql_dir=> $sql_dir,
  45     connect_info => { dsn => $dsn, user => $user, password => $pass },
  46   );
  47
  48   # create SQLite sql
  49   $admin->create('SQLite');
  50
  51   # create SQL diff for an upgrade
  52   $admin->create('SQLite', {} , "1.0");
  53
  54   # upgrade a database
  55   $admin->upgrade();
  56
  57   # install a version for an unversioned schema
  58   $admin->install("3.0");
  59
  60 =head1 REQUIREMENTS
  61
  62 The Admin interface has additional requirements not currently part of
  63 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  64
  65 =head1 ATTRIBUTES
  66
  67 =head2 schema_class
  68
  69 the class of the schema to load
  70
  71 =cut
  72
  73 has 'schema_class' => (
  74   is  => 'ro',
  75   isa => LoadableClass,
  76 );
  77
  78
  79 =head2 schema
  80
  81 A pre-connected schema object can be provided for manipulation
  82
  83 =cut
  84
  85 has 'schema' => (
  86   is          => 'ro',
  87   isa         => 'DBIx::Class::Schema',
  88   lazy_build  => 1,
  89 );
  90
  91 sub _build_schema {
  92   my ($self)  = @_;
  93
  94   $self->connect_info->[3]{ignore_version} = 1;
  95   return $self->schema_class->connect(@{$self->connect_info});
  96 }
  97
  98 =head2 resultset
  99
 100 a resultset from the schema to operate on
 101
 102 =cut
 103
 104 has 'resultset' => (
 105   is  => 'rw',
 106   isa => Str,
 107 );
 108
 109
 110 =head2 where
 111
 112 a hash ref or json string to be used for identifying data to manipulate
 113
 114 =cut
 115
 116 has 'where' => (
 117   is      => 'rw',
 118   isa     => DBICHashRef,
 119   coerce  => 1,
 120 );
 121
 122
 123 =head2 set
 124
 125 a hash ref or json string to be used for inserting or updating data
 126
 127 =cut
 128
 129 has 'set' => (
 130   is      => 'rw',
 131   isa     => DBICHashRef,
 132   coerce  => 1,
 133 );
 134
 135
 136 =head2 attrs
 137
 138 a hash ref or json string to be used for passing additional info to the ->search call
 139
 140 =cut
 141
 142 has 'attrs' => (
 143   is      => 'rw',
 144   isa     => DBICHashRef,
 145   coerce  => 1,
 146 );
 147
 148
 149 =head2 connect_info
 150
 151 connect_info the arguments to provide to the connect call of the schema_class
 152
 153 =cut
 154
 155 has 'connect_info' => (
 156   is          => 'ro',
 157   isa         => DBICConnectInfo,
 158   lazy_build  => 1,
 159   coerce      => 1,
 160 );
 161
 162 sub _build_connect_info {
 163   my ($self) = @_;
 164   return $self->_find_stanza($self->config, $self->config_stanza);
 165 }
 166
 167
 168 =head2 config_file
 169
 170 config_file provide a config_file to read connect_info from, if this is provided
 171 config_stanze should also be provided to locate where the connect_info is in the config
 172 The config file should be in a format readable by Config::Any.
 173
 174 =cut
 175
 176 has config_file => (
 177   is      => 'ro',
 178   isa     => File,
 179   coerce  => 1,
 180 );
 181
 182
 183 =head2 config_stanza
 184
 185 config_stanza for use with config_file should be a '::' delimited 'path' to the connection information
 186 designed for use with catalyst config files
 187
 188 =cut
 189
 190 has 'config_stanza' => (
 191   is  => 'ro',
 192   isa => Str,
 193 );
 194
 195
 196 =head2 config
 197
 198 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 199 config_stanza will still be required.
 200
 201 =cut
 202
 203 has config => (
 204   is          => 'ro',
 205   isa         => DBICHashRef,
 206   lazy_build  => 1,
 207 );
 208
 209 sub _build_config {
 210   my ($self) = @_;
 211
 212   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 213
 214   # just grab the config from the config file
 215   $cfg = $cfg->{$self->config_file};
 216   return $cfg;
 217 }
 218
 219
 220 =head2 sql_dir
 221
 222 The location where sql ddl files should be created or found for an upgrade.
 223
 224 =cut
 225
 226 has 'sql_dir' => (
 227   is      => 'ro',
 228   isa     => Dir,
 229   coerce  => 1,
 230 );
 231
 232
 233 =head2 sql_type
 234
 235 The type of sql dialect to use for creating sql files from schema
 236
 237 =cut
 238
 239 has 'sql_type' => (
 240   is     => 'ro',
 241   isa    => Str,
 242 );
 243
 244 =head2 version
 245
 246 Used for install, the version which will be 'installed' in the schema
 247
 248 =cut
 249
 250 has version => (
 251   is  => 'rw',
 252   isa => Str,
 253 );
 254
 255
 256 =head2 preversion
 257
 258 Previous version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 259
 260 =cut
 261
 262 has preversion => (
 263   is  => 'rw',
 264   isa => Str,
 265 );
 266
 267
 268 =head2 force
 269
 270 Try and force certain operations.
 271
 272 =cut
 273
 274 has force => (
 275   is  => 'rw',
 276   isa => Bool,
 277 );
 278
 279
 280 =head2 quiet
 281
 282 Be less verbose about actions
 283
 284 =cut
 285
 286 has quiet => (
 287   is  => 'rw',
 288   isa => Bool,
 289 );
 290
 291 has '_confirm' => (
 292   is  => 'bare',
 293   isa => Bool,
 294 );
 295
 296
 297 =head2 trace
 298
 299 Toggle DBIx::Class debug output
 300
 301 =cut
 302
 303 has trace => (
 304     is => 'rw',
 305     isa => Bool,
 306     trigger => \&_trigger_trace,
 307 );
 308
 309 sub _trigger_trace {
 310     my ($self, $new, $old) = @_;
 311     $self->schema->storage->debug($new);
 312 }
 313
 314
 315 =head1 METHODS
 316
 317 =head2 create
 318
 319 =over 4
 320
 321 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 322
 323 =back
 324
 325 C<create> will generate sql for the supplied schema_class in sql_dir. The
 326 flavour of sql to generate can be controlled by supplying a sqlt_type which
 327 should be a L<SQL::Translator> name.
 328
 329 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 330
 331 Optional preversion can be supplied to generate a diff to be used by upgrade.
 332
 333 =cut
 334
 335 sub create {
 336   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 337
 338   $preversion ||= $self->preversion();
 339   $sqlt_type ||= $self->sql_type();
 340
 341   my $schema = $self->schema();
 342
 343   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 344 }
 345
 346
 347 =head2 upgrade
 348
 349 =over 4
 350
 351 =item Arguments: <none>
 352
 353 =back
 354
 355 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 356 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 357
 358 =cut
 359
 360 sub upgrade {
 361   my ($self) = @_;
 362   my $schema = $self->schema();
 363
 364   if (!$schema->get_db_version()) {
 365     # schema is unversioned
 366     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 367   } else {
 368     $schema->upgrade_directory ($self->sql_dir) if $self->sql_dir;  # this will override whatever default the schema has
 369     my $ret = $schema->upgrade();
 370     return $ret;
 371   }
 372 }
 373
 374
 375 =head2 install
 376
 377 =over 4
 378
 379 =item Arguments: $version
 380
 381 =back
 382
 383 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 384 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 385 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 386 already versioned databases.
 387
 388 =cut
 389
 390 sub install {
 391   my ($self, $version) = @_;
 392
 393   my $schema = $self->schema();
 394   $version ||= $self->version();
 395   if (!$schema->get_db_version() ) {
 396     # schema is unversioned
 397     print "Going to install schema version\n" if (!$self->quiet);
 398     my $ret = $schema->install($version);
 399     print "return is $ret\n" if (!$self->quiet);
 400   }
 401   elsif ($schema->get_db_version() and $self->force ) {
 402     warn "Forcing install may not be a good idea\n";
 403     if($self->_confirm() ) {
 404       $self->schema->_set_db_version({ version => $version});
 405     }
 406   }
 407   else {
 408     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 409   }
 410
 411 }
 412
 413
 414 =head2 deploy
 415
 416 =over 4
 417
 418 =item Arguments: $args
 419
 420 =back
 421
 422 deploy will create the schema at the connected database.  C<$args> are passed straight to
 423 L<DBIx::Class::Schema/deploy>.
 424
 425 =cut
 426
 427 sub deploy {
 428   my ($self, $args) = @_;
 429   my $schema = $self->schema();
 430   $schema->deploy( $args, $self->sql_dir );
 431 }
 432
 433 =head2 insert
 434
 435 =over 4
 436
 437 =item Arguments: $rs, $set
 438
 439 =back
 440
 441 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 442 into that resultset
 443
 444 =cut
 445
 446 sub insert {
 447   my ($self, $rs, $set) = @_;
 448
 449   $rs ||= $self->resultset();
 450   $set ||= $self->set();
 451   my $resultset = $self->schema->resultset($rs);
 452   my $obj = $resultset->new_result($set)->insert;
 453   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 454 }
 455
 456
 457 =head2 update
 458
 459 =over 4
 460
 461 =item Arguments: $rs, $set, $where
 462
 463 =back
 464
 465 update takes the name of a resultset from the schema_class, a hashref of data to update and
 466 a where hash used to form the search for the rows to update.
 467
 468 =cut
 469
 470 sub update {
 471   my ($self, $rs, $set, $where) = @_;
 472
 473   $rs ||= $self->resultset();
 474   $where ||= $self->where();
 475   $set ||= $self->set();
 476   my $resultset = $self->schema->resultset($rs);
 477   $resultset = $resultset->search( ($where||{}) );
 478
 479   my $count = $resultset->count();
 480   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 481
 482   if ( $self->force || $self->_confirm() ) {
 483     $resultset->update_all( $set );
 484   }
 485 }
 486
 487
 488 =head2 delete
 489
 490 =over 4
 491
 492 =item Arguments: $rs, $where, $attrs
 493
 494 =back
 495
 496 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 497 The found data is deleted and cannot be recovered.
 498
 499 =cut
 500
 501 sub delete {
 502   my ($self, $rs, $where, $attrs) = @_;
 503
 504   $rs ||= $self->resultset();
 505   $where ||= $self->where();
 506   $attrs ||= $self->attrs();
 507   my $resultset = $self->schema->resultset($rs);
 508   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 509
 510   my $count = $resultset->count();
 511   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 512
 513   if ( $self->force || $self->_confirm() ) {
 514     $resultset->delete_all();
 515   }
 516 }
 517
 518
 519 =head2 select
 520
 521 =over 4
 522
 523 =item Arguments: $rs, $where, $attrs
 524
 525 =back
 526
 527 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 528 The found data is returned in a array ref where the first row will be the columns list.
 529
 530 =cut
 531
 532 sub select {
 533   my ($self, $rs, $where, $attrs) = @_;
 534
 535   $rs ||= $self->resultset();
 536   $where ||= $self->where();
 537   $attrs ||= $self->attrs();
 538   my $resultset = $self->schema->resultset($rs);
 539   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 540
 541   my @data;
 542   my @columns = $resultset->result_source->columns();
 543   push @data, [@columns];#
 544
 545   while (my $row = $resultset->next()) {
 546     my @fields;
 547     foreach my $column (@columns) {
 548       push( @fields, $row->get_column($column) );
 549     }
 550     push @data, [@fields];
 551   }
 552
 553   return \@data;
 554 }
 555
 556 sub _confirm {
 557   my ($self) = @_;
 558
 559   # mainly here for testing
 560   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 561
 562   print "Are you sure you want to do this? (type YES to confirm) \n";
 563   my $response = <STDIN>;
 564
 565   return ($response=~/^YES/);
 566 }
 567
 568 sub _find_stanza {
 569   my ($self, $cfg, $stanza) = @_;
 570   my @path = split /::/, $stanza;
 571   while (my $path = shift @path) {
 572     if (exists $cfg->{$path}) {
 573       $cfg = $cfg->{$path};
 574     }
 575     else {
 576       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 577     }
 578   }
 579   $cfg = $cfg->{connect_info} if exists $cfg->{connect_info};
 580   return $cfg;
 581 }
 582
 583 =head1 FURTHER QUESTIONS?
 584
 585 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
 586
 587 =head1 COPYRIGHT AND LICENSE
 588
 589 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
 590 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
 591 redistribute it and/or modify it under the same terms as the
 592 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
 593
 594 =cut
 595
 596 1;